videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9
  10
  11 BEGIN {
  12     # Get rid of a (possibly old) version of BettIrssi
  13     # This is a hack to prevent having to reload irssi just
  14     # because BettIrssi.pm changed
  15
  16     delete($INC{'BettIrssi.pm'});
  17 }
  18
  19 use strict;
  20 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  21 use vars qw($VERSION %IRSSI);
  22 use XML::Simple;
  23 use Data::Dumper;
  24 use File::Spec;
  25 use File::Temp qw(tempfile);
  26 use BettIrssi 101 qw(_bcb _bcs);
  27 use LWP::UserAgent;
  28
  29 my @grabbers;
  30 my @getters;
  31 my $getter;
  32 my $conf;
  33 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  34 my $scriptdir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts');
  35 my $plugindir = File::Spec->catfile($scriptdir, 'videosite');
  36 my @outputstack = (undef);
  37
  38 my $PARAMS = {
  39     'getter' => '',
  40     'mode' => 'download',
  41     'connectorlist' => ['direct'],
  42     'connectors' => {},
  43 };
  44
  45
  46 # activate debug here
  47 my $debug = 0;
  48
  49 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  50 signal_add_last(_bcs("message public" => sub {check_for_link(@_)}));
  51 # "message own_public", SERVER_REC, char *msg, char *target
  52 signal_add_last(_bcs("message own_public" => sub {check_for_link(@_)}));
  53
  54 # "message private", SERVER_REC, char *msg, char *nick, char *address
  55 signal_add_last(_bcs("message private" => sub {check_for_link(@_)}));
  56 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  57 signal_add_last(_bcs("message own_private" => sub {check_for_link(@_)}));
  58
  59 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  60 signal_add_last(_bcs("message irc action" => sub {check_for_link(@_)}));
  61 # "message irc own_action", SERVER_REC, char *msg, char *target
  62 signal_add_last(_bcs("message irc own_action" => sub {check_for_link(@_)}));
  63
  64 # For tab completion
  65 # This does not use BettIrssi (yet)
  66 signal_add_first('complete word', \&sig_complete);
  67
  68 sub push_output {
  69     unshift(@outputstack, shift);
  70 }
  71
  72 sub pop_output {
  73     shift(@outputstack);
  74
  75     @outputstack = (undef) unless (@outputstack);
  76 }
  77
  78 my $videosite_commands = {
  79     'save' => sub {
  80         cmd_save();
  81     },
  82
  83     'set' => sub {
  84         cmd_set(@_);
  85     },
  86
  87     'show' => sub {
  88         cmd_show(@_);
  89     },
  90
  91     'help' => sub {
  92         cmd_help(@_);
  93     },
  94
  95     'getter' => sub {
  96         cmd_getter(@_);
  97     },
  98
  99     'enable' => sub {
 100         cmd_enable(@_);
 101     },
 102
 103     'disable' => sub {
 104         cmd_disable(@_);
 105     },
 106
 107     'reload' => sub {
 108         init_videosite(0);
 109     },
 110
 111     'mode' => sub {
 112         cmd_mode(@_);
 113     },
 114
 115     'connector' => sub {
 116         cmd_connector(@_);
 117     },
 118
 119     'debug' => sub {
 120         $debug = 1;
 121         foreach (@grabbers, @getters) {
 122             $_->setdebug(1);
 123         }
 124         write_irssi('Enabled debugging');
 125     },
 126
 127     'nodebug' => sub {
 128         $debug = 0;
 129         foreach (@grabbers, @getters) {
 130             $_->setdebug(0);
 131         }
 132         write_irssi('Disabled debugging');
 133     },
 134 };
 135
 136 sub write_irssi {
 137     my @text = @_;
 138     my $output = $outputstack[0];
 139
 140     my $format = "%%mvideosite: %%n" . shift(@text);
 141
 142     # escape % in parameters from irssi
 143     s/%/%%/g foreach @text;
 144
 145     if (defined $output) {
 146         $output->(sprintf($format, @text), MSGLEVEL_CLIENTCRAP);
 147     } else {
 148         Irssi::print(sprintf($format, @text));
 149     }
 150
 151 }
 152
 153 sub write_debug {
 154     if ($debug) {
 155         write_irssi(@_);
 156     }
 157 }
 158
 159 sub expand_url_shortener {
 160     my $s = shift;
 161     my $os = '';
 162     my @urlshortener = (
 163         'is\.gd/[[:alnum:]]+',
 164         'otf\.me/[[:alnum:]]+',
 165         'hel\.me/[[:alnum:]]+',
 166         '7ax\.de/[[:alnum:]]+',
 167         'ow\.ly/[[:alnum:]]+',
 168         'j\.mp/[[:alnum:]]+',
 169         'bit\.ly/[[:alnum:]]+',
 170         'tinyurl\.com/[[:alnum:]]+',
 171         'pop\.is/[[:alnum:]]+',
 172         'post\.ly/[[:alnum:]]+',
 173         '1\.ly/[[:alnum:]]+',
 174         '2\.ly/[[:alnum:]]+',
 175         't\.co/[[:alnum:]]+',
 176         'shar\.es/[[:alnum:]]+',
 177         'goo\.gl/[[:alnum:]]+',
 178         );
 179     my $ua = LWP::UserAgent->new(agent => 'Mozilla', max_redirect => 0);
 180     my $i = 10;
 181
 182     OUTER: while (($os ne $s) and ($i > 0)) {
 183         study($s);
 184         $os = $s;
 185         $i--;
 186
 187         foreach my $pattern (@urlshortener) {
 188             my $p = "https?:\/\/" . $pattern;
 189
 190             write_debug("Matching %s against %s", $p, $s);
 191             if ($s =~ m|($p)|) {
 192                 my $matched = $1;
 193                 my $res;
 194
 195                 write_debug("Found %s", $matched);
 196                 $res = $ua->head($matched);
 197                 if ($res->is_redirect()) {
 198                     my $new = $res->headers()->header("Location");
 199
 200                     write_debug("Replacing %s with %s", $matched, $new);
 201                     $s =~ s/$matched/$new/;
 202                     next OUTER;
 203                 } else {
 204                     write_debug("Error resolving %s", $matched);
 205                 }
 206             }
 207         }
 208     }
 209
 210     if ($i == 0) {
 211         write_debug("Loop terminated by counter");
 212     }
 213
 214     write_debug("Final string: %s", $s);
 215
 216     return $s;
 217 }
 218
 219 sub connectorlist {
 220     my @c;
 221
 222     foreach (@{$conf->{'videosite'}->{'connectorlist'}}) {
 223         push(@c, $conf->{'videosite'}->{'connectors'}->{$_});
 224     }
 225
 226     return @c;
 227 }
 228
 229
 230 sub check_for_link {
 231     my $event = shift;
 232     my $message = $event->message();
 233     my $witem = $event->channel();
 234     my $g;
 235     my $m;
 236     my $p;
 237
 238
 239     # Look if we should ignore this line
 240     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
 241         return;
 242     }
 243
 244     push_output($event->ewpf);
 245     $message = expand_url_shortener($message);
 246
 247     study($message);
 248
 249     # Offer the message to all Grabbers in turn
 250     GRABBER: foreach $g (@grabbers) {
 251         ($m, $p) = $g->get($message);
 252         while (defined($m)) {
 253             write_debug('Metadata: %s', Dumper($m));
 254             if ('download' eq ($conf->{'videosite'}->{'mode'})) {
 255                 write_irssi('%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 256                 unless($getter->get($m)) {
 257                     write_irssi('%%R>>> FAILED');
 258                 }
 259             } elsif ('display' eq ($conf->{'videosite'}->{'mode'})) {
 260                 write_irssi('%%M>>> %%NSaw %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 261             } else {
 262                 write_irssi('%%R>>> Invalid operation mode');
 263             }
 264
 265             # Remove the matched part from the message and try again (there may be
 266             # more!)
 267             $message =~ s/$p//;
 268             study($message);
 269             last GRABBER if ($message =~ /^\s*$/);
 270
 271             ($m, $p) = $g->get($message);
 272         }
 273     }
 274
 275     pop_output();
 276 }
 277
 278 sub cmd_save {
 279
 280
 281     eval {
 282         my ($tempfile, $tempfn) = tempfile("videosite.xml.XXXXXX", dir => Irssi::get_irssi_dir());
 283         print $tempfile XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'connector' => '+name', 'config' => 'module', 'option' => 'key'});
 284         close($tempfile);
 285         rename($tempfn, $conffile);
 286     };
 287     if ($@) {
 288         write_irssi('Could not save config to %s: %s', ($conffile, $@));
 289     } else {
 290         write_irssi('configuration saved to %s', $conffile);
 291     }
 292 }
 293
 294 sub cmd_set {
 295     my $target = shift;
 296     my $key = shift;
 297     my $val = shift;
 298     my $p;
 299
 300     foreach $p (@getters, @grabbers) {
 301         if ($p->{'NAME'} eq $target) {
 302             $p->setval($key, $val);
 303             return;
 304         }
 305     }
 306     write_irssi('No such module');
 307 }
 308
 309
 310 sub cmd_enable {
 311     my $target = shift;
 312     my $p;
 313
 314     foreach $p (@grabbers) {
 315         if ($p->{'NAME'} eq $target) {
 316             $p->enable();
 317             return;
 318         }
 319     }
 320     write_irssi('No such module');
 321 }
 322
 323
 324 sub cmd_disable {
 325     my $target = shift;
 326     my $p;
 327
 328     foreach $p (@grabbers) {
 329         if ($p->{'NAME'} eq $target) {
 330             $p->disable();
 331             return;
 332         }
 333     }
 334     write_irssi('No such module');
 335 }
 336
 337
 338 sub cmd_show {
 339     my $target = shift;
 340     my $p;
 341     my $e;
 342
 343     if (defined($target)) {
 344         foreach $p (@getters, @grabbers) {
 345             if ($p->{'NAME'} eq $target) {
 346                 write_irssi($p->getconfstr());
 347                 return;
 348             }
 349         }
 350         write_irssi('No such module');
 351     } else {
 352         write_irssi('Loaded grabbers (* denotes enabled modules):');
 353         foreach $p (@grabbers) {
 354             $e = $p->_getval('enabled');
 355             write_irssi(' %s%s', $p->{'NAME'}, $e?'*':'');
 356         };
 357
 358         write_irssi('Loaded getters:');
 359         foreach $p (@getters) {
 360             write_irssi(' %s', $p->{'NAME'});
 361         };
 362     }
 363 }
 364
 365 sub cmd_help {
 366     my $target = shift;
 367     my $p;
 368
 369     if (defined($target)) {
 370         foreach $p (@getters, @grabbers) {
 371             if ($p->{'NAME'} eq $target) {
 372                 write_irssi($p->gethelpstr());
 373                 return;
 374             }
 375         }
 376         write_irssi('No such module');
 377     } else {
 378         write_irssi(<<'EOT');
 379 Supported commands:
 380  save: save the current configuration
 381  help [modulename]: display this help, or module specific help
 382  show [modulename]: show loaded modules, or the current parameters of a module
 383  set modulename parameter value: set a module parameter to a new value
 384  getter [modulename]: display or set the getter to use
 385  enable [modulename]: enable the usage of this module (grabbers only)
 386  disable [modulename]: disable the usage of this module (grabbers only)
 387  reload: reload all modules (this is somewhat experimental)
 388  mode [modename]: display or set the operation mode (download/display)
 389  debug: enable debugging messages
 390  nodebug: disable debugging messages
 391 EOT
 392     }
 393 }
 394
 395 sub cmd_getter {
 396     my $target = shift;
 397     my $p;
 398
 399     if (defined($target)) {
 400         foreach $p (@getters) {
 401             if ($p->{'NAME'} eq $target) {
 402                 $getter = $p;
 403                 $conf->{'videosite'}->{'getter'} = $target;
 404                 write_irssi("Getter changed to %s", $target);
 405                 return;
 406             }
 407         }
 408         write_irssi('No such getter');
 409     } else {
 410         write_irssi('Current getter: %s', $conf->{'videosite'}->{'getter'});
 411     }
 412 }
 413
 414 sub cmd_mode {
 415     my $mode = shift;
 416
 417     if (defined($mode)) {
 418         $mode = lc($mode);
 419         if (('download' eq $mode) or ('display' eq $mode)) {
 420             $conf->{'videosite'}->{'mode'} = $mode;
 421             write_irssi('Now using %s mode', $mode);
 422         } else {
 423             write_irssi('Invalid mode: %s', $mode);
 424         }
 425     } else {
 426         write_irssi('Current mode: %s', $conf->{'videosite'}->{'mode'});
 427     }
 428 }
 429
 430 sub cmd_connector {
 431     my $subcmd = shift;
 432     my $connconf = $conf->{'videosite'}->{'connectors'};
 433
 434     unless(defined($subcmd)) {
 435         $subcmd = "help";
 436     }
 437
 438     $subcmd = lc($subcmd);
 439
 440     if ($subcmd eq 'list') {
 441         write_irssi("Defined connectors");
 442         foreach (keys(%{$connconf})) {
 443             write_irssi($_);
 444             my $schemas = $connconf->{$_}->{'schemas'};
 445             if (scalar(keys(%{$schemas})) == 0) {
 446                 write_irssi(" No schemas defined");
 447             } else {
 448                 foreach (keys(%{$schemas})) {
 449                     write_irssi(' %s: %s', $_, $schemas->{$_});
 450                 }
 451             }
 452         }
 453
 454         write_irssi();
 455         write_irssi("Selected connectors: %s", join(", ", @{$conf->{'videosite'}->{'connectorlist'}}));
 456     } elsif ($subcmd eq 'add') {
 457         my ($name) = @_;
 458
 459         unless(defined($name)) {
 460             write_irssi("No name given");
 461             return;
 462         }
 463
 464         $name = lc($name);
 465
 466         if (exists($connconf->{$_})) {
 467             write_irssi("Connector already exists");
 468             return;
 469         }
 470
 471         $connconf->{$name} = {'name' => $name, 'schemas' => {}};
 472     } elsif ($subcmd eq 'del') {
 473         my ($name) = @_;
 474
 475         unless(defined($name)) {
 476             write_irssi("No name given");
 477             return;
 478         }
 479
 480         $name = lc($name);
 481
 482         if ($name eq 'direct') {
 483             write_irssi("Cannot remove direct connector");
 484             return;
 485         }
 486
 487         unless (exists($connconf->{$_})) {
 488             write_irssi("Connector does not exist");
 489             return;
 490         }
 491
 492         delete($connconf->{$name});
 493
 494         # Remove from list of active connectors
 495         $conf->{'videosite'}->{'connectorlist'} =
 496             [ grep { $_ ne $name } @{$conf->{'videosite'}->{'connectorlist'}} ];
 497
 498         if (scalar(@{$conf->{'videosite'}->{'connectorlist'}}) == 0) {
 499             write_irssi("List of selected connectors is empty, resetting to direct");
 500             $conf->{'videosite'}->{'connectorlist'} = [ 'direct' ];
 501         }
 502     } elsif ($subcmd eq 'addschema') {
 503         my ($conn, $schema, $proxy) = @_;
 504
 505         unless(defined($conn)) {
 506             write_irssi("No connector name given");
 507             return;
 508         }
 509
 510         $conn = lc($conn);
 511
 512         if ($conn eq 'direct') {
 513             write_irssi("Connector is not modifiable");
 514             return;
 515         }
 516
 517         unless(defined($schema)) {
 518             write_irssi("No schema given");
 519             return;
 520         }
 521
 522         $schema = lc($schema);
 523
 524         unless(defined($proxy)) {
 525             write_irssi("No proxy given");
 526             return;
 527         }
 528
 529         unless(exists($connconf->{$conn})) {
 530             write_irssi("Connector does not exist");
 531             return;
 532         }
 533
 534         $connconf->{$conn}->{'schemas'}->{$schema} = $proxy;
 535     } elsif ($subcmd eq 'delschema') {
 536         my ($conn, $schema) = @_;
 537
 538         unless(defined($conn)) {
 539             write_irssi("No connector name given");
 540             return;
 541         }
 542
 543         $conn = lc($conn);
 544
 545         if ($conn eq 'direct') {
 546             write_irssi("Connector is not modifiable");
 547             return;
 548         }
 549
 550         unless(defined($schema)) {
 551             write_irssi("No schema given");
 552             return;
 553         }
 554
 555         $schema = lc($schema);
 556
 557         unless(exists($connconf->{$conn})) {
 558             write_irssi("Connector does not exist");
 559             return;
 560         }
 561
 562         delete($connconf->{$conn}->{'schemas'}->{$schema});
 563     } elsif ($subcmd eq 'select') {
 564         my @connlist = map { lc } @_;
 565
 566         if (scalar(@connlist) == 0) {
 567             write_irssi("No connectors given");
 568             return;
 569         }
 570
 571         foreach (@connlist) {
 572             unless(exists($connconf->{$_})) {
 573                 write_irssi("Connector %s does not exist", $_);
 574                 return;
 575             }
 576         }
 577
 578         $conf->{'videosite'}->{'connectorlist'} = [ @connlist ];
 579     } else {
 580         write_irssi("connector [list|add|del|addschema|delschema|help] <options>");
 581         write_irssi(" help: Show this help");
 582         write_irssi(" list: List the defined connectors");
 583         write_irssi(" add <name>: Add a connector with name <name>");
 584         write_irssi(" del <name>: Delete the connector with name <name>");
 585         write_irssi(" addschema <name> <schema> <proxy>: Add proxy to connector for the given schema");
 586         write_irssi(" delschema <name> <schema>: Remove the schema from the connector");
 587         write_irssi(" select <name> [<name>...]: Select the connectors to use");
 588     }
 589 }
 590
 591
 592
 593
 594 # save on unload
 595 sub sig_command_script_unload {
 596     my $script = shift;
 597     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 598         cmd_save();
 599     }
 600 }
 601
 602 sub ploader {
 603
 604     my $dir = shift;
 605     my $pattern = shift;
 606     my $type = shift;
 607     my @list;
 608     my $p;
 609     my $g;
 610     my @g = ();
 611
 612     opendir(D, $dir) || return ();
 613     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 614     closedir(D);
 615
 616     foreach $p (@list) {
 617         write_debug("Trying to load $p:");
 618         $p =~ s/\.pm$//;
 619         eval qq{ require videosite::$p; };
 620         if ($@) {
 621             write_irssi("Failed to load plugin: $@");
 622             next;
 623         }
 624
 625         $g = eval qq{ videosite::$p->new(); };
 626         if ($@) {
 627             write_irssi("Failed to instanciate: $@");
 628             delete($INC{$p});
 629             next;
 630         }
 631
 632         write_debug("found $g->{'TYPE'} $g->{'NAME'}");
 633         if ($type eq $g->{'TYPE'}) {
 634             push(@g, $g);
 635             $g->setio(\&write_irssi);
 636             $g->setconn(\&connectorlist);
 637         } else {
 638             write_irssi('%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 639             delete($INC{$p});
 640         }
 641     }
 642
 643     write_debug("Loaded %d plugins", $#g+1);
 644
 645     return @g;
 646 }
 647
 648 sub _load_modules($) {
 649
 650     my $path = shift;
 651
 652     foreach (keys(%INC)) {
 653         if ($INC{$_} =~ m|^$path|) {
 654             write_debug("Removing %s from \$INC", $_);
 655             delete($INC{$_});
 656         }
 657     }
 658     @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
 659     @getters = ploader($path, '.*Getter\.pm$', 'getter');
 660 }
 661
 662
 663 sub init_videosite {
 664
 665     my $bindings = shift;
 666     my $p;
 667
 668     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option', 'connectorlist'], KeepRoot => 1, KeyAttr => {'connector' => '+name', 'config' => 'module', 'option' => 'key'}))) {
 669         # No config, start with an empty one
 670         write_debug('No config found, using defaults');
 671         $conf = { 'videosite' => { }};
 672     }
 673     foreach (keys(%{$PARAMS})) {
 674         unless (exists($conf->{'videosite'}->{$_})) {
 675             $conf->{'videosite'}->{$_} = $PARAMS->{$_};
 676         }
 677     }
 678
 679     # Make sure there is a connector called 'direct', which defines no
 680     # proxies
 681     unless (exists($conf->{'videosite'}->{'connectors'}->{'direct'})) {
 682         $conf->{'videosite'}->{'connectors'}->{'direct'} = {
 683                 'name' => 'direct',
 684                 'schemas' => {},
 685         };
 686     }
 687
 688     _load_modules($plugindir);
 689
 690     unless (defined(@grabbers) && defined(@getters)) {
 691         write_irssi('No grabbers or no getters found, can not proceed.');
 692         return;
 693     }
 694
 695     $getter = $getters[0];
 696     foreach $p (@getters) {
 697         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 698             $getter = $p;
 699         }
 700     }
 701     write_debug('Selected %s as getter', $getter->{'NAME'});
 702     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 703
 704     # Loop through all plugins and load the config
 705     foreach $p (@grabbers, @getters) {
 706         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 707     }
 708
 709     if ($bindings) {
 710
 711         Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 712         Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 713         Irssi::signal_add('setup saved', 'cmd_save');
 714
 715
 716         Irssi::command_bind(_bcb('videosite' => \&cmdhandler));
 717     }
 718
 719     write_irssi('initialized successfully');
 720 }
 721
 722 sub sig_complete {
 723     my ($complist, $window, $word, $linestart, $want_space) = @_;
 724     my @matches;
 725
 726     if ($linestart !~ m|^/videosite\b|) {
 727         return;
 728     }
 729
 730     if ('/videosite' eq $linestart) {
 731         # No command enterd so far. Produce a list of possible follow-ups
 732         @matches = grep {/^$word/} keys (%{$videosite_commands});
 733     } elsif ('/videosite set' eq $linestart) {
 734         # 'set' command entered. Produce a list of modules
 735         foreach (@grabbers, @getters) {
 736             push(@matches, $_->{'NAME'}) if $_->{'NAME'} =~ m|^$word|;
 737         };
 738     } elsif ($linestart =~ m|^/videosite set (\w+)$|) {
 739         my $module = $1;
 740
 741         foreach my $p (@getters, @grabbers) {
 742             if ($p->{'NAME'} eq $module) {
 743                 @matches = $p->getparamlist($word);
 744                 last;
 745             }
 746         }
 747     } elsif ($linestart =~ m|/videosite set (\w+) (\w+)$|) {
 748         my $module = $1;
 749         my $param = $2;
 750
 751         foreach my $p (@getters, @grabbers) {
 752             if ($p->{'NAME'} eq $module) {
 753                 @matches = $p->getparamvalues($param, $word);
 754                 last;
 755             }
 756         }
 757     }
 758
 759
 760     push(@{$complist}, sort @matches);
 761     ${$want_space} = 0;
 762
 763     Irssi::signal_stop();
 764 }
 765
 766 sub cmdhandler {
 767     my $event = shift;
 768     my ($cmd, @params) = split(/\s+/, $event->message());
 769
 770     push_output($event->ewpf);
 771
 772     if (exists($videosite_commands->{$cmd})) {
 773         $videosite_commands->{$cmd}->(@params);
 774     }
 775
 776     pop_output();
 777 }
 778
 779 unshift(@INC, $scriptdir);
 780 init_videosite(1);