videosite/GrabberBase.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3
   4 package videosite::GrabberBase;
   5 use videosite::Base;
   6 use MIME::Base64;
   7 use Data::Dumper;
   8 @ISA = qw(videosite::Base);
   9
  10 use strict;
  11
  12 sub new {
  13     my $class = shift;
  14     my $self = $class->SUPER::new();
  15
  16     $self = {%{$self},
  17         NAME => 'FlashGrab',
  18         TYPE => 'grabber',
  19         PATTERNS => [],
  20     };
  21     return bless($self, $class);
  22 }
  23
  24 sub get($$) {
  25     my $self = shift;
  26     my $url = shift;
  27     my $pattern;
  28     my $res;
  29
  30     return undef unless $self->_getval('enabled');
  31
  32     foreach $pattern (@{$self->{'PATTERNS'}}) {
  33         $self->debug("Matching %s against %s", $pattern, $url);
  34         if ($url =~ m|$pattern|) {
  35             $self->debug("Match");
  36             foreach ($self->connectors()) {
  37                 $self->debug("Using connector %s", $_->{'name'});
  38                 $self->selectconn($_);
  39                 $res = $self->_parse($url, $pattern);
  40                 if (defined($res)) {
  41                     $res->{'CONNECTOR'} = $_;
  42                     last;
  43                 }
  44             }
  45             if (defined($res)) {
  46                 if (defined($self->_cached_ua())) {
  47                     $res->{COOKIES} = encode_base64("#LWP-Cookies-1.0\n" . $self->_cached_ua()->cookie_jar->as_string(), "");
  48                 }
  49             }
  50
  51             return wantarray?($res, $pattern):$res;
  52         }
  53     }
  54
  55     return undef;
  56 }
  57
  58 sub enable {
  59     my $self = shift;
  60
  61     $self->debug('Enabling %s grabber', $self->{'NAME'});
  62     $self->setval('enabled', '1');
  63 }
  64
  65 sub disable {
  66     my $self = shift;
  67
  68     $self->debug('Disabling %s grabber', $self->{'NAME'});
  69     $self->setval('enabled', '0');
  70 }
  71
  72 sub _parse {
  73     my $self = shift;
  74     my $url = shift;
  75
  76     return undef;
  77 }
  78
  79 sub _selftest {
  80     my $self = shift;
  81     my $info;
  82
  83     unless(exists($self->{_SELFTESTURL}) and exists($self->{_SELFTESTTITLE})) {
  84         return 0;
  85     }
  86
  87     unless(defined($info = $self->get($self->{_SELFTESTURL}))) {
  88         $self->error("Could not get information from %s", $self->{_SELFTESTURL});
  89         return undef;
  90     }
  91
  92     unless($info->{TITLE} eq $self->{_SELFTESTTITLE}) {
  93         $self->error("Title from info does not equal expected result (%s != %s)", $info->{TITLE}, $self->{_SELFTESTTITLE});
  94         return undef;
  95     }
  96
  97     return 1;
  98 }
  99
 100 1;