videosite/AsyncWgetFileGetter.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 #     2008-2009,2011 by Christian Garbs <mitch@cgarbs.de>
   3 #     2010 by Maximilian Rehkopf <otakon@gmx.net>
   4 # licensed under GNU GPL v2
   5 #
   6 # A getter which will download the media to a local file storage
   7 # in the background using wget
   8 #
   9
  10 package videosite::AsyncWgetFileGetter;
  11
  12 use videosite::FileGetter;
  13 @ISA = qw(videosite::FileGetter);
  14
  15 use strict;
  16 use File::Basename;
  17 use File::Temp qw(tempfile);
  18 use MIME::Base64;
  19
  20 sub new {
  21     my $class = shift;
  22     my $self = $class->SUPER::new();
  23
  24     $self->{'NAME'} = 'asyncwgetfilegetter';
  25
  26     bless($self, $class);
  27     $self->_prepare_parameters();
  28
  29     return $self;
  30 }
  31
  32 sub get {
  33     my $self = shift;
  34     my $video = shift;
  35     my $dlfile;
  36     my $dirname;
  37     my $cookie = "";
  38
  39     $dlfile = sprintf($self->_getval('FILEPATTERN'),
  40         $self->_encode($video->{'SOURCE'}),
  41         $self->_encode($video->{'ID'}),
  42         $self->_encode($video->{'TITLE'}),
  43         $self->_encode($video->{'DLURL'}),
  44         $self->_encode($video)->{'URL'});
  45
  46     $dirname = dirname($dlfile);
  47     if ($self->_diskfree($dirname) < $self->_getval('MINFREE')) {
  48         $self->error("Not enough free space to download");
  49         return 0;
  50     }
  51
  52     $self->debug('Going to download %s to %s', $video->{'DLURL'}, $dlfile);
  53
  54     my (undef, $tmpfile) = tempfile('videosite.tmp.XXXXXXXXXXXX', DIR => $dirname);
  55
  56     my %saved_env;
  57
  58     if (exists($video->{'CONNECTOR'})) {
  59         my $schemas = $video->{'CONNECTOR'}->{'schemas'};
  60         foreach my $schemakey(keys(%{$schemas})) {
  61             $self->debug("Setting %s_proxy to %s", $schemakey, $schemas->{$schemakey});
  62             my $envkey = $schemakey.'_proxy';
  63             $saved_env{ $envkey } = $ENV{ $envkey };
  64             $ENV{ $envkey } = $schemas->{$schemakey};
  65         }
  66     }
  67
  68     $cookie = "--header=\"Cookie: $video->{'COOKIE'}\"" if (defined $video->{'COOKIE'});
  69     my $cmdline = "( wget -q -O\"$tmpfile\" $cookie \"$video->{'DLURL'}\" && mv \"$tmpfile\" \"$dlfile\" && chmod =rw \"$dlfile\" && touch \"$dlfile\" || rm -f \"$tmpfile\" ) &";
  70     $self->debug("Going to execute: %s", $cmdline);
  71     system($cmdline);
  72
  73     # restore environment
  74     foreach my $envkey (keys %saved_env) {
  75         $self->debug("Restoring environment: %s=%s", $envkey, $saved_env{ $envkey} );
  76         $ENV{ $envkey } = $saved_env{ $envkey };
  77     }
  78
  79     return 1;
  80 }