videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9
  10
  11 BEGIN {
  12     # Get rid of a (possibly old) version of BettIrssi
  13     # This is a hack to prevent having to reload irssi just
  14     # because BettIrssi.pm changed
  15
  16     delete($INC{'BettIrssi.pm'});
  17 }
  18
  19 use strict;
  20 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  21 use vars qw($VERSION %IRSSI);
  22 use XML::Simple;
  23 use Data::Dumper;
  24 use File::Spec;
  25 use BettIrssi 101 qw(_bcb _bcs);
  26 use LWP::UserAgent;
  27
  28 my @grabbers;
  29 my @getters;
  30 my $getter;
  31 my $conf;
  32 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  33 my $scriptdir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts');
  34 my $plugindir = File::Spec->catfile($scriptdir, 'videosite');
  35 my @outputstack = (undef);
  36
  37 my $PARAMS = {
  38     'getter' => '',
  39     'mode' => 'download'
  40 };
  41
  42
  43 # activate debug here
  44 my $debug = 0;
  45
  46 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  47 signal_add_last(_bcs("message public" => sub {check_for_link(@_)}));
  48 # "message own_public", SERVER_REC, char *msg, char *target
  49 signal_add_last(_bcs("message own_public" => sub {check_for_link(@_)}));
  50
  51 # "message private", SERVER_REC, char *msg, char *nick, char *address
  52 signal_add_last(_bcs("message private" => sub {check_for_link(@_)}));
  53 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  54 signal_add_last(_bcs("message own_private" => sub {check_for_link(@_)}));
  55
  56 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  57 signal_add_last(_bcs("message irc action" => sub {check_for_link(@_)}));
  58 # "message irc own_action", SERVER_REC, char *msg, char *target
  59 signal_add_last(_bcs("message irc own_action" => sub {check_for_link(@_)}));
  60
  61 # For tab completion
  62 # This does not use BettIrssi (yet)
  63 signal_add_first('complete word', \&sig_complete);
  64
  65 sub push_output {
  66     unshift(@outputstack, shift);
  67 }
  68
  69 sub pop_output {
  70     shift(@outputstack);
  71
  72     @outputstack = (undef) unless (@outputstack);
  73 }
  74
  75 my $videosite_commands = {
  76     'save' => sub {
  77         cmd_save();
  78     },
  79
  80     'set' => sub {
  81         cmd_set(@_);
  82     },
  83
  84     'show' => sub {
  85         cmd_show(@_);
  86     },
  87
  88     'help' => sub {
  89         cmd_help(@_);
  90     },
  91
  92     'getter' => sub {
  93         cmd_getter(@_);
  94     },
  95
  96     'enable' => sub {
  97         cmd_enable(@_);
  98     },
  99
 100     'disable' => sub {
 101         cmd_disable(@_);
 102     },
 103
 104     'reload' => sub {
 105         init_videosite(0);
 106     },
 107
 108     'mode' => sub {
 109         cmd_mode(@_);
 110     },
 111
 112     'debug' => sub {
 113         $debug = 1;
 114         foreach (@grabbers, @getters) {
 115             $_->setdebug(1);
 116         }
 117         write_irssi('Enabled debugging');
 118     },
 119
 120     'nodebug' => sub {
 121         $debug = 0;
 122         foreach (@grabbers, @getters) {
 123             $_->setdebug(0);
 124         }
 125         write_irssi('Disabled debugging');
 126     },
 127 };
 128
 129 sub write_irssi {
 130     my @text = @_;
 131     my $output = $outputstack[0];
 132
 133     my $format = "%%mvideosite: %%n" . shift(@text);
 134
 135     # escape % in parameters from irssi
 136     s/%/%%/g foreach @text;
 137
 138     if (defined $output) {
 139         $output->(sprintf($format, @text), MSGLEVEL_CLIENTCRAP);
 140     } else {
 141         Irssi::print(sprintf($format, @text));
 142     }
 143
 144 }
 145
 146 sub write_debug {
 147     if ($debug) {
 148         write_irssi(@_);
 149     }
 150 }
 151
 152 sub expand_url_shortener {
 153     my $s = shift;
 154     my $os = '';
 155     my @urlshortener = (
 156         'hel\.me/[[:alnum:]]+',
 157         '7ax\.de/[[:alnum:]]+',
 158         'ow\.ly/[[:alnum:]]+',
 159         'j\.mp/[[:alnum:]]+',
 160         'bit\.ly/[[:alnum:]]+',
 161         'tinyurl\.com/[[:alnum:]]+',
 162         );
 163     my $ua = LWP::UserAgent->new(agent => 'Mozilla', max_redirect => 0);
 164     my $i = 100;
 165
 166     OUTER: while (($os ne $s) and ($i > 0)) {
 167         $os = $s;
 168         $i--;
 169
 170         foreach my $pattern (@urlshortener) {
 171             my $p = "https?:\/\/" . $pattern;
 172
 173             write_debug("Matching %s against %s", $p, $s);
 174             if ($s =~ m|($p)|) {
 175                 my $matched = $1;
 176                 my $res;
 177
 178                 write_debug("Found %s", $matched);
 179                 $res = $ua->head($matched);
 180                 if ($res->is_redirect()) {
 181                     my $new = $res->headers()->header("Location");
 182
 183                     write_debug("Replacing %s with %s", $matched, $new);
 184                     $s =~ s/$matched/$new/;
 185                     next OUTER;
 186                 } else {
 187                     write_debug("Error resolving %s", $matched);
 188                 }
 189             }
 190         }
 191     }
 192
 193     if ($i == 0) {
 194         write_debug("Loop terminated by counter");
 195     }
 196
 197     write_debug("Final string: %s", $s);
 198
 199     return $s;
 200 }
 201
 202
 203 sub check_for_link {
 204     my $event = shift;
 205     my $message = $event->message();
 206     my $witem = $event->channel();
 207     my $g;
 208     my $m;
 209     my $p;
 210
 211
 212     # Look if we should ignore this line
 213     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
 214         return;
 215     }
 216
 217     push_output($event->ewpf);
 218     $message = expand_url_shortener($message);
 219
 220     study($message);
 221
 222     # Offer the message to all Grabbers in turn
 223     GRABBER: foreach $g (@grabbers) {
 224         ($m, $p) = $g->get($message);
 225         while (defined($m)) {
 226             write_debug('Metadata: %s', Dumper($m));
 227             if ('download' eq ($conf->{'videosite'}->{'mode'})) {
 228                 write_irssi('%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 229                 unless($getter->get($m)) {
 230                     write_irssi('%%R>>> FAILED');
 231                 }
 232             } elsif ('display' eq ($conf->{'videosite'}->{'mode'})) {
 233                 write_irssi('%%M>>> %%NSaw %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 234             } else {
 235                 write_irssi('%%R>>> Invalid operation mode');
 236             }
 237
 238             # Remove the matched part from the message and try again (there may be
 239             # more!)
 240             $message =~ s/$p//;
 241             study($message);
 242             last GRABBER if ($message =~ /^\s*$/);
 243
 244             ($m, $p) = $g->get($message);
 245         }
 246     }
 247
 248     pop_output();
 249 }
 250
 251 sub cmd_save {
 252
 253     eval {
 254         open(CONF, '>'.$conffile) or die 'Could not open config file';
 255         print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
 256         close(CONF);
 257     };
 258     if ($@) {
 259         write_irssi('Could not save config to %s: %s', ($conffile, $@));
 260     } else {
 261         write_irssi('configuration saved to %s', $conffile);
 262     }
 263 }
 264
 265 sub cmd_set {
 266     my $target = shift;
 267     my $key = shift;
 268     my $val = shift;
 269     my $p;
 270
 271     foreach $p (@getters, @grabbers) {
 272         if ($p->{'NAME'} eq $target) {
 273             $p->setval($key, $val);
 274             return;
 275         }
 276     }
 277     write_irssi('No such module');
 278 }
 279
 280
 281 sub cmd_enable {
 282     my $target = shift;
 283     my $p;
 284
 285     foreach $p (@grabbers) {
 286         if ($p->{'NAME'} eq $target) {
 287             $p->enable();
 288             return;
 289         }
 290     }
 291     write_irssi('No such module');
 292 }
 293
 294
 295 sub cmd_disable {
 296     my $target = shift;
 297     my $p;
 298
 299     foreach $p (@grabbers) {
 300         if ($p->{'NAME'} eq $target) {
 301             $p->disable();
 302             return;
 303         }
 304     }
 305     write_irssi('No such module');
 306 }
 307
 308
 309 sub cmd_show {
 310     my $target = shift;
 311     my $p;
 312     my $e;
 313
 314     if (defined($target)) {
 315         foreach $p (@getters, @grabbers) {
 316             if ($p->{'NAME'} eq $target) {
 317                 write_irssi($p->getconfstr());
 318                 return;
 319             }
 320         }
 321         write_irssi('No such module');
 322     } else {
 323         write_irssi('Loaded grabbers (* denotes enabled modules):');
 324         foreach $p (@grabbers) {
 325             $e = $p->_getval('enabled');
 326             write_irssi(' %s%s', $p->{'NAME'}, $e?'*':'');
 327         };
 328
 329         write_irssi('Loaded getters:');
 330         foreach $p (@getters) {
 331             write_irssi(' %s', $p->{'NAME'});
 332         };
 333     }
 334 }
 335
 336 sub cmd_help {
 337     my $target = shift;
 338     my $p;
 339
 340     if (defined($target)) {
 341         foreach $p (@getters, @grabbers) {
 342             if ($p->{'NAME'} eq $target) {
 343                 write_irssi($p->gethelpstr());
 344                 return;
 345             }
 346         }
 347         write_irssi('No such module');
 348     } else {
 349         write_irssi(<<'EOT');
 350 Supported commands:
 351  save: save the current configuration
 352  help [modulename]: display this help, or module specific help
 353  show [modulename]: show loaded modules, or the current parameters of a module
 354  set modulename parameter value: set a module parameter to a new value
 355  getter [modulename]: display or set the getter to use
 356  enable [modulename]: enable the usage of this module (grabbers only)
 357  disable [modulename]: disable the usage of this module (grabbers only)
 358  reload: reload all modules (this is somewhat experimental)
 359  mode [modename]: display or set the operation mode (download/display)
 360  debug: enable debugging messages
 361  nodebug: disable debugging messages
 362 EOT
 363     }
 364 }
 365
 366 sub cmd_getter {
 367     my $target = shift;
 368     my $p;
 369
 370     if (defined($target)) {
 371         foreach $p (@getters) {
 372             if ($p->{'NAME'} eq $target) {
 373                 $getter = $p;
 374                 $conf->{'videosite'}->{'getter'} = $target;
 375                 write_irssi("Getter changed to %s", $target);
 376                 return;
 377             }
 378         }
 379         write_irssi('No such getter');
 380     } else {
 381         write_irssi('Current getter: %s', $conf->{'videosite'}->{'getter'});
 382     }
 383 }
 384
 385 sub cmd_mode {
 386     my $mode = shift;
 387
 388     if (defined($mode)) {
 389         $mode = lc($mode);
 390         if (('download' eq $mode) or ('display' eq $mode)) {
 391             $conf->{'videosite'}->{'mode'} = $mode;
 392             write_irssi('Now using %s mode', $mode);
 393         } else {
 394             write_irssi('Invalid mode: %s', $mode);
 395         }
 396     } else {
 397         write_irssi('Current mode: %s', $conf->{'videosite'}->{'mode'});
 398     }
 399 }
 400
 401
 402 # save on unload
 403 sub sig_command_script_unload {
 404     my $script = shift;
 405     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 406         cmd_save();
 407     }
 408 }
 409
 410 sub ploader {
 411
 412     my $dir = shift;
 413     my $pattern = shift;
 414     my $type = shift;
 415     my @list;
 416     my $p;
 417     my $g;
 418     my @g = ();
 419
 420     opendir(D, $dir) || return ();
 421     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 422     closedir(D);
 423
 424     foreach $p (@list) {
 425         write_debug("Trying to load $p:");
 426         $p =~ s/\.pm$//;
 427         eval qq{ require videosite::$p; };
 428         if ($@) {
 429             write_irssi("Failed to load plugin: $@");
 430             next;
 431         }
 432
 433         $g = eval qq{ videosite::$p->new(); };
 434         if ($@) {
 435             write_irssi("Failed to instanciate: $@");
 436             delete($INC{$p});
 437             next;
 438         }
 439
 440         write_debug("found $g->{'TYPE'} $g->{'NAME'}");
 441         if ($type eq $g->{'TYPE'}) {
 442             push(@g, $g);
 443             $g->setio(\&write_irssi);
 444         } else {
 445             write_irssi('%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 446             delete($INC{$p});
 447         }
 448     }
 449
 450     write_debug("Loaded %d plugins", $#g+1);
 451
 452     return @g;
 453 }
 454
 455 sub _load_modules($) {
 456
 457     my $path = shift;
 458
 459     foreach (keys(%INC)) {
 460         if ($INC{$_} =~ m|^$path|) {
 461             write_debug("Removing %s from \$INC", $_);
 462             delete($INC{$_});
 463         }
 464     }
 465     @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
 466     @getters = ploader($path, '.*Getter\.pm$', 'getter');
 467 }
 468
 469
 470 sub init_videosite {
 471
 472     my $bindings = shift;
 473     my $p;
 474
 475     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
 476         # No config, start with an empty one
 477         write_debug('No config found, using defaults');
 478         $conf = { 'videosite' => { }};
 479     }
 480     foreach (keys(%{$PARAMS})) {
 481         unless (exists($conf->{'videosite'}->{$_})) {
 482             $conf->{'videosite'}->{$_} = $PARAMS->{$_};
 483         }
 484     }
 485
 486     _load_modules($plugindir);
 487
 488     unless (defined(@grabbers) && defined(@getters)) {
 489         write_irssi('No grabbers or no getters found, can not proceed.');
 490         return;
 491     }
 492
 493     $getter = $getters[0];
 494     foreach $p (@getters) {
 495         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 496             $getter = $p;
 497         }
 498     }
 499     write_debug('Selected %s as getter', $getter->{'NAME'});
 500     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 501
 502     # Loop through all plugins and load the config
 503     foreach $p (@grabbers, @getters) {
 504         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 505     }
 506
 507     if ($bindings) {
 508
 509         Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 510         Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 511         Irssi::signal_add('setup saved', 'cmd_save');
 512
 513
 514         Irssi::command_bind(_bcb('videosite' => \&cmdhandler));
 515     }
 516
 517     write_irssi('initialized successfully');
 518 }
 519
 520 sub sig_complete {
 521     my ($complist, $window, $word, $linestart, $want_space) = @_;
 522     my @matches;
 523
 524     if ($linestart !~ m|^/videosite\b|) {
 525         return;
 526     }
 527
 528     if ('/videosite' eq $linestart) {
 529         # No command enterd so far. Produce a list of possible follow-ups
 530         @matches = grep {/^$word/} keys (%{$videosite_commands});
 531     } elsif ('/videosite set' eq $linestart) {
 532         # 'set' command entered. Produce a list of modules
 533         foreach (@grabbers, @getters) {
 534             push(@matches, $_->{'NAME'}) if $_->{'NAME'} =~ m|^$word|;
 535         };
 536     } elsif ($linestart =~ m|^/videosite set (\w+)$|) {
 537         my $module = $1;
 538
 539         foreach my $p (@getters, @grabbers) {
 540             if ($p->{'NAME'} eq $module) {
 541                 @matches = $p->getparamlist($word);
 542                 last;
 543             }
 544         }
 545     } elsif ($linestart =~ m|/videosite set (\w+) (\w+)$|) {
 546         my $module = $1;
 547         my $param = $2;
 548
 549         foreach my $p (@getters, @grabbers) {
 550             if ($p->{'NAME'} eq $module) {
 551                 @matches = $p->getparamvalues($param, $word);
 552                 last;
 553             }
 554         }
 555     }
 556
 557
 558     push(@{$complist}, sort @matches);
 559     ${$want_space} = 0;
 560
 561     Irssi::signal_stop();
 562 }
 563
 564 sub cmdhandler {
 565     my $event = shift;
 566     my ($cmd, @params) = split(/\s+/, $event->message());
 567
 568     push_output($event->ewpf);
 569
 570     if (exists($videosite_commands->{$cmd})) {
 571         $videosite_commands->{$cmd}->(@params);
 572     }
 573
 574     pop_output();
 575 }
 576
 577 unshift(@INC, $scriptdir);
 578 init_videosite(1);