videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9
  10 use strict;
  11 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  12 use vars qw($VERSION %IRSSI);
  13 use XML::Simple;
  14 use Data::Dumper;
  15 use File::Spec;
  16
  17 my @grabbers;
  18 my @getters;
  19 my $getter;
  20 my $conf;
  21 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  22
  23 # activate debug here
  24 my $debug = 0;
  25
  26 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  27 signal_add_last("message public" => sub {check_for_link(\@_,1,4,2,0);});
  28 # "message own_public", SERVER_REC, char *msg, char *target
  29 signal_add_last("message own_public" => sub {check_for_link(\@_,1,2,-1,0);});
  30
  31 # "message private", SERVER_REC, char *msg, char *nick, char *address
  32 signal_add_last("message private" => sub {check_for_link(\@_,1,-1,2,0);});
  33 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  34 signal_add_last("message own_private" => sub {check_for_link(\@_,1,2,-1,0);});
  35
  36 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  37 signal_add_last("message irc action" => sub {check_for_link(\@_,1,4,2,0);});
  38 # "message irc own_action", SERVER_REC, char *msg, char *target
  39 signal_add_last("message irc own_action" => sub {check_for_link(\@_,1,2,-1,0);});
  40
  41 sub write_irssi {
  42     my $witem = shift;
  43     my @text = @_;
  44
  45     if (defined $witem) {
  46         $witem->print(sprintf(shift(@text), @text), MSGLEVEL_CLIENTCRAP);
  47     } else {
  48         Irssi::print(sprintf(shift(@text), @text));
  49     }
  50
  51 }
  52
  53 sub write_verbose {
  54     if (Irssi::settings_get_bool('youtube_verbose')) {
  55         write_irssi(shift, @_);
  56     }
  57 }
  58
  59 sub write_debug {
  60     if ($debug) {
  61         write_irssi(shift, @_);
  62     }
  63 }
  64
  65 sub check_for_link {
  66     my ($signal,$parammessage,$paramchannel,$paramnick,$paramserver) = @_;
  67     my $server = $signal->[$paramserver];
  68     my $target = $signal->[$paramchannel];
  69     my $message = ($parammessage == -1) ? '' : $signal->[$parammessage];
  70     my $g;
  71     my $m;
  72
  73
  74     my $witem;
  75     if (defined $server) {
  76         $witem = $server->window_item_find($target);
  77     } else {
  78         $witem = Irssi::window_item_find($target);
  79     }
  80
  81     # Look if we should ignore this line
  82     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
  83         return;
  84     }
  85
  86     # Offer the message to all Grabbers in turn
  87     foreach $g (@grabbers) {
  88         if (defined($m = $g->get($message))) {
  89             write_irssi($witem, '%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
  90             unless($getter->get($m)) {
  91                 write_irssi($witem, '%%R>>> FAILED');
  92             }
  93         }
  94     }
  95 }
  96
  97 sub cmd_save {
  98
  99     open(CONF, '>'.$conffile);
 100     print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
 101     close(CONF);
 102 }
 103
 104 sub cmd_set {
 105     my $target = shift;
 106     my $key = shift;
 107     my $val = shift;
 108     my $p;
 109
 110     foreach $p (@getters, @grabbers) {
 111         if ($p->{'NAME'} eq $target) {
 112             $p->setval($key, $val);
 113             return;
 114         }
 115     }
 116     write_irssi(undef, 'No such module');
 117 }
 118
 119 sub cmd_show {
 120     my $target = shift;
 121     my $p;
 122
 123     if (defined($target)) {
 124         foreach $p (@getters, @grabbers) {
 125             if ($p->{'NAME'} eq $target) {
 126                 write_irssi(undef, $p->getconfstr());
 127                 return;
 128             }
 129         }
 130         write_irssi(undef, 'No such module');
 131     } else {
 132         write_irssi(undef, 'Loaded grabbers:');
 133         foreach $p (@grabbers) {
 134             write_irssi(undef, ' ' . $p->{'NAME'});
 135         };
 136
 137         write_irssi(undef, 'Loaded getters:');
 138         foreach $p (@getters) {
 139             write_irssi(undef, ' ' . $p->{'NAME'});
 140         };
 141     }
 142 }
 143
 144 sub cmd_help {
 145     my $target = shift;
 146     my $p;
 147
 148     if (defined($target)) {
 149         foreach $p (@getters, @grabbers) {
 150             if ($p->{'NAME'} eq $target) {
 151                 write_irssi(undef, $p->gethelpstr());
 152                 return;
 153             }
 154         }
 155         write_irssi(undef, 'No such module');
 156     } else {
 157         write_irssi(undef, "Supported commands:\n save: Save the current configuration\n help [modulename]: Display this help, or module specific help\n show [modulename]: Show loaded modules, or the current parameters of a module\n set modulename parameter value: set a module parameter to a new value\n getter [modulename]: display or set the getter to use");
 158     }
 159 }
 160
 161 sub cmd_getter {
 162     my $target = shift;
 163     my $p;
 164
 165     if (defined($target)) {
 166         foreach $p (@getters, @grabbers) {
 167             if (($p->{'NAME'} eq $target) && ($p->{'TYPE'} eq 'getter')) {
 168                 $getter = $p;
 169                 $conf->{'videosite'}->{'getter'} = $target;
 170                 return;
 171             }
 172         }
 173         write_irssi(undef, 'No such getter');
 174     } else {
 175         write_irssi(undef, 'Current getter: %s', $conf->{'videosite'}->{'getter'});
 176     }
 177 }
 178
 179
 180 # save on unload
 181 sub sig_command_script_unload {
 182     my $script = shift;
 183     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 184         cmd_save();
 185     }
 186 }
 187
 188 sub ploader {
 189
 190     my $dir = shift;
 191     my $pattern = shift;
 192     my $type = shift;
 193     my @list;
 194     my $p;
 195     my $g;
 196     my @g = ();
 197
 198     opendir(D, $dir) || return ();
 199     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 200     closedir(D);
 201
 202     foreach $p (@list) {
 203         write_debug(undef, "Trying to load $p:");
 204         $p =~ s/\.pm$//;
 205         eval qq{ require $p; };
 206         if ($@) {
 207             write_debug(undef, "Failed to load plugin: $@");
 208             next;
 209         }
 210
 211         $g = eval $p.q{->new();};
 212         if ($@) {
 213             write_debug(undef, "Failed to instanciate: $@");
 214             next;
 215         }
 216
 217         write_debug(undef, "found $g->{'TYPE'} $g->{'NAME'}");
 218         if ($type eq $g->{'TYPE'}) {
 219             push(@g, $g);
 220         } else {
 221             write_irssi(undef, '%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 222         }
 223     }
 224
 225     write_debug(undef, "Loaded %d plugins", $#g+1);
 226
 227     return @g;
 228 }
 229
 230 sub init_videosite {
 231
 232     my $p;
 233
 234     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
 235         # No config, start with an empty one
 236         write_debug(undef, 'No config found, using defaults');
 237         $conf = { 'videosite' => { 'getter' => '' }};
 238     }
 239
 240     unshift(@INC, File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts', 'videosite'));
 241     @grabbers = ploader(File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts', 'videosite'), '.*Grabber\.pm$', 'grabber');
 242     @getters = ploader(File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts', 'videosite'), '.*Getter\.pm$', 'getter');
 243
 244     unless (defined(@grabbers) && defined(@getters)) {
 245         write_irssi(undef, 'No grabbers or no getters found, can not proceed.');
 246         return;
 247     }
 248
 249     $getter = $getters[0];
 250     foreach $p (@getters) {
 251         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 252             $getter = $p;
 253         }
 254     }
 255     write_debug(undef, 'Selected %s as getter', $getter->{'NAME'});
 256     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 257
 258     # Loop through all plugins and load the config
 259     foreach $p (@grabbers, @getters) {
 260         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 261     }
 262
 263     Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 264     Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 265
 266     Irssi::command_bind('videosite' => \&cmdhandler);
 267 }
 268
 269 sub cmdhandler {
 270     my ($data, $server, $item) = @_;
 271     my @params = split(/\s+/, $data);
 272
 273     if ($params[0] eq 'save') {
 274         cmd_save();
 275     } elsif ($params[0] eq 'set') {
 276         shift(@params);
 277         cmd_set(@params);
 278     } elsif ($params[0] eq 'show') {
 279         shift(@params);
 280         cmd_show(@params);
 281     } elsif ($params[0] eq 'help') {
 282         shift(@params);
 283         cmd_help(@params);
 284     } elsif ($params[0] eq 'getter') {
 285         shift(@params);
 286         cmd_getter(@params);
 287     } elsif ($params[0] eq 'debug') {
 288         $debug = 1;
 289         foreach (@grabbers, @getters) {
 290             $_->setdebug(1);
 291         }
 292         write_irssi(undef, 'Enabled debugging');
 293     } elsif ($params[0] eq 'nodebug') {
 294         $debug = 0;
 295         foreach (@grabbers, @getters) {
 296             $_->setdebug(0);
 297         }
 298         write_irssi(undef, 'Disabled debugging');
 299     }
 300 }
 301
 302 init_videosite();