config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  11         ZFS_AC_KERNEL_TYPE_FMODE_T
  12         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  13         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  14         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  15         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  16         ZFS_AC_KERNEL_LOOKUP_BDEV
  17         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  18         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  19         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  20         ZFS_AC_KERNEL_BIO_FAILFAST
  21         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  22         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  23         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  24         ZFS_AC_KERNEL_BIO_RW_SYNC
  25         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  26         ZFS_AC_KERNEL_REQ_SYNC
  27         ZFS_AC_KERNEL_BLK_END_REQUEST
  28         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  31         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  32         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  33         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  34         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  35         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  36         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  37         ZFS_AC_KERNEL_BLK_RQ_BYTES
  38         ZFS_AC_KERNEL_BLK_RQ_POS
  39         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  40         ZFS_AC_KERNEL_GET_DISK_RO
  41         ZFS_AC_KERNEL_GET_GENDISK
  42         ZFS_AC_KERNEL_RQ_IS_SYNC
  43         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  44         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  45         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  46         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  47         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  48         ZFS_AC_KERNEL_SHOW_OPTIONS
  49         ZFS_AC_KERNEL_FSYNC
  50         ZFS_AC_KERNEL_EVICT_INODE
  51         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  52         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  54         ZFS_AC_KERNEL_FALLOCATE
  55         ZFS_AC_KERNEL_MKDIR_UMODE_T
  56         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  57         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  58         ZFS_AC_KERNEL_TRUNCATE_RANGE
  59         ZFS_AC_KERNEL_AUTOMOUNT
  60         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  61         ZFS_AC_KERNEL_COMMIT_METADATA
  62         ZFS_AC_KERNEL_CLEAR_INODE
  63         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  64         ZFS_AC_KERNEL_D_MAKE_ROOT
  65         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  66         ZFS_AC_KERNEL_D_SET_D_OP
  67         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  68         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  69         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  70         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  71         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  72         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  73         ZFS_AC_KERNEL_MOUNT_NODEV
  74         ZFS_AC_KERNEL_SHRINK
  75         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  76         ZFS_AC_KERNEL_S_D_OP
  77         ZFS_AC_KERNEL_BDI
  78         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  79         ZFS_AC_KERNEL_SET_NLINK
  80         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  81         ZFS_AC_KERNEL_5ARG_SGET
  82         ZFS_AC_KERNEL_LSEEK_EXECUTE
  83         ZFS_AC_KERNEL_VFS_ITERATE
  84
  85         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  86                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  87         ])
  88         AC_SUBST(KERNELMAKE_PARAMS)
  89
  90
  91         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  92         dnl # compiler options are added by the kernel build system.
  93         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  94         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  95         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  96
  97         AC_SUBST(KERNELCPPFLAGS)
  98 ])
  99
 100 dnl #
 101 dnl # Detect name used for Module.symvers file in kernel
 102 dnl #
 103 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 104         modpost=$LINUX/scripts/Makefile.modpost
 105         AC_MSG_CHECKING([kernel file name for module symbols])
 106         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 107                 AS_IF([grep -q Modules.symvers $modpost], [
 108                         LINUX_SYMBOLS=Modules.symvers
 109                 ], [
 110                         LINUX_SYMBOLS=Module.symvers
 111                 ])
 112
 113                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 114                         AC_MSG_ERROR([
 115         *** Please make sure the kernel devel package for your distribution
 116         *** is installed.  If you are building with a custom kernel, make sure the
 117         *** kernel is configured, built, and the '--with-linux=PATH' configure
 118         *** option refers to the location of the kernel source.])
 119                 ])
 120         ], [
 121                 LINUX_SYMBOLS=NONE
 122         ])
 123         AC_MSG_RESULT($LINUX_SYMBOLS)
 124         AC_SUBST(LINUX_SYMBOLS)
 125 ])
 126
 127 dnl #
 128 dnl # Detect the kernel to be built against
 129 dnl #
 130 AC_DEFUN([ZFS_AC_KERNEL], [
 131         AC_ARG_WITH([linux],
 132                 AS_HELP_STRING([--with-linux=PATH],
 133                 [Path to kernel source]),
 134                 [kernelsrc="$withval"])
 135
 136         AC_ARG_WITH(linux-obj,
 137                 AS_HELP_STRING([--with-linux-obj=PATH],
 138                 [Path to kernel build objects]),
 139                 [kernelbuild="$withval"])
 140
 141         AC_MSG_CHECKING([kernel source directory])
 142         AS_IF([test -z "$kernelsrc"], [
 143                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 144                         headersdir="/lib/modules/$(uname -r)/source"
 145                         sourcelink=$(readlink -f "$headersdir")
 146                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 147                         headersdir="/lib/modules/$(uname -r)/build"
 148                         sourcelink=$(readlink -f "$headersdir")
 149                 ], [
 150                         sourcelink=$(ls -1d /usr/src/kernels/* \
 151                                      /usr/src/linux-* \
 152                                      2>/dev/null | grep -v obj | tail -1)
 153                 ])
 154
 155                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 156                         kernelsrc=`readlink -f ${sourcelink}`
 157                 ], [
 158                         kernelsrc="[Not found]"
 159                 ])
 160         ], [
 161                 AS_IF([test "$kernelsrc" = "NONE"], [
 162                         kernsrcver=NONE
 163                 ])
 164         ])
 165
 166         AC_MSG_RESULT([$kernelsrc])
 167         AS_IF([test ! -d "$kernelsrc"], [
 168                 AC_MSG_ERROR([
 169         *** Please make sure the kernel devel package for your distribution
 170         *** is installed and then try again.  If that fails, you can specify the
 171         *** location of the kernel source with the '--with-linux=PATH' option.])
 172         ])
 173
 174         AC_MSG_CHECKING([kernel build directory])
 175         AS_IF([test -z "$kernelbuild"], [
 176                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 177                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 178                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 179                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 180                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 181                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 182                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 183                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 184                 ], [
 185                         kernelbuild=${kernelsrc}
 186                 ])
 187         ])
 188         AC_MSG_RESULT([$kernelbuild])
 189
 190         AC_MSG_CHECKING([kernel source version])
 191         utsrelease1=$kernelbuild/include/linux/version.h
 192         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 193         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 194         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 195                 utsrelease=linux/version.h
 196         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 197                 utsrelease=linux/utsrelease.h
 198         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 199                 utsrelease=generated/utsrelease.h
 200         ])
 201
 202         AS_IF([test "$utsrelease"], [
 203                 kernsrcver=`(echo "#include <$utsrelease>";
 204                              echo "kernsrcver=UTS_RELEASE") |
 205                              cpp -I $kernelbuild/include |
 206                              grep "^kernsrcver=" | cut -d \" -f 2`
 207
 208                 AS_IF([test -z "$kernsrcver"], [
 209                         AC_MSG_RESULT([Not found])
 210                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 211                 ])
 212         ], [
 213                 AC_MSG_RESULT([Not found])
 214                 if test "x$enable_linux_builtin" != xyes; then
 215                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 216                 else
 217                         AC_MSG_ERROR([
 218         *** Cannot find UTS_RELEASE definition.
 219         *** Please run 'make prepare' inside the kernel source tree.])
 220                 fi
 221         ])
 222
 223         AC_MSG_RESULT([$kernsrcver])
 224
 225         LINUX=${kernelsrc}
 226         LINUX_OBJ=${kernelbuild}
 227         LINUX_VERSION=${kernsrcver}
 228
 229         AC_SUBST(LINUX)
 230         AC_SUBST(LINUX_OBJ)
 231         AC_SUBST(LINUX_VERSION)
 232
 233         ZFS_AC_MODULE_SYMVERS
 234 ])
 235
 236
 237 dnl #
 238 dnl # Detect the SPL module to be built against
 239 dnl #
 240 AC_DEFUN([ZFS_AC_SPL], [
 241         AC_ARG_WITH([spl],
 242                 AS_HELP_STRING([--with-spl=PATH],
 243                 [Path to spl source]),
 244                 [splsrc="$withval"])
 245
 246         AC_ARG_WITH([spl-obj],
 247                 AS_HELP_STRING([--with-spl-obj=PATH],
 248                 [Path to spl build objects]),
 249                 [splbuild="$withval"])
 250
 251         AC_ARG_WITH([spl-timeout],
 252                 AS_HELP_STRING([--with-spl-timeout=SECS],
 253                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 254                 [timeout="$withval"], [timeout=0])
 255
 256         dnl #
 257         dnl # The existence of spl.release.in is used to identify a valid
 258         dnl # source directory.  In order of preference:
 259         dnl #
 260         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 261         splsrc1="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 262         splsrc2="/usr/src/spl-${VERSION}"
 263         splsrc3="../spl/"
 264         splsrc4="$LINUX"
 265
 266         AC_MSG_CHECKING([spl source directory])
 267         AS_IF([test -z "${splsrc}"], [
 268                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 269                         splsrc=${splsrc0}
 270                 ], [ test -e "${splsrc1}/spl.release.in"], [
 271                         splsrc=${splsrc1}
 272                 ], [ test -e "${splsrc2}/spl.release.in"], [
 273                         splsrc=${splsrc2}
 274                 ], [ test -e "${splsrc3}/spl.release.in"], [
 275                         splsrc=$(readlink -f "${splsrc3}")
 276                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 277                         splsrc=${splsrc4}
 278                 ], [
 279                         splsrc="[Not found]"
 280                 ])
 281         ], [
 282                 AS_IF([test "$splsrc" = "NONE"], [
 283                         splbuild=NONE
 284                         splsrcver=NONE
 285                 ])
 286         ])
 287
 288         AC_MSG_RESULT([$splsrc])
 289         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 290                 AC_MSG_ERROR([
 291         *** Please make sure the kmod spl devel package for your distribution
 292         *** is installed then try again.  If that fails you can specify the
 293         *** location of the spl source with the '--with-spl=PATH' option.])
 294         ])
 295
 296         dnl #
 297         dnl # The existence of the spl_config.h is used to identify a valid
 298         dnl # spl object directory.  In many cases the object and source
 299         dnl # directory are the same, however the objects may also reside
 300         dnl # is a subdirectory named after the kernel version.
 301         dnl #
 302         dnl # This file is supposed to be available after DKMS finishes
 303         dnl # building the SPL kernel module for the target kernel.  The
 304         dnl # '--with-spl-timeout' option can be passed to pause here,
 305         dnl # waiting for the file to appear from a concurrently building
 306         dnl # SPL package.
 307         dnl #
 308         AC_MSG_CHECKING([spl build directory])
 309         while true; do
 310                 AS_IF([test -z "$splbuild"], [
 311                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 312                                 splbuild="${splsrc}/${LINUX_VERSION}"
 313                         ], [ test -e "${splsrc}/spl_config.h" ], [
 314                                 splbuild="${splsrc}"
 315                         ], [
 316                                 splbuild="[Not found]"
 317                         ])
 318                 ])
 319                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 320                         break;
 321                 ], [
 322                         sleep 1
 323                         timeout=$((timeout-1))
 324                 ])
 325         done
 326
 327         AC_MSG_RESULT([$splbuild])
 328         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 329                 AC_MSG_ERROR([
 330         *** Please make sure the kmod spl devel <kernel> package for your
 331         *** distribution is installed then try again.  If that fails you
 332         *** can specify the location of the spl objects with the
 333         *** '--with-spl-obj=PATH' option.])
 334         ])
 335
 336         AC_MSG_CHECKING([spl source version])
 337         AS_IF([test -r $splbuild/spl_config.h &&
 338                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 339
 340                 splsrcver=`(echo "#include <spl_config.h>";
 341                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 342                             cpp -I $splbuild |
 343                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 344         ])
 345
 346         AS_IF([test -z "$splsrcver"], [
 347                 AC_MSG_RESULT([Not found])
 348                 AC_MSG_ERROR([
 349         *** Cannot determine the version of the spl source.
 350         *** Please prepare the spl source before running this script])
 351         ])
 352
 353         AC_MSG_RESULT([$splsrcver])
 354
 355         SPL=${splsrc}
 356         SPL_OBJ=${splbuild}
 357         SPL_VERSION=${splsrcver}
 358
 359         AC_SUBST(SPL)
 360         AC_SUBST(SPL_OBJ)
 361         AC_SUBST(SPL_VERSION)
 362
 363         dnl #
 364         dnl # Detect the name used for the SPL Module.symvers file.  If one
 365         dnl # does not exist this is likely because the SPL has been configured
 366         dnl # but not built.  The '--with-spl-timeout' option can be passed
 367         dnl # to pause here, waiting for the file to appear from a concurrently
 368         dnl # building SPL package.  If the file does not appear in time, a good
 369         dnl # guess is made as to what this file will be named based on what it
 370         dnl # is named in the kernel build products.  This file will first be
 371         dnl # used at link time so if the guess is wrong the build will fail
 372         dnl # then.  This unfortunately means the ZFS package does not contain a
 373         dnl # reliable mechanism to detect symbols exported by the SPL at
 374         dnl # configure time.
 375         dnl #
 376         AC_MSG_CHECKING([spl file name for module symbols])
 377         SPL_SYMBOLS=NONE
 378
 379         while true; do
 380                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 381                         SPL_SYMBOLS=Module.symvers
 382                 ], [test -r $SPL_OBJ/Modules.symvers], [
 383                         SPL_SYMBOLS=Modules.symvers
 384                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 385                         SPL_SYMBOLS=Module.symvers
 386                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 387                         SPL_SYMBOLS=Modules.symvers
 388                 ])
 389
 390                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 391                         break;
 392                 ], [
 393                         sleep 1
 394                         timeout=$((timeout-1))
 395                 ])
 396         done
 397
 398         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 399                 SPL_SYMBOLS=$LINUX_SYMBOLS
 400         ])
 401
 402         AC_MSG_RESULT([$SPL_SYMBOLS])
 403         AC_SUBST(SPL_SYMBOLS)
 404 ])
 405
 406 dnl #
 407 dnl # Basic toolchain sanity check.
 408 dnl #
 409 AC_DEFUN([ZFS_AC_TEST_MODULE],
 410         [AC_MSG_CHECKING([whether modules can be built])
 411         ZFS_LINUX_TRY_COMPILE([],[],[
 412                 AC_MSG_RESULT([yes])
 413         ],[
 414                 AC_MSG_RESULT([no])
 415                 if test "x$enable_linux_builtin" != xyes; then
 416                         AC_MSG_ERROR([*** Unable to build an empty module.])
 417                 else
 418                         AC_MSG_ERROR([
 419         *** Unable to build an empty module.
 420         *** Please run 'make scripts' inside the kernel source tree.])
 421                 fi
 422         ])
 423 ])
 424
 425 dnl #
 426 dnl # Certain kernel build options are not supported.  These must be
 427 dnl # detected at configure time and cause a build failure.  Otherwise
 428 dnl # modules may be successfully built that behave incorrectly.
 429 dnl #
 430 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 431
 432         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 433                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 434                         [Define to 1 if licensed under the GPL])
 435         ])
 436
 437         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 438 ])
 439
 440 dnl #
 441 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 442 dnl #
 443 dnl # This is typically only set for debug kernels because it comes with
 444 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 445 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 446 dnl # This will cause a failure at link time which we'd rather know about
 447 dnl # at compile time.
 448 dnl #
 449 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 450 dnl # with the upstream community we add a check to detect this case.
 451 dnl #
 452 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 453
 454         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 455                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 456                 tmp_flags="$EXTRA_KCFLAGS"
 457                 ZFS_LINUX_TRY_COMPILE([
 458                         #include <linux/module.h>
 459                         #include <linux/mutex.h>
 460
 461                         MODULE_LICENSE("$ZFS_META_LICENSE");
 462                 ],[
 463                         struct mutex lock;
 464
 465                         mutex_init(&lock);
 466                         mutex_lock(&lock);
 467                         mutex_unlock(&lock);
 468                 ],[
 469                         AC_MSG_RESULT(no)
 470                 ],[
 471                         AC_MSG_RESULT(yes)
 472                         AC_MSG_ERROR([
 473         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 474         *** with the CDDL license and will prevent the module linking stage
 475         *** from succeeding.  You must rebuild your kernel without this
 476         *** option enabled.])
 477                 ])
 478                 EXTRA_KCFLAGS="$tmp_flags"
 479         ], [])
 480 ])
 481
 482 dnl #
 483 dnl # ZFS_LINUX_CONFTEST
 484 dnl #
 485 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 486 cat confdefs.h - <<_ACEOF >conftest.c
 487 $1
 488 _ACEOF
 489 ])
 490
 491 dnl #
 492 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 493 dnl #
 494 m4_define([ZFS_LANG_PROGRAM], [
 495 $1
 496 int
 497 main (void)
 498 {
 499 dnl Do *not* indent the following line: there may be CPP directives.
 500 dnl Don't move the `;' right after for the same reason.
 501 $2
 502   ;
 503   return 0;
 504 }
 505 ])
 506
 507 dnl #
 508 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 509 dnl #
 510 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 511         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 512         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 513         echo "obj-m := conftest.o" >build/Makefile
 514         modpost_flag=''
 515         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 516         AS_IF(
 517                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 518                 [$4],
 519                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 520         )
 521         rm -Rf build
 522 ])
 523
 524 dnl #
 525 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 526 dnl #
 527 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 528         [ZFS_LINUX_COMPILE_IFELSE(
 529         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 530         [modules],
 531         [test -s build/conftest.o],
 532         [$3], [$4])
 533 ])
 534
 535 dnl #
 536 dnl # ZFS_LINUX_CONFIG
 537 dnl #
 538 AC_DEFUN([ZFS_LINUX_CONFIG],
 539         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 540         ZFS_LINUX_TRY_COMPILE([
 541                 #include <linux/module.h>
 542         ],[
 543                 #ifndef CONFIG_$1
 544                 #error CONFIG_$1 not #defined
 545                 #endif
 546         ],[
 547                 AC_MSG_RESULT([yes])
 548                 $2
 549         ],[
 550                 AC_MSG_RESULT([no])
 551                 $3
 552         ])
 553 ])
 554
 555 dnl #
 556 dnl # ZFS_CHECK_SYMBOL_EXPORT
 557 dnl # check symbol exported or not
 558 dnl #
 559 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 560         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 561                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 562         rc=$?
 563         if test $rc -ne 0; then
 564                 export=0
 565                 for file in $2; do
 566                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 567                                 "$LINUX/$file" 2>/dev/null
 568                         rc=$?
 569                         if test $rc -eq 0; then
 570                                 export=1
 571                                 break;
 572                         fi
 573                 done
 574                 if test $export -eq 0; then :
 575                         $4
 576                 else :
 577                         $3
 578                 fi
 579         else :
 580                 $3
 581         fi
 582 ])
 583
 584 dnl #
 585 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 586 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 587 dnl # is called if not compiling for builtin
 588 dnl #
 589 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 590         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 591         if test $rc -ne 0; then :
 592                 $6
 593         else
 594                 if test "x$enable_linux_builtin" != xyes; then
 595                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 596                 fi
 597                 if test $rc -ne 0; then :
 598                         $6
 599                 else :
 600                         $5
 601                 fi
 602         fi
 603 ])