videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package videosite::YouTubeGrabber;
  10
  11 use videosite::GrabberBase;
  12 @ISA = qw(videosite::GrabberBase);
  13
  14 use HTML::TokeParser;
  15 use HTML::Entities qw(decode_entities);
  16 use Encode;
  17 use Data::Dumper;
  18 use videosite::JSArrayParser;
  19
  20 use strict;
  21
  22 my %preflist = (
  23     'insane' => [38, 37, 22, 35, 18, 34, 6, 5, 43],
  24     'hd' => [37, 22, 35, 18, 34, 6, 5, 38, 43],
  25     'h264' => [18, 34, 37, 22, 35, 6, 5, 38, 43],
  26     'high' => [34, 35, 18, 37, 22, 6, 5, 38, 43],
  27     'normal' => [6, 5, 34, 35, 18, 22, 37, 38, 43]);
  28 my %videoformats = (
  29     # Container/Video codec/Audio codec/Resolution
  30     5 => 'FLV/Sorenson/MP3/240p',
  31     6 => 'FLV/Sorenson/MP3/270p',
  32     13 => '3GP/MPEG4-Visual/144p',  # 0.5MBit
  33     17 => '3GP/MPEG4-Visual/144p',  # 2MBit
  34     18 => 'MP4/H264/AAC/360p',      # isommp42, Baseline
  35     22 => 'MP4/H264/AAC/720p',      # isommp42, High
  36     34 => 'FLV/H264/AAC/360p',      # Main
  37     35 => 'FLV/H264/AAC/480p',      # Main
  38     37 => 'MP4/H264/AAC/1080p',     # High
  39     38 => 'MP4/H264/AAC/3072p',     # High
  40     43 => 'WebM/VP8/Vorbis/360p',
  41     44 => 'WebM/VP8/Vorbis/480p',
  42     45 => 'WebM/VP8/Vorbis/720p',
  43     46 => 'WebM/VP8/Vorbis/1080p/3D',  # effective 540p
  44     82 => 'MP4/H264/AAC/360p/3D',      # isomavc1mp42
  45     83 => 'MP4/H264/AAC/240p/3D',      # isomavc1mp42
  46     84 => 'MP4/H264/AAC/720p/3D',      # isomavc1mp42
  47     85 => 'MP4/H264/AAC/1080p/3D',     # isomavc1mp42, effective 540p
  48     100 => 'WebM/VP8/Vorbis/360p/3D',
  49     101 => 'WebM/VP8/Vorbis/480p/3D',
  50     102 => 'WebM/VP8/Vorbis/720p/3D',
  51     );
  52
  53 sub new {
  54     my $class = shift;
  55     my $self = $class->SUPER::new();
  56
  57     $self->{'NAME'} = 'youtube';
  58     $self->{_SELFTESTURL} = 'http://www.youtube.com/watch?v=dMH0bHeiRNg';
  59     $self->{_SELFTESTTITLE} = 'Evolution of Dance - By Judson Laipply';
  60     $self->{'PATTERNS'} = ['(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch(?:_popup)?\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  61                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\#\!v=([-a-zA-Z0-9_]+))',
  62                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))',
  63                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/user/[[:alnum:]]+\?v=([-a-zA-Z0-9_]+))',
  64                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/(?:user/)?[[:alnum:]]+#p/(?:\w+/)+\d+/([-a-zA-Z0-9_]+))',
  65                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/watch\?v=([-a-zA-Z0-9_]+))',
  66                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/([-a-zA-Z0-9_]+))',
  67                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/user/\w+\?.*/([-a-zA-Z0-9_]+))'];
  68     $self->{'_PARAMS'} = {
  69             'QUALITY' => ['normal', 'Quality of the video to download.', {
  70                     'normal' => 'standard resolution flash video',
  71                     'high' => 'higher resolution flash video',
  72                     'h264' => 'high resolution MPEG4 video',
  73                     'hd' => 'HD720 resolution'}],
  74             'USERNAME' => ['', 'Username to use for YouTube login'],
  75             'PASSWORD' => ['', 'Password to use for YouTube login'],
  76             'HTTPS' => [1, 'Whether to use HTTPS (if available) to connect to YouTube']};
  77
  78     bless($self, $class);
  79     $self->_prepare_parameters();
  80
  81     return $self;
  82 }
  83
  84 sub _parse {
  85     my $self = shift;
  86     my $url = shift;
  87     my $pattern = shift;
  88     my $id;
  89     my $res;
  90
  91     $url =~ m|$pattern|;
  92     $url = $1;
  93     $id = $2;
  94
  95     $self->debug("Matched id %s from pattern %s", $id, $pattern);
  96
  97     $res = $self->_parse_by_video_info($url, $id);
  98     if (defined($res) && ref($res)) {
  99         return $res;
 100     } else {
 101         $res = $self->_parse_by_scrape($url, $id);
 102     }
 103
 104     return $res;
 105 }
 106
 107 sub _parse_by_video_info {
 108     my $self = shift;
 109     my $url = shift;
 110     my $id = shift;
 111     my $quality = $self->_getval('QUALITY');
 112     my $metadata;
 113     my $videourl;
 114     my $ua = $self->ua();
 115     my $preflist;
 116     my $r;
 117     my $content;
 118     my $urls;
 119
 120     $metadata->{'URL'} = $url;
 121     $metadata->{'ID'} = $id;
 122     $metadata->{'TYPE'} = 'video';
 123     $metadata->{'SOURCE'} = $self->{'NAME'};
 124     $metadata->{'TITLE'} = undef;
 125     $metadata->{'DLURL'} = undef;
 126
 127     $preflist = $preflist{$quality};
 128     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
 129
 130     $videourl = sprintf('%s://www.youtube.com/get_video_info?video_id=%s&eurl=%s',
 131             $self->_getval('HTTPS')?'https':'http', $id, 'http%3A%2F%2Fwww%2Eyoutube%2Ecom%2F');
 132     $self->debug("Video info URL: %s", $videourl);
 133
 134     $r = $ua->get($videourl);
 135     unless($r->is_success()) {
 136         $self->debug('Could not download %s: %s', $videourl, $r->code());
 137         return undef;
 138     }
 139
 140     $content = $r->content();
 141     $self->debug('Content from get_video_info: %s', $content);
 142
 143     # Decode content
 144     $content = $self->decode_querystring($content);
 145
 146     if ($content->{'status'} ne 'ok') {
 147         $self->debug("Non OK status code found: %s", $content->{'status'});
 148         return undef;
 149     }
 150
 151     if (exists($content->{'fmt_url_map'})) {
 152         # Decode fmt_url_map
 153         $urls = $self->decode_hexurl($content->{'fmt_url_map'});
 154         $urls = { split /[\|,]/, $urls };
 155     } elsif (exists($content->{'url_encoded_fmt_stream_map'})) {
 156         $urls = $self->_decode_url_encoded_fmt_stream_map($content->{'url_encoded_fmt_stream_map'}, 1);
 157     } else {
 158         $self->debug("No URL data found");
 159         return undef;
 160     }
 161
 162     unless(exists($content->{'title'})) {
 163         $self->debug("No title found");
 164         return undef;
 165     }
 166
 167     $self->__pick_url($urls, $preflist, $metadata);
 168
 169     $metadata->{'TITLE'} = $content->{'title'};
 170     $metadata->{'TITLE'} =~ s/\+/ /g;
 171     $metadata->{'TITLE'} = $self->decode_hexurl($metadata->{'TITLE'});
 172     $metadata->{'TITLE'} = decode("utf8", $metadata->{'TITLE'});
 173
 174     $self->debug('Title found: %s', $metadata->{'TITLE'});
 175
 176     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 177         $self->error('Could not determine download URL');
 178         return undef;
 179     }
 180
 181     return $metadata;
 182 }
 183
 184 sub _parse_by_scrape {
 185     my $self = shift;
 186     my $url = shift;
 187     my $id = shift;
 188     my $content;
 189     my $metadata = {};
 190     my $p;
 191     my $e;
 192     my $tag;
 193     my $ua = $self->ua();
 194     my $r;
 195     my $videourl;
 196     my $quality = $self->_getval('QUALITY');
 197     my $preflist;
 198     my $jsp;
 199
 200     $metadata->{'URL'} = $url;
 201     $metadata->{'ID'} = $id;
 202     $metadata->{'TYPE'} = 'video';
 203     $metadata->{'SOURCE'} = $self->{'NAME'};
 204     $metadata->{'TITLE'} = undef;
 205     $metadata->{'DLURL'} = undef;
 206
 207
 208     $preflist = $preflist{$quality};
 209     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
 210
 211     $videourl = sprintf('%s://www.youtube.com/watch?v=%s', $self->_getval('HTTPS')?'https':'http', $id);
 212
 213     unless(defined($r = $ua->get($videourl))) {
 214         $self->error('Could not download %s', $url);
 215         return undef;
 216     }
 217
 218     if ($r->base->as_string() =~ m,/verify_age,) {
 219         $self->debug('Video requires age verification');
 220         my @logindata = $self->__login($videourl, $ua);
 221         $r = $logindata[0];
 222         unless(defined($r)) {
 223             $self->error('Could not log into YouTube');
 224             return undef;
 225         }
 226     }
 227     $content = $r->content();
 228
 229     $p = HTML::TokeParser->new(\$content);
 230
 231     SWF_ARGS: while ($tag = $p->get_tag('div', 'meta', 'script')) {
 232         if ('meta' eq $tag->[0]) {
 233             if (exists($tag->[1]->{'name'}) and ('title' eq $tag->[1]->{'name'})) {
 234                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
 235                 # Convert HTML entities in the title. This is a bit convoluted.
 236                 $metadata->{'TITLE'} = decode_entities(
 237                                            decode("utf8", $metadata->{'TITLE'}));
 238
 239                 $self->debug('Title found: %s', $metadata->{'TITLE'});
 240             }
 241         } elsif ('script' eq $tag->[0]) {
 242             my %urls;
 243
 244             $e = $p->get_text();
 245             $self->debug("Found script: %s", $e);
 246
 247             if ($e =~ m|\x27SWF_ARGS\x27:\s+(.+),|) {
 248                 my $args = $1;
 249
 250                 $self->debug("Found SWF_ARGS: %s", $args);
 251                 $jsp = videosite::JSArrayParser->new();
 252                 $self->debug("Using %s to parse", ref($jsp));
 253                 $r = $jsp->parse($args);
 254
 255                 unless(defined($r)) {
 256                     $self->error("Found information hash, but could not parse");
 257                     return undef;
 258                 }
 259
 260                 if (exists($r->{'fmt_url_map'}) and ($r->{'fmt_url_map'} ne '')) {
 261                     my $urls =  $r->{'fmt_url_map'};
 262
 263                     $self->debug("Video has fmt_url_map: %s", $urls);
 264
 265                     $urls = $self->decode_hexurl($urls);
 266                     %urls = split(/[\|,]/, $urls);
 267                     $self->debug("Pagetype: old (SWF_ARGS), fmt_url_map");
 268
 269                 } elsif (exists($r->{'t'}) and ($r->{'t'} ne '')) {
 270                     my $thash = $r->{'t'};
 271
 272                     if (exists($r->{'fmt_map'}) && ($r->{'fmt_map'} ne '')) {
 273                         my $fmt = $r->{'fmt_map'};
 274                         my @fmt;
 275
 276                         $self->debug('Video has fmt_map');
 277                         $fmt = $self->decode_hexurl($fmt);
 278                         @fmt = split(/,/, $fmt);
 279                         foreach (@fmt) {
 280                             @_=split(/\//);
 281                             $urls{$_[0]} =  sprintf('http://www.youtube.com/get_video?video_id=%s&fmt=%d&t=%s',
 282                                 $metadata->{'ID'},
 283                                 $_[0],
 284                                 $thash);
 285                         }
 286                         $self->debug("Pagetype: 2009 (SWF_ARGS), t with fmt_map");
 287
 288                     } else {
 289                         $urls{5} = sprintf('http://www.youtube.com/get_video?video_id=%s&t=%s',
 290                             $metadata->{'ID'},
 291                             $thash);
 292                         $self->debug("Pagetype: 2009 (SWF_ARGS), t without fmt_map");
 293                     }
 294                 } else {
 295                     $self->error('Neither fmt_url_map nor t found in video information hash');
 296                     return undef;
 297                 }
 298             } elsif ($e =~ m|var swfHTML = .*fmt_url_map=([^\&]+)\&|) {
 299                 my $urls = $1;
 300                 $self->debug("Video has fmt_url_map: %s", $urls);
 301
 302                 $urls = $self->decode_hexurl($urls);
 303                 %urls = split(/[\|,]/, $urls);
 304                 $self->debug("Pagetype: 2010 (swfHTML), fmt_url_map");
 305             } elsif ($e =~ m|\x27PLAYER_CONFIG\x27:\s+(.+)(?:\}\);)?|) {
 306                 my $args = $1;
 307                 $self->debug("Found PLAYER_CONFIG: %s", $args);
 308
 309                 $jsp = videosite::JSArrayParser->new();
 310                 $self->debug("Using %s to parse", ref($jsp));
 311                 $r = $jsp->parse($args);
 312
 313                 unless(defined($r)) {
 314                     $self->error("Found information hash, but could not parse");
 315                     return undef;
 316                 }
 317
 318                 if (exists($r->{'args'}) and exists($r->{'args'}->{'ps'}) and ($r->{'args'}->{'ps'} eq 'live')) {
 319                     $self->error("Video URL seems to point to a live stream, cannot save this");
 320                     return undef;
 321                 }
 322
 323                 if (exists($r->{'args'}) and exists($r->{'args'}->{'fmt_url_map'}) and ($r->{'args'}->{'fmt_url_map'} ne '')) {
 324                     my $urls = $r->{'args'}->{'fmt_url_map'};
 325
 326                     $self->debug("Video has fmt_url_map: %s", $urls);
 327
 328                     %urls = split(/[\|,]/, $urls);
 329                     foreach (keys(%urls)) {
 330                         $urls{$_} = $self->decode_hexurl($urls{$_});
 331                     }
 332                     $self->debug("Pagetype: 2011 (PLAYER_CONFIG), fmt_url_map");
 333                 } elsif (exists($r->{'args'}) and exists($r->{'args'}->{'url_encoded_fmt_stream_map'}) and ($r->{'args'}->{'url_encoded_fmt_stream_map'} ne '')) {
 334                     %urls = %{$self->_decode_url_encoded_fmt_stream_map($r->{'args'}->{'url_encoded_fmt_stream_map'}, 0)};
 335
 336                     $self->debug("Pagetype: 2011 (PLAYER_CONFIG), url_encoded_fmt_stream_map");
 337                 } else {
 338                     $self->error('fmt_url_map not found in PLAYER_CONFIG');
 339                     return undef;
 340                 }
 341             }
 342
 343             if (%urls) {
 344                 $self->__pick_url(\%urls, $preflist, $metadata);
 345                 last SWF_ARGS;
 346             }
 347         } elsif ('div' eq $tag->[0]) {
 348             if (exists($tag->[1]->{'id'}) and ('watch-player-unavailable-message-container' eq $tag->[1]->{'id'})) {
 349                 # Search forward to the next <div>
 350                 $tag = $p->get_tag('div');
 351                 $self->error("Could not get video data for youtube %s: %s",
 352                         $metadata->{'ID'}, $p->get_trimmed_text());
 353                 return undef;
 354             }
 355         }
 356     }
 357
 358     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 359         $self->error('Could not determine download URL');
 360         return undef;
 361     }
 362
 363     return $metadata;
 364 }
 365
 366 sub __login {
 367     my $self = shift;
 368     my $videourl = shift;
 369     my $ua = shift;
 370     my $user = $self->_getval('USERNAME');
 371     my $pass = $self->_getval('PASSWORD');
 372     my $r;
 373     my $p;
 374     my $c;
 375     my $token;
 376
 377     sub check_cookie {
 378
 379         my $jar = shift;
 380         my $key = shift;
 381         my $found = undef;
 382
 383         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 384
 385         return $found;
 386     }
 387
 388     sub get_all_cookies {
 389
 390         my $jar = shift;
 391         my $key = shift;
 392         my $val = "";
 393         $jar->scan(sub { $val .= "; " if !( $val eq "" ); $val .= "$_[1]=$_[2]" });
 394
 395         return $val;
 396     }
 397
 398     if (($user eq '') or ($pass eq '')) {
 399         $self->error('No username or password defined for YouTube');
 400         return undef;
 401     }
 402
 403     $self->debug('Logging in');
 404     $r = $ua->get('https://www.google.com/accounts/ServiceLoginAuth?service=youtube');
 405     unless($r->is_success()) {
 406         $self->debug("Could not get login page (make sure your LWP supports HTTPS!)");
 407         return undef;
 408     }
 409     $c = $r->decoded_content();
 410     $p = HTML::TokeParser->new(\$c);
 411     while (my $tag = $p->get_tag('input')) {
 412         $self->debug("%s", Dumper($tag));
 413         if ($tag->[1]{name} eq 'GALX') {
 414             $token = $tag->[1]{value};
 415             last;
 416         }
 417     }
 418     $self->debug("GALX = %s", $token);
 419     $r = $ua->post('https://www.google.com/accounts/ServiceLoginAuth?service=youtube', { 'service' => 'youtube', 'Email' => $user, 'Passwd' => $pass, 'GALX' => $token });
 420     unless($r->is_success()) {
 421         $self->debug("Could not get login page (make sure your LWP supports HTTPS!)");
 422         return undef;
 423     }
 424     $c = $r -> decoded_content();
 425     $p = HTML::TokeParser->new(\$c);
 426     while (my $tag = $p->get_tag('script')) {
 427         if($p->get_text() =~ /location\.replace\("(.+)"\)/) {
 428             $token = $1;
 429             $token =~ s/\\x([A-Fa-f0-9]{2})/pack('C', hex($1))/seg;
 430             last;
 431         }
 432     }
 433     $r = $ua->get($token);
 434     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 435         $self->error('Could not log into YouTube');
 436         return undef;
 437     }
 438
 439     $self->debug("Got a cookie");
 440
 441     $r = $ua->get($videourl);
 442     if ($r->base->as_string() =~ m,/verify_age,) {
 443         $self->debug("Looking for session token...");
 444         $c = $r->decoded_content();
 445         $p = HTML::TokeParser->new(\$c);
 446         while (my $tag = $p->get_tag('script')) {
 447             if ($p->get_text() =~ /'XSRF_TOKEN': '(.+)'/) {
 448                 $token = $1;
 449                 last;
 450             }
 451         }
 452
 453         unless(defined($token)) {
 454             $self->error("Could not find session token");
 455             return undef;
 456         }
 457
 458         $self->debug('Authenticating session...');
 459         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 460     }
 461
 462 # Apparently there is no longer a specific "is_adult" cookie
 463 # or, by the looks of it, anything similar
 464 #
 465 #    unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 466 #        $self->error('Could not authenticate session');
 467 #        return undef;
 468 #    }
 469
 470     my $cookie = get_all_cookies($ua->cookie_jar);
 471     return ($ua->get($videourl), $cookie);
 472 }
 473
 474 # Take an encoded url_encoded_fmt_stream_map and return a hash
 475 # matching video IDs to download URLs
 476 sub _decode_url_encoded_fmt_stream_map {
 477     my $self = shift;
 478     my $data = shift;
 479     my $dataencoded = shift;
 480     my @data;
 481
 482     $data = $self->decode_hexurl($data) if $dataencoded;
 483     # This will
 484     # - Split the decoded string into segments (along ,)
 485     # - Interpret each segment as a concatenated key-value list (key and value separated by =, pairs separated by &
 486     # - URL-decode each key and value _again_
 487     #
 488     # @data will be an array of hash references
 489
 490     @data = map { { map { $self->decode_hexurl($_) } split /[&=]/  } } split /,/, $data;
 491     $self->debug("_decode_url_encoded_fmt_stream_map() decoded %s", Dumper(\@data));
 492
 493     # From each array entry, pick the itag and the url values and return that
 494     # as a hash reference
 495
 496     return { map { $_->{'itag'}, $_->{'url'} } @data };
 497 }
 498
 499
 500
 501 sub __pick_url {
 502     my $self = shift;
 503     my $urls = shift;
 504     my $preflist = shift;
 505     my $metadata = shift;
 506
 507     foreach (keys(%{$urls})) {
 508         if (exists($videoformats{$_})) {
 509             $self->debug('Found URL for format %s (%s): %s', $_, $videoformats{$_}, $urls->{$_});
 510         } else {
 511             $self->error('Unknown format %s: %s', $_, $urls->{$_});
 512         }
 513     }
 514
 515     foreach (@{$preflist}) {
 516         if (exists($urls->{$_})) {
 517             $self->debug("Selected URL with quality level %s", $_);
 518             $metadata->{'DLURL'} = $urls->{$_};
 519             if (exists($videoformats{$_})) {
 520                 $metadata->{'FORMAT'} = $videoformats{$_};
 521             } else {
 522                 $metadata->{'FORMAT'} = 'unknown';
 523             }
 524             last;
 525         }
 526     }
 527
 528     $self->debug('URL found: %s', $metadata->{'DLURL'});
 529 }
 530
 531 1;
 532