videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9
  10 use strict;
  11 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  12 use vars qw($VERSION %IRSSI);
  13 use XML::Simple;
  14 use Data::Dumper;
  15 use File::Spec;
  16
  17 my @grabbers;
  18 my @getters;
  19 my $getter;
  20 my $conf;
  21 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  22 my $plugindir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts', 'videosite');
  23
  24 my $PARAMS = {
  25     'getter' => '',
  26     'mode' => 'download'
  27 };
  28
  29
  30 # activate debug here
  31 my $debug = 0;
  32
  33 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  34 signal_add_last("message public" => sub {check_for_link(\@_,1,4,2,0);});
  35 # "message own_public", SERVER_REC, char *msg, char *target
  36 signal_add_last("message own_public" => sub {check_for_link(\@_,1,2,-1,0);});
  37
  38 # "message private", SERVER_REC, char *msg, char *nick, char *address
  39 signal_add_last("message private" => sub {check_for_link(\@_,1,-1,2,0);});
  40 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  41 signal_add_last("message own_private" => sub {check_for_link(\@_,1,2,-1,0);});
  42
  43 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  44 signal_add_last("message irc action" => sub {check_for_link(\@_,1,4,2,0);});
  45 # "message irc own_action", SERVER_REC, char *msg, char *target
  46 signal_add_last("message irc own_action" => sub {check_for_link(\@_,1,2,-1,0);});
  47
  48 sub write_irssi {
  49     my $witem = shift;
  50     my @text = @_;
  51
  52     $text[0] = 'videosite: ' . $text[0];
  53
  54     if (defined $witem) {
  55         $witem->print(sprintf(shift(@text), @text), MSGLEVEL_CLIENTCRAP);
  56     } else {
  57         Irssi::print(sprintf(shift(@text), @text));
  58     }
  59
  60 }
  61
  62 sub write_debug {
  63     if ($debug) {
  64         write_irssi(shift, @_);
  65     }
  66 }
  67
  68 sub check_for_link {
  69     my ($signal,$parammessage,$paramchannel,$paramnick,$paramserver) = @_;
  70     my $server = $signal->[$paramserver];
  71     my $target = $signal->[$paramchannel];
  72     my $message = ($parammessage == -1) ? '' : $signal->[$parammessage];
  73     my $g;
  74     my $m;
  75     my $p;
  76
  77
  78     my $witem;
  79     if (defined $server) {
  80         $witem = $server->window_item_find($target);
  81     } else {
  82         $witem = Irssi::window_item_find($target);
  83     }
  84
  85     # Look if we should ignore this line
  86     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
  87         return;
  88     }
  89
  90     # Offer the message to all Grabbers in turn
  91     foreach $g (@grabbers) {
  92         ($m, $p) = $g->get($message);
  93         while (defined($m)) {
  94             write_debug($witem, 'Metadata: %s', Dumper($m));
  95             if ('download' eq ($conf->{'videosite'}->{'mode'})) {
  96                 write_irssi($witem, '%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
  97                 unless($getter->get($m)) {
  98                     write_irssi($witem, '%%R>>> FAILED');
  99                 }
 100             } elsif ('display' eq ($conf->{'videosite'}->{'mode'})) {
 101                 write_irssi($witem, '%%M>>> %%NSaw %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 102             } else {
 103                 write_irssi($witem, '%%R>>> Invalid operation mode');
 104             }
 105
 106             # Remove the matched part from the message and try again (there may be
 107             # more!)
 108             $message =~ s/$p//;
 109
 110             ($m, $p) = $g->get($message);
 111         }
 112     }
 113 }
 114
 115 sub cmd_save {
 116
 117     eval {
 118         open(CONF, '>'.$conffile) or die 'Could not open config file';
 119         print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
 120         close(CONF);
 121     };
 122     if ($@) {
 123         write_irssi(undef, 'Could not save config to %s: %s', ($conffile, $@));
 124     } else {
 125         write_irssi(undef, 'configuration saved to %s', $conffile);
 126     }
 127 }
 128
 129 sub cmd_set {
 130     my $target = shift;
 131     my $key = shift;
 132     my $val = shift;
 133     my $p;
 134
 135     foreach $p (@getters, @grabbers) {
 136         if ($p->{'NAME'} eq $target) {
 137             $p->setval($key, $val);
 138             return;
 139         }
 140     }
 141     write_irssi(undef, 'No such module');
 142 }
 143
 144
 145 sub cmd_enable {
 146     my $target = shift;
 147     my $p;
 148
 149     foreach $p (@grabbers) {
 150         if ($p->{'NAME'} eq $target) {
 151             $p->enable();
 152             return;
 153         }
 154     }
 155     write_irssi(undef, 'No such module');
 156 }
 157
 158
 159 sub cmd_disable {
 160     my $target = shift;
 161     my $p;
 162
 163     foreach $p (@grabbers) {
 164         if ($p->{'NAME'} eq $target) {
 165             $p->disable();
 166             return;
 167         }
 168     }
 169     write_irssi(undef, 'No such module');
 170 }
 171
 172
 173 sub cmd_show {
 174     my $target = shift;
 175     my $p;
 176     my $e;
 177
 178     if (defined($target)) {
 179         foreach $p (@getters, @grabbers) {
 180             if ($p->{'NAME'} eq $target) {
 181                 write_irssi(undef, $p->getconfstr());
 182                 return;
 183             }
 184         }
 185         write_irssi(undef, 'No such module');
 186     } else {
 187         write_irssi(undef, 'Loaded grabbers (* denotes enabled modules):');
 188         foreach $p (@grabbers) {
 189             $e = $p->_getval('enabled');
 190             write_irssi(undef, ' %s%s', $p->{'NAME'}, $e?'*':'');
 191         };
 192
 193         write_irssi(undef, 'Loaded getters:');
 194         foreach $p (@getters) {
 195             write_irssi(undef, ' %s', $p->{'NAME'});
 196         };
 197     }
 198 }
 199
 200 sub cmd_help {
 201     my $target = shift;
 202     my $p;
 203
 204     if (defined($target)) {
 205         foreach $p (@getters, @grabbers) {
 206             if ($p->{'NAME'} eq $target) {
 207                 write_irssi(undef, $p->gethelpstr());
 208                 return;
 209             }
 210         }
 211         write_irssi(undef, 'No such module');
 212     } else {
 213         write_irssi(undef, <<'EOT');
 214 Supported commands:
 215  save: Save the current configuration
 216  help [modulename]: Display this help, or module specific help
 217  show [modulename]: Show loaded modules, or the current parameters of a module
 218  set modulename parameter value: set a module parameter to a new value
 219  getter [modulename]: display or set the getter to use
 220  enable [modulename]: enable the usage of this module (grabbers only)
 221  disable [modulename]: disable the usage of this module (grabbers only)
 222  reload: reload all modules (this is somewhat experimental)
 223  mode [modename]: display or set the operation mode (download/display)
 224  debug: enable debugging messages
 225  nodebug: disable debugging messages
 226 EOT
 227     }
 228 }
 229
 230 sub cmd_getter {
 231     my $target = shift;
 232     my $p;
 233
 234     if (defined($target)) {
 235         foreach $p (@getters, @grabbers) {
 236             if (($p->{'NAME'} eq $target) && ($p->{'TYPE'} eq 'getter')) {
 237                 $getter = $p;
 238                 $conf->{'videosite'}->{'getter'} = $target;
 239                 return;
 240             }
 241         }
 242         write_irssi(undef, 'No such getter');
 243     } else {
 244         write_irssi(undef, 'Current getter: %s', $conf->{'videosite'}->{'getter'});
 245     }
 246 }
 247
 248 sub cmd_mode {
 249     my $mode = shift;
 250
 251     if (defined($mode)) {
 252         $mode = lc($mode);
 253         if (('download' eq $mode) or ('display' eq $mode)) {
 254             $conf->{'videosite'}->{'mode'} = $mode;
 255         } else {
 256             write_irssi(undef, 'Invalid mode: %s', $mode);
 257         }
 258     } else {
 259         write_irssi(undef, 'Current mode: %s', $conf->{'videosite'}->{'mode'});
 260     }
 261 }
 262
 263
 264 # save on unload
 265 sub sig_command_script_unload {
 266     my $script = shift;
 267     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 268         cmd_save();
 269     }
 270 }
 271
 272 sub ploader {
 273
 274     my $dir = shift;
 275     my $pattern = shift;
 276     my $type = shift;
 277     my @list;
 278     my $p;
 279     my $g;
 280     my @g = ();
 281
 282     opendir(D, $dir) || return ();
 283     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 284     closedir(D);
 285
 286     foreach $p (@list) {
 287         write_debug(undef, "Trying to load $p:");
 288         $p =~ s/\.pm$//;
 289         eval qq{ require $p; };
 290         if ($@) {
 291             write_debug(undef, "Failed to load plugin: $@");
 292             next;
 293         }
 294
 295         $g = eval $p.q{->new();};
 296         if ($@) {
 297             write_debug(undef, "Failed to instanciate: $@");
 298             delete($INC{$p});
 299             next;
 300         }
 301
 302         write_debug(undef, "found $g->{'TYPE'} $g->{'NAME'}");
 303         if ($type eq $g->{'TYPE'}) {
 304             push(@g, $g);
 305         } else {
 306             write_irssi(undef, '%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 307             delete($INC{$p});
 308         }
 309     }
 310
 311     write_debug(undef, "Loaded %d plugins", $#g+1);
 312
 313     return @g;
 314 }
 315
 316 sub _load_modules($) {
 317
 318     my $path = shift;
 319
 320     foreach (keys(%INC)) {
 321         if ($INC{$_} =~ m|^$path|) {
 322             write_debug(undef, "Removing %s from \$INC", $_);
 323             delete($INC{$_});
 324         }
 325     }
 326     @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
 327     @getters = ploader($path, '.*Getter\.pm$', 'getter');
 328 }
 329
 330
 331 sub init_videosite {
 332
 333     my $bindings = shift;
 334     my $p;
 335
 336     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
 337         # No config, start with an empty one
 338         write_debug(undef, 'No config found, using defaults');
 339         $conf = { 'videosite' => { }};
 340     }
 341     foreach (keys(%{$PARAMS})) {
 342         unless (exists($conf->{'videosite'}->{$_})) {
 343             $conf->{'videosite'}->{$_} = $PARAMS->{$_};
 344         }
 345     }
 346
 347     _load_modules($plugindir);
 348
 349     unless (defined(@grabbers) && defined(@getters)) {
 350         write_irssi(undef, 'No grabbers or no getters found, can not proceed.');
 351         return;
 352     }
 353
 354     $getter = $getters[0];
 355     foreach $p (@getters) {
 356         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 357             $getter = $p;
 358         }
 359     }
 360     write_debug(undef, 'Selected %s as getter', $getter->{'NAME'});
 361     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 362
 363     # Loop through all plugins and load the config
 364     foreach $p (@grabbers, @getters) {
 365         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 366     }
 367
 368     if ($bindings) {
 369
 370         Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 371         Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 372         Irssi::signal_add('setup saved', 'cmd_save');
 373
 374
 375         Irssi::command_bind('videosite' => \&cmdhandler);
 376     }
 377
 378     write_irssi(undef, 'videosite initialized');
 379 }
 380
 381 sub cmdhandler {
 382     my ($data, $server, $item) = @_;
 383     my @params = split(/\s+/, $data);
 384
 385     if ($params[0] eq 'save') {
 386         cmd_save();
 387     } elsif ($params[0] eq 'set') {
 388         shift(@params);
 389         cmd_set(@params);
 390     } elsif ($params[0] eq 'show') {
 391         shift(@params);
 392         cmd_show(@params);
 393     } elsif ($params[0] eq 'help') {
 394         shift(@params);
 395         cmd_help(@params);
 396     } elsif ($params[0] eq 'getter') {
 397         shift(@params);
 398         cmd_getter(@params);
 399     } elsif ($params[0] eq 'enable') {
 400         shift(@params);
 401         cmd_enable(@params);
 402     } elsif ($params[0] eq 'disable') {
 403         shift(@params);
 404         cmd_disable(@params);
 405     } elsif ($params[0] eq 'reload') {
 406         init_videosite(0);
 407     } elsif ($params[0] eq 'mode') {
 408         shift(@params);
 409         cmd_mode(@params);
 410     } elsif ($params[0] eq 'debug') {
 411         $debug = 1;
 412         foreach (@grabbers, @getters) {
 413             $_->setdebug(1);
 414         }
 415         write_irssi(undef, 'Enabled debugging');
 416     } elsif ($params[0] eq 'nodebug') {
 417         $debug = 0;
 418         foreach (@grabbers, @getters) {
 419             $_->setdebug(0);
 420         }
 421         write_irssi(undef, 'Disabled debugging');
 422     }
 423 }
 424
 425 unshift(@INC, $plugindir);
 426 init_videosite(1);