videosite/AsyncFileGetter.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 #     2008-2009,2011 by Christian Garbs <mitch@cgarbs.de>
   3 #
   4 # licensed under GNU GPL v2
   5 #
   6 # A getter which will download the media to a local file storage
   7 # in the background
   8 #
   9
  10 package videosite::AsyncFileGetter;
  11
  12 use videosite::FileGetter;
  13 @ISA = qw(videosite::FileGetter);
  14
  15 use strict;
  16 use LWP::Simple qw(!get);
  17 use File::Basename;
  18 use File::Temp qw(tempfile);
  19 use MIME::Base64;
  20
  21 sub new {
  22     my $class = shift;
  23     my $self = $class->SUPER::new();
  24
  25     $self->{'NAME'} = 'asyncfilegetter';
  26
  27     bless($self, $class);
  28     $self->_prepare_parameters();
  29
  30     return $self;
  31 }
  32
  33 sub get {
  34     my $self = shift;
  35     my $video = shift;
  36     my $dlfile;
  37     my $dirname;
  38     my $cookie = "";
  39
  40     $dlfile = sprintf($self->_getval('FILEPATTERN'),
  41         $self->_encode($video->{'SOURCE'}),
  42         $self->_encode($video->{'ID'}),
  43         $self->_encode($video->{'TITLE'}),
  44         $self->_encode($video->{'DLURL'}),
  45         $self->_encode($video)->{'URL'});
  46
  47     $dirname = dirname($dlfile);
  48     if ($self->_diskfree($dirname) < $self->_getval('MINFREE')) {
  49         $self->error("Not enough free space to download");
  50         return 0;
  51     }
  52
  53     $self->debug('Going to download %s to %s', $video->{'DLURL'}, $dlfile);
  54
  55     my (undef, $tmpfile) = tempfile('videosite.tmp.XXXXXXXXXXXX', DIR => $dirname);
  56
  57     my %saved_env;
  58
  59     if (exists($video->{'CONNECTOR'})) {
  60         my $schemas = $video->{'CONNECTOR'}->{'schemas'};
  61         foreach my $schemakey(keys(%{$schemas})) {
  62             $self->debug("Setting %s_proxy to %s", $schemakey, $schemas->{$schemakey});
  63             my $envkey = $schemakey.'_proxy';
  64             $saved_env{ $envkey } = $ENV{ $envkey };
  65             $ENV{ $envkey } = $schemas->{$schemakey};
  66         }
  67     }
  68
  69     $cookie = "-H \"Cookie: $video->{'COOKIE'}\"" if (defined $video->{'COOKIE'});
  70     my $cmdline = "( GET $cookie \"$video->{'DLURL'}\" > \"$tmpfile\" && mv \"$tmpfile\" \"$dlfile\" && chmod =rw \"$dlfile\" || rm -f \"$tmpfile\" ) &";
  71     $self->debug(encode_base64($cmdline));
  72     system($cmdline);
  73
  74     # restore environment
  75     foreach my $envkey (keys %saved_env) {
  76         $self->debug("Restoring environment: %s=%s", $envkey, $saved_env{ $envkey} );
  77         $ENV{ $envkey } = $saved_env{ $envkey };
  78     }
  79
  80     return 1;
  81 }