videosite/AsyncWgetFileGetter.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 #     2008-2009,2011-2012 by Christian Garbs <mitch@cgarbs.de>
   3 #     2010 by Maximilian Rehkopf <otakon@gmx.net>
   4 #
   5 # licensed under GNU GPL v2
   6 #
   7 # A getter which will download the media to a local file storage
   8 # in the background using wget
   9 #
  10
  11 package videosite::AsyncWgetFileGetter;
  12
  13 use videosite::FileGetter;
  14 @ISA = qw(videosite::FileGetter);
  15
  16 use strict;
  17 use File::Basename;
  18 use File::Temp qw(tempfile);
  19 use MIME::Base64;
  20
  21 sub new {
  22     my $class = shift;
  23     my $self = $class->SUPER::new();
  24
  25     $self->{'NAME'} = 'asyncwgetfilegetter';
  26
  27     bless($self, $class);
  28     $self->_prepare_parameters();
  29
  30     return $self;
  31 }
  32
  33 sub get {
  34     my $self = shift;
  35     my $video = shift;
  36     my $dlfile;
  37     my $dirname;
  38     my $cookie = "";
  39
  40     $dlfile = sprintf($self->_getval('FILEPATTERN'),
  41         $self->_encode($video->{'SOURCE'}),
  42         $self->_encode($video->{'ID'}),
  43         $self->_encode($video->{'TITLE'}),
  44         $self->_encode($video->{'DLURL'}),
  45         $self->_encode($video)->{'URL'});
  46
  47     $dlfile =~ s/([\\"])/\\$1/g;
  48
  49     $dirname = dirname($dlfile);
  50     if ($self->_diskfree($dirname) < $self->_getval('MINFREE')) {
  51         $self->error("Not enough free space to download");
  52         return 0;
  53     }
  54
  55     $self->debug('Going to download %s to %s', $video->{'DLURL'}, $dlfile);
  56
  57     my (undef, $tmpfile) = tempfile('videosite.tmp.XXXXXXXXXXXX', DIR => $dirname);
  58
  59     my %saved_env;
  60
  61     if (exists($video->{'CONNECTOR'})) {
  62         my $schemas = $video->{'CONNECTOR'}->{'schemas'};
  63         foreach my $schemakey(keys(%{$schemas})) {
  64             $self->debug("Setting %s_proxy to %s", $schemakey, $schemas->{$schemakey});
  65             my $envkey = $schemakey.'_proxy';
  66             $saved_env{ $envkey } = $ENV{ $envkey };
  67             $ENV{ $envkey } = $schemas->{$schemakey};
  68         }
  69     }
  70
  71     $cookie = "--header=\"Cookie: $video->{'COOKIE'}\"" if (defined $video->{'COOKIE'});
  72     my $cmdline = "( wget -q -O\"$tmpfile\" $cookie \"$video->{'DLURL'}\" && mv \"$tmpfile\" \"$dlfile\" && chmod =rw \"$dlfile\" && touch \"$dlfile\" || rm -f \"$tmpfile\" ) &";
  73     $self->debug("Going to execute: %s", $cmdline);
  74     system($cmdline);
  75
  76     # restore environment
  77     foreach my $envkey (keys %saved_env) {
  78         $self->debug("Restoring environment: %s=%s", $envkey, $saved_env{ $envkey} );
  79         $ENV{ $envkey } = $saved_env{ $envkey };
  80     }
  81
  82     return 1;
  83 }