config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_LOOKUP_BDEV
  16         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  17         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  19         ZFS_AC_KERNEL_BIO_FAILFAST
  20         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  21         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  22         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  23         ZFS_AC_KERNEL_BIO_RW_SYNC
  24         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  25         ZFS_AC_KERNEL_REQ_SYNC
  26         ZFS_AC_KERNEL_BLK_END_REQUEST
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  31         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  32         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  33         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  34         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  35         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_RQ_IS_SYNC
  42         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_SHOW_OPTIONS
  48         ZFS_AC_KERNEL_FSYNC
  49         ZFS_AC_KERNEL_EVICT_INODE
  50         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  51         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  52         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FALLOCATE
  54         ZFS_AC_KERNEL_MKDIR_UMODE_T
  55         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  56         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  57         ZFS_AC_KERNEL_TRUNCATE_RANGE
  58         ZFS_AC_KERNEL_AUTOMOUNT
  59         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  60         ZFS_AC_KERNEL_COMMIT_METADATA
  61         ZFS_AC_KERNEL_CLEAR_INODE
  62         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  63         ZFS_AC_KERNEL_D_MAKE_ROOT
  64         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  65         ZFS_AC_KERNEL_D_SET_D_OP
  66         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  67         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  68         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  69         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  70         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  71         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  72         ZFS_AC_KERNEL_MOUNT_NODEV
  73         ZFS_AC_KERNEL_SHRINK
  74         ZFS_AC_KERNEL_S_D_OP
  75         ZFS_AC_KERNEL_BDI
  76         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  77         ZFS_AC_KERNEL_SET_NLINK
  78         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  79         ZFS_AC_KERNEL_5ARG_SGET
  80         ZFS_AC_KERNEL_LSEEK_EXECUTE
  81
  82         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  83                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  84         ])
  85         AC_SUBST(KERNELMAKE_PARAMS)
  86
  87
  88         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  89         dnl # compiler options are added by the kernel build system.
  90         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  91         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  92         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  93
  94         AC_SUBST(KERNELCPPFLAGS)
  95 ])
  96
  97 dnl #
  98 dnl # Detect name used for Module.symvers file in kernel
  99 dnl #
 100 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 101         modpost=$LINUX/scripts/Makefile.modpost
 102         AC_MSG_CHECKING([kernel file name for module symbols])
 103         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 104                 AS_IF([grep -q Modules.symvers $modpost], [
 105                         LINUX_SYMBOLS=Modules.symvers
 106                 ], [
 107                         LINUX_SYMBOLS=Module.symvers
 108                 ])
 109
 110                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 111                         AC_MSG_ERROR([
 112         *** Please make sure the kernel devel package for your distribution
 113         *** is installed.  If you are building with a custom kernel, make sure the
 114         *** kernel is configured, built, and the '--with-linux=PATH' configure
 115         *** option refers to the location of the kernel source.])
 116                 ])
 117         ], [
 118                 LINUX_SYMBOLS=NONE
 119         ])
 120         AC_MSG_RESULT($LINUX_SYMBOLS)
 121         AC_SUBST(LINUX_SYMBOLS)
 122 ])
 123
 124 dnl #
 125 dnl # Detect the kernel to be built against
 126 dnl #
 127 AC_DEFUN([ZFS_AC_KERNEL], [
 128         AC_ARG_WITH([linux],
 129                 AS_HELP_STRING([--with-linux=PATH],
 130                 [Path to kernel source]),
 131                 [kernelsrc="$withval"])
 132
 133         AC_ARG_WITH(linux-obj,
 134                 AS_HELP_STRING([--with-linux-obj=PATH],
 135                 [Path to kernel build objects]),
 136                 [kernelbuild="$withval"])
 137
 138         AC_MSG_CHECKING([kernel source directory])
 139         AS_IF([test -z "$kernelsrc"], [
 140                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 141                         headersdir="/lib/modules/$(uname -r)/source"
 142                         sourcelink=$(readlink -f "$headersdir")
 143                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 144                         headersdir="/lib/modules/$(uname -r)/build"
 145                         sourcelink=$(readlink -f "$headersdir")
 146                 ], [
 147                         sourcelink=$(ls -1d /usr/src/kernels/* \
 148                                      /usr/src/linux-* \
 149                                      2>/dev/null | grep -v obj | tail -1)
 150                 ])
 151
 152                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 153                         kernelsrc=`readlink -f ${sourcelink}`
 154                 ], [
 155                         kernelsrc="[Not found]"
 156                 ])
 157         ], [
 158                 AS_IF([test "$kernelsrc" = "NONE"], [
 159                         kernsrcver=NONE
 160                 ])
 161         ])
 162
 163         AC_MSG_RESULT([$kernelsrc])
 164         AS_IF([test ! -d "$kernelsrc"], [
 165                 AC_MSG_ERROR([
 166         *** Please make sure the kernel devel package for your distribution
 167         *** is installed and then try again.  If that fails, you can specify the
 168         *** location of the kernel source with the '--with-linux=PATH' option.])
 169         ])
 170
 171         AC_MSG_CHECKING([kernel build directory])
 172         AS_IF([test -z "$kernelbuild"], [
 173                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 174                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 175                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 176                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 177                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 178                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 179                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 180                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 181                 ], [
 182                         kernelbuild=${kernelsrc}
 183                 ])
 184         ])
 185         AC_MSG_RESULT([$kernelbuild])
 186
 187         AC_MSG_CHECKING([kernel source version])
 188         utsrelease1=$kernelbuild/include/linux/version.h
 189         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 190         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 191         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 192                 utsrelease=linux/version.h
 193         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 194                 utsrelease=linux/utsrelease.h
 195         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 196                 utsrelease=generated/utsrelease.h
 197         ])
 198
 199         AS_IF([test "$utsrelease"], [
 200                 kernsrcver=`(echo "#include <$utsrelease>";
 201                              echo "kernsrcver=UTS_RELEASE") |
 202                              cpp -I $kernelbuild/include |
 203                              grep "^kernsrcver=" | cut -d \" -f 2`
 204
 205                 AS_IF([test -z "$kernsrcver"], [
 206                         AC_MSG_RESULT([Not found])
 207                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 208                 ])
 209         ], [
 210                 AC_MSG_RESULT([Not found])
 211                 if test "x$enable_linux_builtin" != xyes; then
 212                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 213                 else
 214                         AC_MSG_ERROR([
 215         *** Cannot find UTS_RELEASE definition.
 216         *** Please run 'make prepare' inside the kernel source tree.])
 217                 fi
 218         ])
 219
 220         AC_MSG_RESULT([$kernsrcver])
 221
 222         LINUX=${kernelsrc}
 223         LINUX_OBJ=${kernelbuild}
 224         LINUX_VERSION=${kernsrcver}
 225
 226         AC_SUBST(LINUX)
 227         AC_SUBST(LINUX_OBJ)
 228         AC_SUBST(LINUX_VERSION)
 229
 230         ZFS_AC_MODULE_SYMVERS
 231 ])
 232
 233
 234 dnl #
 235 dnl # Detect the SPL module to be built against
 236 dnl #
 237 AC_DEFUN([ZFS_AC_SPL], [
 238         AC_ARG_WITH([spl],
 239                 AS_HELP_STRING([--with-spl=PATH],
 240                 [Path to spl source]),
 241                 [splsrc="$withval"])
 242
 243         AC_ARG_WITH([spl-obj],
 244                 AS_HELP_STRING([--with-spl-obj=PATH],
 245                 [Path to spl build objects]),
 246                 [splbuild="$withval"])
 247
 248         AC_ARG_WITH([spl-timeout],
 249                 AS_HELP_STRING([--with-spl-timeout=SECS],
 250                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 251                 [timeout="$withval"], [timeout=0])
 252
 253         dnl #
 254         dnl # The existence of spl.release.in is used to identify a valid
 255         dnl # source directory.  In order of preference:
 256         dnl #
 257         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 258         splsrc1="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 259         splsrc2="/usr/src/spl-${VERSION}"
 260         splsrc3="../spl/"
 261         splsrc4="$LINUX"
 262
 263         AC_MSG_CHECKING([spl source directory])
 264         AS_IF([test -z "${splsrc}"], [
 265                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 266                         splsrc=${splsrc0}
 267                 ], [ test -e "${splsrc1}/spl.release.in"], [
 268                         splsrc=${splsrc1}
 269                 ], [ test -e "${splsrc2}/spl.release.in"], [
 270                         splsrc=${splsrc2}
 271                 ], [ test -e "${splsrc3}/spl.release.in"], [
 272                         splsrc=$(readlink -f "${splsrc3}")
 273                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 274                         splsrc=${splsrc4}
 275                 ], [
 276                         splsrc="[Not found]"
 277                 ])
 278         ], [
 279                 AS_IF([test "$splsrc" = "NONE"], [
 280                         splbuild=NONE
 281                         splsrcver=NONE
 282                 ])
 283         ])
 284
 285         AC_MSG_RESULT([$splsrc])
 286         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 287                 AC_MSG_ERROR([
 288         *** Please make sure the kmod spl devel package for your distribution
 289         *** is installed then try again.  If that fails you can specify the
 290         *** location of the spl source with the '--with-spl=PATH' option.])
 291         ])
 292
 293         dnl #
 294         dnl # The existence of the spl_config.h is used to identify a valid
 295         dnl # spl object directory.  In many cases the object and source
 296         dnl # directory are the same, however the objects may also reside
 297         dnl # is a subdirectory named after the kernel version.
 298         dnl #
 299         dnl # This file is supposed to be available after DKMS finishes
 300         dnl # building the SPL kernel module for the target kernel.  The
 301         dnl # '--with-spl-timeout' option can be passed to pause here,
 302         dnl # waiting for the file to appear from a concurrently building
 303         dnl # SPL package.
 304         dnl #
 305         AC_MSG_CHECKING([spl build directory])
 306         while true; do
 307                 AS_IF([test -z "$splbuild"], [
 308                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 309                                 splbuild="${splsrc}/${LINUX_VERSION}"
 310                         ], [ test -e "${splsrc}/spl_config.h" ], [
 311                                 splbuild="${splsrc}"
 312                         ], [
 313                                 splbuild="[Not found]"
 314                         ])
 315                 ])
 316                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 317                         break;
 318                 ], [
 319                         sleep 1
 320                         timeout=$((timeout-1))
 321                 ])
 322         done
 323
 324         AC_MSG_RESULT([$splbuild])
 325         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 326                 AC_MSG_ERROR([
 327         *** Please make sure the kmod spl devel <kernel> package for your
 328         *** distribution is installed then try again.  If that fails you
 329         *** can specify the location of the spl objects with the
 330         *** '--with-spl-obj=PATH' option.])
 331         ])
 332
 333         AC_MSG_CHECKING([spl source version])
 334         AS_IF([test -r $splbuild/spl_config.h &&
 335                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 336
 337                 splsrcver=`(echo "#include <spl_config.h>";
 338                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 339                             cpp -I $splbuild |
 340                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 341         ])
 342
 343         AS_IF([test -z "$splsrcver"], [
 344                 AC_MSG_RESULT([Not found])
 345                 AC_MSG_ERROR([
 346         *** Cannot determine the version of the spl source.
 347         *** Please prepare the spl source before running this script])
 348         ])
 349
 350         AC_MSG_RESULT([$splsrcver])
 351
 352         SPL=${splsrc}
 353         SPL_OBJ=${splbuild}
 354         SPL_VERSION=${splsrcver}
 355
 356         AC_SUBST(SPL)
 357         AC_SUBST(SPL_OBJ)
 358         AC_SUBST(SPL_VERSION)
 359
 360         dnl #
 361         dnl # Detect the name used for the SPL Module.symvers file.  If one
 362         dnl # does not exist this is likely because the SPL has been configured
 363         dnl # but not built.  The '--with-spl-timeout' option can be passed
 364         dnl # to pause here, waiting for the file to appear from a concurrently
 365         dnl # building SPL package.  If the file does not appear in time, a good
 366         dnl # guess is made as to what this file will be named based on what it
 367         dnl # is named in the kernel build products.  This file will first be
 368         dnl # used at link time so if the guess is wrong the build will fail
 369         dnl # then.  This unfortunately means the ZFS package does not contain a
 370         dnl # reliable mechanism to detect symbols exported by the SPL at
 371         dnl # configure time.
 372         dnl #
 373         AC_MSG_CHECKING([spl file name for module symbols])
 374         SPL_SYMBOLS=NONE
 375
 376         while true; do
 377                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 378                         SPL_SYMBOLS=Module.symvers
 379                 ], [test -r $SPL_OBJ/Modules.symvers], [
 380                         SPL_SYMBOLS=Modules.symvers
 381                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 382                         SPL_SYMBOLS=Module.symvers
 383                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 384                         SPL_SYMBOLS=Modules.symvers
 385                 ])
 386
 387                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 388                         break;
 389                 ], [
 390                         sleep 1
 391                         timeout=$((timeout-1))
 392                 ])
 393         done
 394
 395         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 396                 SPL_SYMBOLS=$LINUX_SYMBOLS
 397         ])
 398
 399         AC_MSG_RESULT([$SPL_SYMBOLS])
 400         AC_SUBST(SPL_SYMBOLS)
 401 ])
 402
 403 dnl #
 404 dnl # Basic toolchain sanity check.
 405 dnl #
 406 AC_DEFUN([ZFS_AC_TEST_MODULE],
 407         [AC_MSG_CHECKING([whether modules can be built])
 408         ZFS_LINUX_TRY_COMPILE([],[],[
 409                 AC_MSG_RESULT([yes])
 410         ],[
 411                 AC_MSG_RESULT([no])
 412                 if test "x$enable_linux_builtin" != xyes; then
 413                         AC_MSG_ERROR([*** Unable to build an empty module.])
 414                 else
 415                         AC_MSG_ERROR([
 416         *** Unable to build an empty module.
 417         *** Please run 'make scripts' inside the kernel source tree.])
 418                 fi
 419         ])
 420 ])
 421
 422 dnl #
 423 dnl # Certain kernel build options are not supported.  These must be
 424 dnl # detected at configure time and cause a build failure.  Otherwise
 425 dnl # modules may be successfully built that behave incorrectly.
 426 dnl #
 427 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 428
 429         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 430                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 431                         [Define to 1 if licensed under the GPL])
 432         ])
 433
 434         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 435 ])
 436
 437 dnl #
 438 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 439 dnl #
 440 dnl # This is typically only set for debug kernels because it comes with
 441 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 442 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 443 dnl # This will cause a failure at link time which we'd rather know about
 444 dnl # at compile time.
 445 dnl #
 446 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 447 dnl # with the upstream community we add a check to detect this case.
 448 dnl #
 449 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 450
 451         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 452                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 453                 tmp_flags="$EXTRA_KCFLAGS"
 454                 ZFS_LINUX_TRY_COMPILE([
 455                         #include <linux/module.h>
 456                         #include <linux/mutex.h>
 457
 458                         MODULE_LICENSE("$ZFS_META_LICENSE");
 459                 ],[
 460                         struct mutex lock;
 461
 462                         mutex_init(&lock);
 463                         mutex_lock(&lock);
 464                         mutex_unlock(&lock);
 465                 ],[
 466                         AC_MSG_RESULT(no)
 467                 ],[
 468                         AC_MSG_RESULT(yes)
 469                         AC_MSG_ERROR([
 470         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 471         *** with the CDDL license and will prevent the module linking stage
 472         *** from succeeding.  You must rebuild your kernel without this
 473         *** option enabled.])
 474                 ])
 475                 EXTRA_KCFLAGS="$tmp_flags"
 476         ], [])
 477 ])
 478
 479 dnl #
 480 dnl # ZFS_LINUX_CONFTEST
 481 dnl #
 482 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 483 cat confdefs.h - <<_ACEOF >conftest.c
 484 $1
 485 _ACEOF
 486 ])
 487
 488 dnl #
 489 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 490 dnl #
 491 m4_define([ZFS_LANG_PROGRAM], [
 492 $1
 493 int
 494 main (void)
 495 {
 496 dnl Do *not* indent the following line: there may be CPP directives.
 497 dnl Don't move the `;' right after for the same reason.
 498 $2
 499   ;
 500   return 0;
 501 }
 502 ])
 503
 504 dnl #
 505 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 506 dnl #
 507 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 508         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 509         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 510         echo "obj-m := conftest.o" >build/Makefile
 511         modpost_flag=''
 512         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 513         AS_IF(
 514                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 515                 [$4],
 516                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 517         )
 518         rm -Rf build
 519 ])
 520
 521 dnl #
 522 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 523 dnl #
 524 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 525         [ZFS_LINUX_COMPILE_IFELSE(
 526         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 527         [modules],
 528         [test -s build/conftest.o],
 529         [$3], [$4])
 530 ])
 531
 532 dnl #
 533 dnl # ZFS_LINUX_CONFIG
 534 dnl #
 535 AC_DEFUN([ZFS_LINUX_CONFIG],
 536         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 537         ZFS_LINUX_TRY_COMPILE([
 538                 #include <linux/module.h>
 539         ],[
 540                 #ifndef CONFIG_$1
 541                 #error CONFIG_$1 not #defined
 542                 #endif
 543         ],[
 544                 AC_MSG_RESULT([yes])
 545                 $2
 546         ],[
 547                 AC_MSG_RESULT([no])
 548                 $3
 549         ])
 550 ])
 551
 552 dnl #
 553 dnl # ZFS_CHECK_SYMBOL_EXPORT
 554 dnl # check symbol exported or not
 555 dnl #
 556 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 557         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 558                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 559         rc=$?
 560         if test $rc -ne 0; then
 561                 export=0
 562                 for file in $2; do
 563                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 564                                 "$LINUX/$file" 2>/dev/null
 565                         rc=$?
 566                         if test $rc -eq 0; then
 567                                 export=1
 568                                 break;
 569                         fi
 570                 done
 571                 if test $export -eq 0; then :
 572                         $4
 573                 else :
 574                         $3
 575                 fi
 576         else :
 577                 $3
 578         fi
 579 ])
 580
 581 dnl #
 582 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 583 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 584 dnl # is called if not compiling for builtin
 585 dnl #
 586 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 587         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 588         if test $rc -ne 0; then :
 589                 $6
 590         else
 591                 if test "x$enable_linux_builtin" != xyes; then
 592                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 593                 fi
 594                 if test $rc -ne 0; then :
 595                         $6
 596                 else :
 597                         $5
 598                 fi
 599         fi
 600 ])