videosite/WimpGrabber.pm

   1 # (c) 2009 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for wimp.com
   5
   6 package videosite::WimpGrabber;
   7
   8 use videosite::GrabberBase;
   9 @ISA = qw(videosite::GrabberBase);
  10
  11 use MIME::Base64;
  12 use HTML::Parser;
  13 use Data::Dumper;
  14
  15 use strict;
  16
  17 sub new {
  18     my $class = shift;
  19     my $self = $class->SUPER::new();
  20
  21     $self->{'NAME'} = 'wimp';
  22     $self->{_SELFTESTURL} = 'http://www.wimp.com/insanebuilding/';
  23     $self->{_SELFTESTTITLE} = 'Insane building.';
  24     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*wimp.com/([^/]+)/?)'];
  25
  26     bless($self, $class);
  27
  28     $self->_prepare_parameters();
  29
  30     return $self;
  31 }
  32
  33 sub _parse {
  34     my $self = shift;
  35     my $url = shift;
  36     my $pattern = shift;
  37     my $content;
  38     my $metadata = {};
  39     my $p = HTML::Parser->new(api_version => 3);
  40     my @accum;
  41     my @text;
  42     my $e;
  43
  44     $url =~ m|$pattern|;
  45     $url = $1;
  46
  47     $metadata->{'URL'} = $url;
  48     $metadata->{'ID'} = $2;
  49     $metadata->{'TYPE'} = 'video';
  50     $metadata->{'SOURCE'} = $self->{'NAME'};
  51     $metadata->{'TITLE'} = undef;
  52     $metadata->{'DLURL'} = undef;
  53
  54     unless(defined($content = $self->simple_get(sprintf('http://www.wimp.com/%s', $2)))) {
  55         $self->error('Could not download %s', $url);
  56         return undef;
  57     }
  58
  59     $p->handler(start => \@accum, "tagname, attr");
  60     $p->handler(text => \@text, "text");
  61     $p->report_tags(qw(meta script));
  62     $p->utf8_mode(1);
  63     $p->parse($content);
  64
  65     # Look for the title in the meta tags
  66     foreach $e (@accum) {
  67         if ('meta' eq $e->[0] and exists($e->[1]->{'name'})) {
  68             if ('description' eq $e->[1]->{'name'}) {
  69                 $metadata->{'TITLE'} = $e->[1]->{'content'};
  70                 last;
  71             }
  72         }
  73     }
  74
  75     # Look for the download URL
  76     # This is obfuscated a little bit.
  77     foreach $e (@text) {
  78         if ($e->[0] =~ m|var googleCode = '([^\x27]+)'|) {
  79             my $c = $1;
  80
  81             $self->debug("Found obfuscated code: %s", $c);
  82             my $d = decode_base64($c);
  83             $self->debug("Decoded to: %s", $d);
  84
  85             if ($d =~ m|\.addVariable\("file",\s*"([^\x22]+)"\)|) {
  86                 $metadata->{'DLURL'} = $1;
  87             }
  88         }
  89     }
  90
  91     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
  92         $self->error('Could not determine download URL');
  93         return undef;
  94     }
  95
  96     return $metadata;
  97 }
  98
  99 1;