config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  11         ZFS_AC_KERNEL_TYPE_FMODE_T
  12         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  13         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  14         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  15         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  16         ZFS_AC_KERNEL_LOOKUP_BDEV
  17         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  18         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  19         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  20         ZFS_AC_KERNEL_BIO_FAILFAST
  21         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  22         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  23         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  24         ZFS_AC_KERNEL_BIO_RW_SYNC
  25         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  26         ZFS_AC_KERNEL_REQ_SYNC
  27         ZFS_AC_KERNEL_BLK_END_REQUEST
  28         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  31         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  32         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  33         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  34         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  35         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  36         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  37         ZFS_AC_KERNEL_BLK_RQ_BYTES
  38         ZFS_AC_KERNEL_BLK_RQ_POS
  39         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  40         ZFS_AC_KERNEL_GET_DISK_RO
  41         ZFS_AC_KERNEL_GET_GENDISK
  42         ZFS_AC_KERNEL_RQ_IS_SYNC
  43         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  44         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  45         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  46         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  47         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  48         ZFS_AC_KERNEL_SHOW_OPTIONS
  49         ZFS_AC_KERNEL_FSYNC
  50         ZFS_AC_KERNEL_EVICT_INODE
  51         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  52         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  54         ZFS_AC_KERNEL_FALLOCATE
  55         ZFS_AC_KERNEL_MKDIR_UMODE_T
  56         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  57         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  58         ZFS_AC_KERNEL_TRUNCATE_RANGE
  59         ZFS_AC_KERNEL_AUTOMOUNT
  60         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  61         ZFS_AC_KERNEL_COMMIT_METADATA
  62         ZFS_AC_KERNEL_CLEAR_INODE
  63         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  64         ZFS_AC_KERNEL_D_MAKE_ROOT
  65         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  66         ZFS_AC_KERNEL_D_SET_D_OP
  67         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  68         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  69         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  70         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  71         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  72         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  73         ZFS_AC_KERNEL_MOUNT_NODEV
  74         ZFS_AC_KERNEL_SHRINK
  75         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  76         ZFS_AC_KERNEL_S_D_OP
  77         ZFS_AC_KERNEL_BDI
  78         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  79         ZFS_AC_KERNEL_SET_NLINK
  80         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  81         ZFS_AC_KERNEL_5ARG_SGET
  82         ZFS_AC_KERNEL_LSEEK_EXECUTE
  83
  84         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  85                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  86         ])
  87         AC_SUBST(KERNELMAKE_PARAMS)
  88
  89
  90         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  91         dnl # compiler options are added by the kernel build system.
  92         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  93         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  94         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  95
  96         AC_SUBST(KERNELCPPFLAGS)
  97 ])
  98
  99 dnl #
 100 dnl # Detect name used for Module.symvers file in kernel
 101 dnl #
 102 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 103         modpost=$LINUX/scripts/Makefile.modpost
 104         AC_MSG_CHECKING([kernel file name for module symbols])
 105         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 106                 AS_IF([grep -q Modules.symvers $modpost], [
 107                         LINUX_SYMBOLS=Modules.symvers
 108                 ], [
 109                         LINUX_SYMBOLS=Module.symvers
 110                 ])
 111
 112                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 113                         AC_MSG_ERROR([
 114         *** Please make sure the kernel devel package for your distribution
 115         *** is installed.  If you are building with a custom kernel, make sure the
 116         *** kernel is configured, built, and the '--with-linux=PATH' configure
 117         *** option refers to the location of the kernel source.])
 118                 ])
 119         ], [
 120                 LINUX_SYMBOLS=NONE
 121         ])
 122         AC_MSG_RESULT($LINUX_SYMBOLS)
 123         AC_SUBST(LINUX_SYMBOLS)
 124 ])
 125
 126 dnl #
 127 dnl # Detect the kernel to be built against
 128 dnl #
 129 AC_DEFUN([ZFS_AC_KERNEL], [
 130         AC_ARG_WITH([linux],
 131                 AS_HELP_STRING([--with-linux=PATH],
 132                 [Path to kernel source]),
 133                 [kernelsrc="$withval"])
 134
 135         AC_ARG_WITH(linux-obj,
 136                 AS_HELP_STRING([--with-linux-obj=PATH],
 137                 [Path to kernel build objects]),
 138                 [kernelbuild="$withval"])
 139
 140         AC_MSG_CHECKING([kernel source directory])
 141         AS_IF([test -z "$kernelsrc"], [
 142                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 143                         headersdir="/lib/modules/$(uname -r)/source"
 144                         sourcelink=$(readlink -f "$headersdir")
 145                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 146                         headersdir="/lib/modules/$(uname -r)/build"
 147                         sourcelink=$(readlink -f "$headersdir")
 148                 ], [
 149                         sourcelink=$(ls -1d /usr/src/kernels/* \
 150                                      /usr/src/linux-* \
 151                                      2>/dev/null | grep -v obj | tail -1)
 152                 ])
 153
 154                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 155                         kernelsrc=`readlink -f ${sourcelink}`
 156                 ], [
 157                         kernelsrc="[Not found]"
 158                 ])
 159         ], [
 160                 AS_IF([test "$kernelsrc" = "NONE"], [
 161                         kernsrcver=NONE
 162                 ])
 163         ])
 164
 165         AC_MSG_RESULT([$kernelsrc])
 166         AS_IF([test ! -d "$kernelsrc"], [
 167                 AC_MSG_ERROR([
 168         *** Please make sure the kernel devel package for your distribution
 169         *** is installed and then try again.  If that fails, you can specify the
 170         *** location of the kernel source with the '--with-linux=PATH' option.])
 171         ])
 172
 173         AC_MSG_CHECKING([kernel build directory])
 174         AS_IF([test -z "$kernelbuild"], [
 175                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 176                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 177                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 178                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 179                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 180                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 181                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 182                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 183                 ], [
 184                         kernelbuild=${kernelsrc}
 185                 ])
 186         ])
 187         AC_MSG_RESULT([$kernelbuild])
 188
 189         AC_MSG_CHECKING([kernel source version])
 190         utsrelease1=$kernelbuild/include/linux/version.h
 191         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 192         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 193         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 194                 utsrelease=linux/version.h
 195         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 196                 utsrelease=linux/utsrelease.h
 197         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 198                 utsrelease=generated/utsrelease.h
 199         ])
 200
 201         AS_IF([test "$utsrelease"], [
 202                 kernsrcver=`(echo "#include <$utsrelease>";
 203                              echo "kernsrcver=UTS_RELEASE") |
 204                              cpp -I $kernelbuild/include |
 205                              grep "^kernsrcver=" | cut -d \" -f 2`
 206
 207                 AS_IF([test -z "$kernsrcver"], [
 208                         AC_MSG_RESULT([Not found])
 209                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 210                 ])
 211         ], [
 212                 AC_MSG_RESULT([Not found])
 213                 if test "x$enable_linux_builtin" != xyes; then
 214                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 215                 else
 216                         AC_MSG_ERROR([
 217         *** Cannot find UTS_RELEASE definition.
 218         *** Please run 'make prepare' inside the kernel source tree.])
 219                 fi
 220         ])
 221
 222         AC_MSG_RESULT([$kernsrcver])
 223
 224         LINUX=${kernelsrc}
 225         LINUX_OBJ=${kernelbuild}
 226         LINUX_VERSION=${kernsrcver}
 227
 228         AC_SUBST(LINUX)
 229         AC_SUBST(LINUX_OBJ)
 230         AC_SUBST(LINUX_VERSION)
 231
 232         ZFS_AC_MODULE_SYMVERS
 233 ])
 234
 235
 236 dnl #
 237 dnl # Detect the SPL module to be built against
 238 dnl #
 239 AC_DEFUN([ZFS_AC_SPL], [
 240         AC_ARG_WITH([spl],
 241                 AS_HELP_STRING([--with-spl=PATH],
 242                 [Path to spl source]),
 243                 [splsrc="$withval"])
 244
 245         AC_ARG_WITH([spl-obj],
 246                 AS_HELP_STRING([--with-spl-obj=PATH],
 247                 [Path to spl build objects]),
 248                 [splbuild="$withval"])
 249
 250         AC_ARG_WITH([spl-timeout],
 251                 AS_HELP_STRING([--with-spl-timeout=SECS],
 252                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 253                 [timeout="$withval"], [timeout=0])
 254
 255         dnl #
 256         dnl # The existence of spl.release.in is used to identify a valid
 257         dnl # source directory.  In order of preference:
 258         dnl #
 259         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 260         splsrc1="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 261         splsrc2="/usr/src/spl-${VERSION}"
 262         splsrc3="../spl/"
 263         splsrc4="$LINUX"
 264
 265         AC_MSG_CHECKING([spl source directory])
 266         AS_IF([test -z "${splsrc}"], [
 267                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 268                         splsrc=${splsrc0}
 269                 ], [ test -e "${splsrc1}/spl.release.in"], [
 270                         splsrc=${splsrc1}
 271                 ], [ test -e "${splsrc2}/spl.release.in"], [
 272                         splsrc=${splsrc2}
 273                 ], [ test -e "${splsrc3}/spl.release.in"], [
 274                         splsrc=$(readlink -f "${splsrc3}")
 275                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 276                         splsrc=${splsrc4}
 277                 ], [
 278                         splsrc="[Not found]"
 279                 ])
 280         ], [
 281                 AS_IF([test "$splsrc" = "NONE"], [
 282                         splbuild=NONE
 283                         splsrcver=NONE
 284                 ])
 285         ])
 286
 287         AC_MSG_RESULT([$splsrc])
 288         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 289                 AC_MSG_ERROR([
 290         *** Please make sure the kmod spl devel package for your distribution
 291         *** is installed then try again.  If that fails you can specify the
 292         *** location of the spl source with the '--with-spl=PATH' option.])
 293         ])
 294
 295         dnl #
 296         dnl # The existence of the spl_config.h is used to identify a valid
 297         dnl # spl object directory.  In many cases the object and source
 298         dnl # directory are the same, however the objects may also reside
 299         dnl # is a subdirectory named after the kernel version.
 300         dnl #
 301         dnl # This file is supposed to be available after DKMS finishes
 302         dnl # building the SPL kernel module for the target kernel.  The
 303         dnl # '--with-spl-timeout' option can be passed to pause here,
 304         dnl # waiting for the file to appear from a concurrently building
 305         dnl # SPL package.
 306         dnl #
 307         AC_MSG_CHECKING([spl build directory])
 308         while true; do
 309                 AS_IF([test -z "$splbuild"], [
 310                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 311                                 splbuild="${splsrc}/${LINUX_VERSION}"
 312                         ], [ test -e "${splsrc}/spl_config.h" ], [
 313                                 splbuild="${splsrc}"
 314                         ], [
 315                                 splbuild="[Not found]"
 316                         ])
 317                 ])
 318                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 319                         break;
 320                 ], [
 321                         sleep 1
 322                         timeout=$((timeout-1))
 323                 ])
 324         done
 325
 326         AC_MSG_RESULT([$splbuild])
 327         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 328                 AC_MSG_ERROR([
 329         *** Please make sure the kmod spl devel <kernel> package for your
 330         *** distribution is installed then try again.  If that fails you
 331         *** can specify the location of the spl objects with the
 332         *** '--with-spl-obj=PATH' option.])
 333         ])
 334
 335         AC_MSG_CHECKING([spl source version])
 336         AS_IF([test -r $splbuild/spl_config.h &&
 337                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 338
 339                 splsrcver=`(echo "#include <spl_config.h>";
 340                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 341                             cpp -I $splbuild |
 342                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 343         ])
 344
 345         AS_IF([test -z "$splsrcver"], [
 346                 AC_MSG_RESULT([Not found])
 347                 AC_MSG_ERROR([
 348         *** Cannot determine the version of the spl source.
 349         *** Please prepare the spl source before running this script])
 350         ])
 351
 352         AC_MSG_RESULT([$splsrcver])
 353
 354         SPL=${splsrc}
 355         SPL_OBJ=${splbuild}
 356         SPL_VERSION=${splsrcver}
 357
 358         AC_SUBST(SPL)
 359         AC_SUBST(SPL_OBJ)
 360         AC_SUBST(SPL_VERSION)
 361
 362         dnl #
 363         dnl # Detect the name used for the SPL Module.symvers file.  If one
 364         dnl # does not exist this is likely because the SPL has been configured
 365         dnl # but not built.  The '--with-spl-timeout' option can be passed
 366         dnl # to pause here, waiting for the file to appear from a concurrently
 367         dnl # building SPL package.  If the file does not appear in time, a good
 368         dnl # guess is made as to what this file will be named based on what it
 369         dnl # is named in the kernel build products.  This file will first be
 370         dnl # used at link time so if the guess is wrong the build will fail
 371         dnl # then.  This unfortunately means the ZFS package does not contain a
 372         dnl # reliable mechanism to detect symbols exported by the SPL at
 373         dnl # configure time.
 374         dnl #
 375         AC_MSG_CHECKING([spl file name for module symbols])
 376         SPL_SYMBOLS=NONE
 377
 378         while true; do
 379                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 380                         SPL_SYMBOLS=Module.symvers
 381                 ], [test -r $SPL_OBJ/Modules.symvers], [
 382                         SPL_SYMBOLS=Modules.symvers
 383                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 384                         SPL_SYMBOLS=Module.symvers
 385                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 386                         SPL_SYMBOLS=Modules.symvers
 387                 ])
 388
 389                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 390                         break;
 391                 ], [
 392                         sleep 1
 393                         timeout=$((timeout-1))
 394                 ])
 395         done
 396
 397         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 398                 SPL_SYMBOLS=$LINUX_SYMBOLS
 399         ])
 400
 401         AC_MSG_RESULT([$SPL_SYMBOLS])
 402         AC_SUBST(SPL_SYMBOLS)
 403 ])
 404
 405 dnl #
 406 dnl # Basic toolchain sanity check.
 407 dnl #
 408 AC_DEFUN([ZFS_AC_TEST_MODULE],
 409         [AC_MSG_CHECKING([whether modules can be built])
 410         ZFS_LINUX_TRY_COMPILE([],[],[
 411                 AC_MSG_RESULT([yes])
 412         ],[
 413                 AC_MSG_RESULT([no])
 414                 if test "x$enable_linux_builtin" != xyes; then
 415                         AC_MSG_ERROR([*** Unable to build an empty module.])
 416                 else
 417                         AC_MSG_ERROR([
 418         *** Unable to build an empty module.
 419         *** Please run 'make scripts' inside the kernel source tree.])
 420                 fi
 421         ])
 422 ])
 423
 424 dnl #
 425 dnl # Certain kernel build options are not supported.  These must be
 426 dnl # detected at configure time and cause a build failure.  Otherwise
 427 dnl # modules may be successfully built that behave incorrectly.
 428 dnl #
 429 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 430
 431         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 432                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 433                         [Define to 1 if licensed under the GPL])
 434         ])
 435
 436         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 437 ])
 438
 439 dnl #
 440 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 441 dnl #
 442 dnl # This is typically only set for debug kernels because it comes with
 443 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 444 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 445 dnl # This will cause a failure at link time which we'd rather know about
 446 dnl # at compile time.
 447 dnl #
 448 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 449 dnl # with the upstream community we add a check to detect this case.
 450 dnl #
 451 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 452
 453         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 454                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 455                 tmp_flags="$EXTRA_KCFLAGS"
 456                 ZFS_LINUX_TRY_COMPILE([
 457                         #include <linux/module.h>
 458                         #include <linux/mutex.h>
 459
 460                         MODULE_LICENSE("$ZFS_META_LICENSE");
 461                 ],[
 462                         struct mutex lock;
 463
 464                         mutex_init(&lock);
 465                         mutex_lock(&lock);
 466                         mutex_unlock(&lock);
 467                 ],[
 468                         AC_MSG_RESULT(no)
 469                 ],[
 470                         AC_MSG_RESULT(yes)
 471                         AC_MSG_ERROR([
 472         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 473         *** with the CDDL license and will prevent the module linking stage
 474         *** from succeeding.  You must rebuild your kernel without this
 475         *** option enabled.])
 476                 ])
 477                 EXTRA_KCFLAGS="$tmp_flags"
 478         ], [])
 479 ])
 480
 481 dnl #
 482 dnl # ZFS_LINUX_CONFTEST
 483 dnl #
 484 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 485 cat confdefs.h - <<_ACEOF >conftest.c
 486 $1
 487 _ACEOF
 488 ])
 489
 490 dnl #
 491 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 492 dnl #
 493 m4_define([ZFS_LANG_PROGRAM], [
 494 $1
 495 int
 496 main (void)
 497 {
 498 dnl Do *not* indent the following line: there may be CPP directives.
 499 dnl Don't move the `;' right after for the same reason.
 500 $2
 501   ;
 502   return 0;
 503 }
 504 ])
 505
 506 dnl #
 507 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 508 dnl #
 509 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 510         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 511         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 512         echo "obj-m := conftest.o" >build/Makefile
 513         modpost_flag=''
 514         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 515         AS_IF(
 516                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 517                 [$4],
 518                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 519         )
 520         rm -Rf build
 521 ])
 522
 523 dnl #
 524 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 525 dnl #
 526 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 527         [ZFS_LINUX_COMPILE_IFELSE(
 528         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 529         [modules],
 530         [test -s build/conftest.o],
 531         [$3], [$4])
 532 ])
 533
 534 dnl #
 535 dnl # ZFS_LINUX_CONFIG
 536 dnl #
 537 AC_DEFUN([ZFS_LINUX_CONFIG],
 538         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 539         ZFS_LINUX_TRY_COMPILE([
 540                 #include <linux/module.h>
 541         ],[
 542                 #ifndef CONFIG_$1
 543                 #error CONFIG_$1 not #defined
 544                 #endif
 545         ],[
 546                 AC_MSG_RESULT([yes])
 547                 $2
 548         ],[
 549                 AC_MSG_RESULT([no])
 550                 $3
 551         ])
 552 ])
 553
 554 dnl #
 555 dnl # ZFS_CHECK_SYMBOL_EXPORT
 556 dnl # check symbol exported or not
 557 dnl #
 558 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 559         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 560                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 561         rc=$?
 562         if test $rc -ne 0; then
 563                 export=0
 564                 for file in $2; do
 565                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 566                                 "$LINUX/$file" 2>/dev/null
 567                         rc=$?
 568                         if test $rc -eq 0; then
 569                                 export=1
 570                                 break;
 571                         fi
 572                 done
 573                 if test $export -eq 0; then :
 574                         $4
 575                 else :
 576                         $3
 577                 fi
 578         else :
 579                 $3
 580         fi
 581 ])
 582
 583 dnl #
 584 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 585 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 586 dnl # is called if not compiling for builtin
 587 dnl #
 588 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 589         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 590         if test $rc -ne 0; then :
 591                 $6
 592         else
 593                 if test "x$enable_linux_builtin" != xyes; then
 594                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 595                 fi
 596                 if test $rc -ne 0; then :
 597                         $6
 598                 else :
 599                         $5
 600                 fi
 601         fi
 602 ])