config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_LOOKUP_BDEV
  16         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  17         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  19         ZFS_AC_KERNEL_BIO_FAILFAST
  20         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  21         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  22         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  23         ZFS_AC_KERNEL_BIO_RW_SYNC
  24         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  25         ZFS_AC_KERNEL_REQ_SYNC
  26         ZFS_AC_KERNEL_BLK_END_REQUEST
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  31         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  32         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  33         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  34         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  35         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_RQ_IS_SYNC
  42         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_SHOW_OPTIONS
  48         ZFS_AC_KERNEL_FSYNC
  49         ZFS_AC_KERNEL_EVICT_INODE
  50         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  51         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  52         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FALLOCATE
  54         ZFS_AC_KERNEL_MKDIR_UMODE_T
  55         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  56         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  57         ZFS_AC_KERNEL_TRUNCATE_RANGE
  58         ZFS_AC_KERNEL_AUTOMOUNT
  59         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  60         ZFS_AC_KERNEL_COMMIT_METADATA
  61         ZFS_AC_KERNEL_CLEAR_INODE
  62         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  63         ZFS_AC_KERNEL_D_MAKE_ROOT
  64         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  65         ZFS_AC_KERNEL_D_SET_D_OP
  66         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  67         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  68         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  69         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  70         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  71         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  72         ZFS_AC_KERNEL_MOUNT_NODEV
  73         ZFS_AC_KERNEL_SHRINK
  74         ZFS_AC_KERNEL_S_D_OP
  75         ZFS_AC_KERNEL_BDI
  76         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  77         ZFS_AC_KERNEL_SET_NLINK
  78         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  79         ZFS_AC_KERNEL_5ARG_SGET
  80
  81         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  82                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  83         ])
  84         AC_SUBST(KERNELMAKE_PARAMS)
  85
  86
  87         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  88         dnl # compiler options are added by the kernel build system.
  89         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  90         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  91         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  92
  93         AC_SUBST(KERNELCPPFLAGS)
  94 ])
  95
  96 dnl #
  97 dnl # Detect name used for Module.symvers file in kernel
  98 dnl #
  99 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 100         modpost=$LINUX/scripts/Makefile.modpost
 101         AC_MSG_CHECKING([kernel file name for module symbols])
 102         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 103                 AS_IF([grep -q Modules.symvers $modpost], [
 104                         LINUX_SYMBOLS=Modules.symvers
 105                 ], [
 106                         LINUX_SYMBOLS=Module.symvers
 107                 ])
 108
 109                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 110                         AC_MSG_ERROR([
 111         *** Please make sure the kernel devel package for your distribution
 112         *** is installed.  If you are building with a custom kernel, make sure the
 113         *** kernel is configured, built, and the '--with-linux=PATH' configure
 114         *** option refers to the location of the kernel source.])
 115                 ])
 116         ], [
 117                 LINUX_SYMBOLS=NONE
 118         ])
 119         AC_MSG_RESULT($LINUX_SYMBOLS)
 120         AC_SUBST(LINUX_SYMBOLS)
 121 ])
 122
 123 dnl #
 124 dnl # Detect the kernel to be built against
 125 dnl #
 126 AC_DEFUN([ZFS_AC_KERNEL], [
 127         AC_ARG_WITH([linux],
 128                 AS_HELP_STRING([--with-linux=PATH],
 129                 [Path to kernel source]),
 130                 [kernelsrc="$withval"])
 131
 132         AC_ARG_WITH(linux-obj,
 133                 AS_HELP_STRING([--with-linux-obj=PATH],
 134                 [Path to kernel build objects]),
 135                 [kernelbuild="$withval"])
 136
 137         AC_MSG_CHECKING([kernel source directory])
 138         AS_IF([test -z "$kernelsrc"], [
 139                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 140                         headersdir="/lib/modules/$(uname -r)/source"
 141                         sourcelink=$(readlink -f "$headersdir")
 142                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 143                         headersdir="/lib/modules/$(uname -r)/build"
 144                         sourcelink=$(readlink -f "$headersdir")
 145                 ], [
 146                         sourcelink=$(ls -1d /usr/src/kernels/* \
 147                                      /usr/src/linux-* \
 148                                      2>/dev/null | grep -v obj | tail -1)
 149                 ])
 150
 151                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 152                         kernelsrc=`readlink -f ${sourcelink}`
 153                 ], [
 154                         kernelsrc="[Not found]"
 155                 ])
 156         ], [
 157                 AS_IF([test "$kernelsrc" = "NONE"], [
 158                         kernsrcver=NONE
 159                 ])
 160         ])
 161
 162         AC_MSG_RESULT([$kernelsrc])
 163         AS_IF([test ! -d "$kernelsrc"], [
 164                 AC_MSG_ERROR([
 165         *** Please make sure the kernel devel package for your distribution
 166         *** is installed and then try again.  If that fails, you can specify the
 167         *** location of the kernel source with the '--with-linux=PATH' option.])
 168         ])
 169
 170         AC_MSG_CHECKING([kernel build directory])
 171         AS_IF([test -z "$kernelbuild"], [
 172                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 173                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 174                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 175                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 176                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 177                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 178                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 179                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 180                 ], [
 181                         kernelbuild=${kernelsrc}
 182                 ])
 183         ])
 184         AC_MSG_RESULT([$kernelbuild])
 185
 186         AC_MSG_CHECKING([kernel source version])
 187         utsrelease1=$kernelbuild/include/linux/version.h
 188         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 189         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 190         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 191                 utsrelease=linux/version.h
 192         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 193                 utsrelease=linux/utsrelease.h
 194         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 195                 utsrelease=generated/utsrelease.h
 196         ])
 197
 198         AS_IF([test "$utsrelease"], [
 199                 kernsrcver=`(echo "#include <$utsrelease>";
 200                              echo "kernsrcver=UTS_RELEASE") |
 201                              cpp -I $kernelbuild/include |
 202                              grep "^kernsrcver=" | cut -d \" -f 2`
 203
 204                 AS_IF([test -z "$kernsrcver"], [
 205                         AC_MSG_RESULT([Not found])
 206                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 207                 ])
 208         ], [
 209                 AC_MSG_RESULT([Not found])
 210                 if test "x$enable_linux_builtin" != xyes; then
 211                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 212                 else
 213                         AC_MSG_ERROR([
 214         *** Cannot find UTS_RELEASE definition.
 215         *** Please run 'make prepare' inside the kernel source tree.])
 216                 fi
 217         ])
 218
 219         AC_MSG_RESULT([$kernsrcver])
 220
 221         LINUX=${kernelsrc}
 222         LINUX_OBJ=${kernelbuild}
 223         LINUX_VERSION=${kernsrcver}
 224
 225         AC_SUBST(LINUX)
 226         AC_SUBST(LINUX_OBJ)
 227         AC_SUBST(LINUX_VERSION)
 228
 229         ZFS_AC_MODULE_SYMVERS
 230 ])
 231
 232
 233 dnl #
 234 dnl # Detect the SPL module to be built against
 235 dnl #
 236 AC_DEFUN([ZFS_AC_SPL], [
 237         AC_ARG_WITH([spl],
 238                 AS_HELP_STRING([--with-spl=PATH],
 239                 [Path to spl source]),
 240                 [splsrc="$withval"])
 241
 242         AC_ARG_WITH([spl-obj],
 243                 AS_HELP_STRING([--with-spl-obj=PATH],
 244                 [Path to spl build objects]),
 245                 [splbuild="$withval"])
 246
 247         AC_ARG_WITH([spl-timeout],
 248                 AS_HELP_STRING([--with-spl-timeout=SECS],
 249                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 250                 [timeout="$withval"], [timeout=0])
 251
 252         dnl #
 253         dnl # The existence of spl.release.in is used to identify a valid
 254         dnl # source directory.  In order of preference:
 255         dnl #
 256         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 257         splsrc1="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 258         splsrc2="/usr/src/spl-${VERSION}"
 259         splsrc3="../spl/"
 260         splsrc4="$LINUX"
 261
 262         AC_MSG_CHECKING([spl source directory])
 263         AS_IF([test -z "${splsrc}"], [
 264                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 265                         splsrc=${splsrc0}
 266                 ], [ test -e "${splsrc1}/spl.release.in"], [
 267                         splsrc=${splsrc1}
 268                 ], [ test -e "${splsrc2}/spl.release.in"], [
 269                         splsrc=${splsrc2}
 270                 ], [ test -e "${splsrc3}/spl.release.in"], [
 271                         splsrc=$(readlink -f "${splsrc3}")
 272                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 273                         splsrc=${splsrc4}
 274                 ], [
 275                         splsrc="[Not found]"
 276                 ])
 277         ], [
 278                 AS_IF([test "$splsrc" = "NONE"], [
 279                         splbuild=NONE
 280                         splsrcver=NONE
 281                 ])
 282         ])
 283
 284         AC_MSG_RESULT([$splsrc])
 285         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 286                 AC_MSG_ERROR([
 287         *** Please make sure the kmod spl devel package for your distribution
 288         *** is installed then try again.  If that fails you can specify the
 289         *** location of the spl source with the '--with-spl=PATH' option.])
 290         ])
 291
 292         dnl #
 293         dnl # The existence of the spl_config.h is used to identify a valid
 294         dnl # spl object directory.  In many cases the object and source
 295         dnl # directory are the same, however the objects may also reside
 296         dnl # is a subdirectory named after the kernel version.
 297         dnl #
 298         dnl # This file is supposed to be available after DKMS finishes
 299         dnl # building the SPL kernel module for the target kernel.  The
 300         dnl # '--with-spl-timeout' option can be passed to pause here,
 301         dnl # waiting for the file to appear from a concurrently building
 302         dnl # SPL package.
 303         dnl #
 304         AC_MSG_CHECKING([spl build directory])
 305         while true; do
 306                 AS_IF([test -z "$splbuild"], [
 307                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 308                                 splbuild="${splsrc}/${LINUX_VERSION}"
 309                         ], [ test -e "${splsrc}/spl_config.h" ], [
 310                                 splbuild="${splsrc}"
 311                         ], [
 312                                 splbuild="[Not found]"
 313                         ])
 314                 ])
 315                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 316                         break;
 317                 ], [
 318                         sleep 1
 319                         timeout=$((timeout-1))
 320                 ])
 321         done
 322
 323         AC_MSG_RESULT([$splbuild])
 324         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 325                 AC_MSG_ERROR([
 326         *** Please make sure the kmod spl devel <kernel> package for your
 327         *** distribution is installed then try again.  If that fails you
 328         *** can specify the location of the spl objects with the
 329         *** '--with-spl-obj=PATH' option.])
 330         ])
 331
 332         AC_MSG_CHECKING([spl source version])
 333         AS_IF([test -r $splbuild/spl_config.h &&
 334                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 335
 336                 splsrcver=`(echo "#include <spl_config.h>";
 337                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 338                             cpp -I $splbuild |
 339                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 340         ])
 341
 342         AS_IF([test -z "$splsrcver"], [
 343                 AC_MSG_RESULT([Not found])
 344                 AC_MSG_ERROR([
 345         *** Cannot determine the version of the spl source.
 346         *** Please prepare the spl source before running this script])
 347         ])
 348
 349         AC_MSG_RESULT([$splsrcver])
 350
 351         SPL=${splsrc}
 352         SPL_OBJ=${splbuild}
 353         SPL_VERSION=${splsrcver}
 354
 355         AC_SUBST(SPL)
 356         AC_SUBST(SPL_OBJ)
 357         AC_SUBST(SPL_VERSION)
 358
 359         dnl #
 360         dnl # Detect the name used for the SPL Module.symvers file.  If one
 361         dnl # does not exist this is likely because the SPL has been configured
 362         dnl # but not built.  The '--with-spl-timeout' option can be passed
 363         dnl # to pause here, waiting for the file to appear from a concurrently
 364         dnl # building SPL package.  If the file does not appear in time, a good
 365         dnl # guess is made as to what this file will be named based on what it
 366         dnl # is named in the kernel build products.  This file will first be
 367         dnl # used at link time so if the guess is wrong the build will fail
 368         dnl # then.  This unfortunately means the ZFS package does not contain a
 369         dnl # reliable mechanism to detect symbols exported by the SPL at
 370         dnl # configure time.
 371         dnl #
 372         AC_MSG_CHECKING([spl file name for module symbols])
 373         SPL_SYMBOLS=NONE
 374
 375         while true; do
 376                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 377                         SPL_SYMBOLS=Module.symvers
 378                 ], [test -r $SPL_OBJ/Modules.symvers], [
 379                         SPL_SYMBOLS=Modules.symvers
 380                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 381                         SPL_SYMBOLS=Module.symvers
 382                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 383                         SPL_SYMBOLS=Modules.symvers
 384                 ])
 385
 386                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 387                         break;
 388                 ], [
 389                         sleep 1
 390                         timeout=$((timeout-1))
 391                 ])
 392         done
 393
 394         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 395                 SPL_SYMBOLS=$LINUX_SYMBOLS
 396         ])
 397
 398         AC_MSG_RESULT([$SPL_SYMBOLS])
 399         AC_SUBST(SPL_SYMBOLS)
 400 ])
 401
 402 dnl #
 403 dnl # Basic toolchain sanity check.
 404 dnl #
 405 AC_DEFUN([ZFS_AC_TEST_MODULE],
 406         [AC_MSG_CHECKING([whether modules can be built])
 407         ZFS_LINUX_TRY_COMPILE([],[],[
 408                 AC_MSG_RESULT([yes])
 409         ],[
 410                 AC_MSG_RESULT([no])
 411                 if test "x$enable_linux_builtin" != xyes; then
 412                         AC_MSG_ERROR([*** Unable to build an empty module.])
 413                 else
 414                         AC_MSG_ERROR([
 415         *** Unable to build an empty module.
 416         *** Please run 'make scripts' inside the kernel source tree.])
 417                 fi
 418         ])
 419 ])
 420
 421 dnl #
 422 dnl # Certain kernel build options are not supported.  These must be
 423 dnl # detected at configure time and cause a build failure.  Otherwise
 424 dnl # modules may be successfully built that behave incorrectly.
 425 dnl #
 426 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 427
 428         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 429                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 430                         [Define to 1 if licensed under the GPL])
 431         ])
 432
 433         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 434 ])
 435
 436 dnl #
 437 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 438 dnl #
 439 dnl # This is typically only set for debug kernels because it comes with
 440 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 441 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 442 dnl # This will cause a failure at link time which we'd rather know about
 443 dnl # at compile time.
 444 dnl #
 445 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 446 dnl # with the upstream community we add a check to detect this case.
 447 dnl #
 448 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 449
 450         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 451                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 452                 tmp_flags="$EXTRA_KCFLAGS"
 453                 ZFS_LINUX_TRY_COMPILE([
 454                         #include <linux/module.h>
 455                         #include <linux/mutex.h>
 456
 457                         MODULE_LICENSE("$ZFS_META_LICENSE");
 458                 ],[
 459                         struct mutex lock;
 460
 461                         mutex_init(&lock);
 462                         mutex_lock(&lock);
 463                         mutex_unlock(&lock);
 464                 ],[
 465                         AC_MSG_RESULT(no)
 466                 ],[
 467                         AC_MSG_RESULT(yes)
 468                         AC_MSG_ERROR([
 469         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 470         *** with the CDDL license and will prevent the module linking stage
 471         *** from succeeding.  You must rebuild your kernel without this
 472         *** option enabled.])
 473                 ])
 474                 EXTRA_KCFLAGS="$tmp_flags"
 475         ], [])
 476 ])
 477
 478 dnl #
 479 dnl # ZFS_LINUX_CONFTEST
 480 dnl #
 481 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 482 cat confdefs.h - <<_ACEOF >conftest.c
 483 $1
 484 _ACEOF
 485 ])
 486
 487 dnl #
 488 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 489 dnl #
 490 m4_define([ZFS_LANG_PROGRAM], [
 491 $1
 492 int
 493 main (void)
 494 {
 495 dnl Do *not* indent the following line: there may be CPP directives.
 496 dnl Don't move the `;' right after for the same reason.
 497 $2
 498   ;
 499   return 0;
 500 }
 501 ])
 502
 503 dnl #
 504 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 505 dnl #
 506 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 507         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 508         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 509         echo "obj-m := conftest.o" >build/Makefile
 510         modpost_flag=''
 511         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 512         AS_IF(
 513                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 514                 [$4],
 515                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 516         )
 517         rm -Rf build
 518 ])
 519
 520 dnl #
 521 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 522 dnl #
 523 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 524         [ZFS_LINUX_COMPILE_IFELSE(
 525         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 526         [modules],
 527         [test -s build/conftest.o],
 528         [$3], [$4])
 529 ])
 530
 531 dnl #
 532 dnl # ZFS_LINUX_CONFIG
 533 dnl #
 534 AC_DEFUN([ZFS_LINUX_CONFIG],
 535         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 536         ZFS_LINUX_TRY_COMPILE([
 537                 #include <linux/module.h>
 538         ],[
 539                 #ifndef CONFIG_$1
 540                 #error CONFIG_$1 not #defined
 541                 #endif
 542         ],[
 543                 AC_MSG_RESULT([yes])
 544                 $2
 545         ],[
 546                 AC_MSG_RESULT([no])
 547                 $3
 548         ])
 549 ])
 550
 551 dnl #
 552 dnl # ZFS_CHECK_SYMBOL_EXPORT
 553 dnl # check symbol exported or not
 554 dnl #
 555 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 556         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 557                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 558         rc=$?
 559         if test $rc -ne 0; then
 560                 export=0
 561                 for file in $2; do
 562                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 563                                 "$LINUX/$file" 2>/dev/null
 564                         rc=$?
 565                         if test $rc -eq 0; then
 566                                 export=1
 567                                 break;
 568                         fi
 569                 done
 570                 if test $export -eq 0; then :
 571                         $4
 572                 else :
 573                         $3
 574                 fi
 575         else :
 576                 $3
 577         fi
 578 ])
 579
 580 dnl #
 581 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 582 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 583 dnl # is called if not compiling for builtin
 584 dnl #
 585 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 586         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 587         if test $rc -ne 0; then :
 588                 $6
 589         else
 590                 if test "x$enable_linux_builtin" != xyes; then
 591                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 592                 fi
 593                 if test $rc -ne 0; then :
 594                         $6
 595                 else :
 596                         $5
 597                 fi
 598         fi
 599 ])