videosite/AsyncFileGetter.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 #     2008-2009,2011-2012 by Christian Garbs <mitch@cgarbs.de>
   3 #
   4 # licensed under GNU GPL v2
   5 #
   6 # A getter which will download the media to a local file storage
   7 # in the background
   8 #
   9
  10 package videosite::AsyncFileGetter;
  11
  12 use videosite::FileGetter;
  13 @ISA = qw(videosite::FileGetter);
  14
  15 use strict;
  16 use LWP::Simple qw(!get);
  17 use File::Basename;
  18 use File::Temp qw(tempfile);
  19 use MIME::Base64;
  20
  21 sub new {
  22     my $class = shift;
  23     my $self = $class->SUPER::new(
  24         NAME => 'asyncfilegetter',
  25         @_,
  26     );
  27
  28     return bless($self, $class);
  29 }
  30
  31 sub get {
  32     my $self = shift;
  33     my $video = shift;
  34     my $dlfile;
  35     my $dirname;
  36     my $cookie = "";
  37     my $useragent = "-H \"User-Agent: Mozilla/5.0\"";
  38
  39     $dlfile = sprintf($self->_getval('FILEPATTERN'),
  40         $self->_encode($video->{'SOURCE'}),
  41         $self->_encode($video->{'ID'}),
  42         $self->_encode($video->{'TITLE'}),
  43         $self->_encode($video->{'DLURL'}),
  44         $self->_encode($video)->{'URL'});
  45
  46     $dlfile =~ s/([\\"])/\\$1/g;
  47
  48     $dirname = dirname($dlfile);
  49     if ($self->_diskfree($dirname) < $self->_getval('MINFREE')) {
  50         $self->error("Not enough free space to download");
  51         return 0;
  52     }
  53
  54     $self->debug('Going to download %s to %s', $video->{'DLURL'}, $dlfile);
  55
  56     my (undef, $tmpfile) = tempfile('videosite.tmp.XXXXXXXXXXXX', DIR => $dirname);
  57
  58     my %saved_env;
  59
  60     if (exists($video->{'CONNECTOR'})) {
  61         my $schemas = $video->{'CONNECTOR'}->{'schemas'};
  62         foreach my $schemakey(keys(%{$schemas})) {
  63             $self->debug("Setting %s_proxy to %s", $schemakey, $schemas->{$schemakey});
  64             my $envkey = $schemakey.'_proxy';
  65             $saved_env{ $envkey } = $ENV{ $envkey };
  66             $ENV{ $envkey } = $schemas->{$schemakey};
  67         }
  68     }
  69
  70     $cookie = "-H \"Cookie: $video->{'COOKIE'}\"" if (defined $video->{'COOKIE'});
  71     my $cmdline = "( GET $useragent $cookie \"$video->{'DLURL'}\" > \"$tmpfile\" && mv \"$tmpfile\" \"$dlfile\" && chmod =rw \"$dlfile\" || rm -f \"$tmpfile\" ) &";
  72     $self->debug(encode_base64($cmdline));
  73     system($cmdline);
  74
  75     # restore environment
  76     foreach my $envkey (keys %saved_env) {
  77         $self->debug("Restoring environment: %s=%s", $envkey, $saved_env{ $envkey} );
  78         $ENV{ $envkey } = $saved_env{ $envkey };
  79     }
  80
  81     return 1;
  82 }