videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package videosite::YouTubeGrabber;
  10
  11 use videosite::GrabberBase;
  12 @ISA = qw(videosite::GrabberBase);
  13
  14 use HTML::TokeParser;
  15 use HTML::Entities qw(decode_entities);
  16 use Encode;
  17 use Data::Dumper;
  18 use videosite::JSArrayParser;
  19
  20 use strict;
  21
  22 my %preflist = (
  23     'insane' => [38, 37, 22, 35, 18, 34, 6, 5, 43],
  24     'hd' => [37, 22, 35, 18, 34, 6, 5, 38, 43],
  25     'h264' => [18, 34, 37, 22, 35, 6, 5, 38, 43],
  26     'high' => [34, 35, 18, 37, 22, 6, 5, 38, 43],
  27     'normal' => [6, 5, 34, 35, 18, 22, 37, 38, 43]);
  28 my %videoformats = (
  29     # Container/Video codec/Audio codec/Resolution
  30     5 => 'FLV/Sorenson/MP3/240p',
  31     6 => 'FLV/Sorenson/MP3/270p',
  32     13 => '3GP/MPEG4-Visual/144p',  # 0.5MBit
  33     17 => '3GP/MPEG4-Visual/144p',  # 2MBit
  34     18 => 'MP4/H264/AAC/360p',      # isommp42, Baseline
  35     22 => 'MP4/H264/AAC/720p',      # isommp42, High
  36     34 => 'FLV/H264/AAC/360p',      # Main
  37     35 => 'FLV/H264/AAC/480p',      # Main
  38     36 => '3GP/MPEG4-Visual/240p',
  39     37 => 'MP4/H264/AAC/1080p',     # High
  40     38 => 'MP4/H264/AAC/3072p',     # High
  41     43 => 'WebM/VP8/Vorbis/360p',
  42     44 => 'WebM/VP8/Vorbis/480p',
  43     45 => 'WebM/VP8/Vorbis/720p',
  44     46 => 'WebM/VP8/Vorbis/1080p/3D',  # effective 540p
  45     82 => 'MP4/H264/AAC/360p/3D',      # isomavc1mp42
  46     83 => 'MP4/H264/AAC/240p/3D',      # isomavc1mp42
  47     84 => 'MP4/H264/AAC/720p/3D',      # isomavc1mp42
  48     85 => 'MP4/H264/AAC/1080p/3D',     # isomavc1mp42, effective 540p
  49     100 => 'WebM/VP8/Vorbis/360p/3D',
  50     101 => 'WebM/VP8/Vorbis/480p/3D',
  51     102 => 'WebM/VP8/Vorbis/720p/3D',
  52     );
  53
  54 sub new {
  55     my $class = shift;
  56     my $self = $class->SUPER::new();
  57
  58     $self->{'NAME'} = 'youtube';
  59     $self->{_SELFTESTURL} = 'http://www.youtube.com/watch?v=dMH0bHeiRNg';
  60     $self->{_SELFTESTTITLE} = 'Evolution of Dance - By Judson Laipply';
  61     $self->{'PATTERNS'} = ['(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch(?:_popup)?\?.*?v=([-a-zA-Z0-9_]+))',
  62                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\#\!v=([-a-zA-Z0-9_]+))',
  63                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))',
  64                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/embed/([-a-zA-Z0-9_]+))',
  65                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/user/[[:alnum:]]+\?v=([-a-zA-Z0-9_]+))',
  66                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/(?:user/)?[[:alnum:]]+#p/(?:\w+/)+\d+/([-a-zA-Z0-9_]+))',
  67                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/watch\?v=([-a-zA-Z0-9_]+))',
  68                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/([-a-zA-Z0-9_]+))',
  69                            '(https?://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/user/\w+\?.*/([-a-zA-Z0-9_]+))'];
  70     $self->{'_PARAMS'} = {
  71             'QUALITY' => ['normal', 'Quality of the video to download.', {
  72                     'normal' => 'standard resolution flash video',
  73                     'high' => 'higher resolution flash video',
  74                     'h264' => 'high resolution MPEG4 video',
  75                     'hd' => 'HD720 resolution'}],
  76             'USERNAME' => ['', 'Username to use for YouTube login'],
  77             'PASSWORD' => ['', 'Password to use for YouTube login'],
  78             'HTTPS' => [1, 'Whether to use HTTPS (if available) to connect to YouTube']};
  79
  80     bless($self, $class);
  81     $self->_prepare_parameters();
  82
  83     return $self;
  84 }
  85
  86 sub _parse {
  87     my $self = shift;
  88     my $url = shift;
  89     my $pattern = shift;
  90     my $id;
  91     my $res;
  92
  93     $url =~ m|$pattern|;
  94     $url = $1;
  95     $id = $2;
  96
  97     $self->debug("Matched id %s from pattern %s", $id, $pattern);
  98
  99     $res = $self->_parse_by_video_info($url, $id);
 100     if (defined($res) && ref($res)) {
 101         return $res;
 102     } else {
 103         $res = $self->_parse_by_scrape($url, $id);
 104     }
 105
 106     return $res;
 107 }
 108
 109 sub _parse_by_video_info {
 110     my $self = shift;
 111     my $url = shift;
 112     my $id = shift;
 113     my $quality = $self->_getval('QUALITY');
 114     my $metadata;
 115     my $videourl;
 116     my $ua = $self->ua();
 117     my $preflist;
 118     my $r;
 119     my $content;
 120     my $urls;
 121
 122     $metadata->{'URL'} = $url;
 123     $metadata->{'ID'} = $id;
 124     $metadata->{'TYPE'} = 'video';
 125     $metadata->{'SOURCE'} = $self->{'NAME'};
 126     $metadata->{'TITLE'} = undef;
 127     $metadata->{'DLURL'} = undef;
 128
 129     $preflist = $preflist{$quality};
 130     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
 131
 132     $videourl = sprintf('%s://www.youtube.com/get_video_info?video_id=%s&eurl=%s',
 133             $self->_getval('HTTPS')?'https':'http', $id, 'http%3A%2F%2Fwww%2Eyoutube%2Ecom%2F');
 134     $self->debug("Video info URL: %s", $videourl);
 135
 136     $r = $ua->get($videourl);
 137     unless($r->is_success()) {
 138         $self->debug('Could not download %s: %s', $videourl, $r->code());
 139         return undef;
 140     }
 141
 142     $content = $r->content();
 143     $self->debug('Content from get_video_info: %s', $content);
 144
 145     # Decode content
 146     $content = $self->decode_querystring($content);
 147
 148     if ($content->{'status'} ne 'ok') {
 149         $self->debug("Non OK status code found: %s", $content->{'status'});
 150         return undef;
 151     }
 152
 153     if (exists($content->{'fmt_url_map'})) {
 154         # Decode fmt_url_map
 155         $urls = $self->decode_hexurl($content->{'fmt_url_map'});
 156         $urls = { split /[\|,]/, $urls };
 157     } elsif (exists($content->{'url_encoded_fmt_stream_map'})) {
 158         $urls = $self->_decode_url_encoded_fmt_stream_map($content->{'url_encoded_fmt_stream_map'}, 1);
 159     } else {
 160         $self->debug("No URL data found");
 161         return undef;
 162     }
 163
 164     unless(exists($content->{'title'})) {
 165         $self->debug("No title found");
 166         return undef;
 167     }
 168
 169     $self->__pick_url($urls, $preflist, $metadata);
 170
 171     $metadata->{'TITLE'} = $content->{'title'};
 172     $metadata->{'TITLE'} =~ s/\+/ /g;
 173     $metadata->{'TITLE'} = $self->decode_hexurl($metadata->{'TITLE'});
 174     $metadata->{'TITLE'} = decode("utf8", $metadata->{'TITLE'});
 175
 176     $self->debug('Title found: %s', $metadata->{'TITLE'});
 177
 178     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 179         $self->error('Could not determine download URL');
 180         return undef;
 181     }
 182
 183     return $metadata;
 184 }
 185
 186 sub _parse_by_scrape {
 187     my $self = shift;
 188     my $url = shift;
 189     my $id = shift;
 190     my $content;
 191     my $metadata = {};
 192     my $p;
 193     my $e;
 194     my $tag;
 195     my $ua = $self->ua();
 196     my $r;
 197     my $videourl;
 198     my $quality = $self->_getval('QUALITY');
 199     my $preflist;
 200     my $jsp;
 201
 202     $metadata->{'URL'} = $url;
 203     $metadata->{'ID'} = $id;
 204     $metadata->{'TYPE'} = 'video';
 205     $metadata->{'SOURCE'} = $self->{'NAME'};
 206     $metadata->{'TITLE'} = undef;
 207     $metadata->{'DLURL'} = undef;
 208
 209
 210     $preflist = $preflist{$quality};
 211     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
 212
 213     $videourl = sprintf('%s://www.youtube.com/watch?v=%s', $self->_getval('HTTPS')?'https':'http', $id);
 214
 215     unless(defined($r = $ua->get($videourl))) {
 216         $self->error('Could not download %s', $url);
 217         return undef;
 218     }
 219
 220     if ($r->base->as_string() =~ m,/verify_age,) {
 221         $self->debug('Video requires age verification');
 222         my @logindata = $self->__login($videourl, $ua);
 223         $r = $logindata[0];
 224         unless(defined($r)) {
 225             $self->error('Could not log into YouTube');
 226             return undef;
 227         }
 228     }
 229     $content = $r->content();
 230
 231     $p = HTML::TokeParser->new(\$content);
 232
 233     SWF_ARGS: while ($tag = $p->get_tag('div', 'meta', 'script')) {
 234         if ('meta' eq $tag->[0]) {
 235             if (exists($tag->[1]->{'name'}) and ('title' eq $tag->[1]->{'name'})) {
 236                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
 237                 # Convert HTML entities in the title. This is a bit convoluted.
 238                 $metadata->{'TITLE'} = decode_entities(
 239                                            decode("utf8", $metadata->{'TITLE'}));
 240
 241                 $self->debug('Title found: %s', $metadata->{'TITLE'});
 242             }
 243         } elsif ('script' eq $tag->[0]) {
 244             my %urls;
 245
 246             $e = $p->get_text();
 247             $self->debug("Found script: %s", $e);
 248
 249              if ($e =~ m|\x27PLAYER_CONFIG\x27:\s+(.+)(?:\}\);)?|) {
 250                 my $args = $1;
 251                 $self->debug("Found PLAYER_CONFIG: %s", $args);
 252
 253                 $jsp = videosite::JSArrayParser->new();
 254                 $self->debug("Using %s to parse", ref($jsp));
 255                 $r = $jsp->parse($args);
 256
 257                 unless(defined($r)) {
 258                     $self->error("Found information hash, but could not parse");
 259                     return undef;
 260                 }
 261
 262                 if (exists($r->{'args'}) and exists($r->{'args'}->{'ps'}) and ($r->{'args'}->{'ps'} eq 'live')) {
 263                     $self->error("Video URL seems to point to a live stream, cannot save this");
 264                     return undef;
 265                 }
 266
 267                 if (exists($r->{'args'}) and exists($r->{'args'}->{'fmt_url_map'}) and ($r->{'args'}->{'fmt_url_map'} ne '')) {
 268                     my $urls = $r->{'args'}->{'fmt_url_map'};
 269
 270                     $self->debug("Video has fmt_url_map: %s", $urls);
 271
 272                     %urls = split(/[\|,]/, $urls);
 273                     foreach (keys(%urls)) {
 274                         $urls{$_} = $self->decode_hexurl($urls{$_});
 275                     }
 276                     $self->debug("Pagetype: 2011 (PLAYER_CONFIG), fmt_url_map");
 277                 } elsif (exists($r->{'args'}) and exists($r->{'args'}->{'url_encoded_fmt_stream_map'}) and ($r->{'args'}->{'url_encoded_fmt_stream_map'} ne '')) {
 278                     %urls = %{$self->_decode_url_encoded_fmt_stream_map($r->{'args'}->{'url_encoded_fmt_stream_map'}, 0)};
 279
 280                     $self->debug("Pagetype: 2011 (PLAYER_CONFIG), url_encoded_fmt_stream_map");
 281                 } else {
 282                     $self->error('fmt_url_map not found in PLAYER_CONFIG');
 283                     return undef;
 284                 }
 285             } elsif ($e =~ m|yt\.playerConfig\s*=\s*(.+);\n|) {
 286                 my $args = $1;
 287                 $self->debug("Found yt.playerConfig: %s", $args);
 288
 289                 $jsp = videosite::JSArrayParser->new();
 290                 $self->debug("Using %s to parse", ref($jsp));
 291                 $r = $jsp->parse($args);
 292
 293                 unless(defined($r)) {
 294                     $self->error("Found information hash, but could not parse");
 295                     return undef;
 296                 }
 297
 298                 if (exists($r->{'args'}) and exists($r->{'args'}->{'ps'}) and ($r->{'args'}->{'ps'} eq 'live')) {
 299                     $self->error("Video URL seems to point to a live stream, cannot save this");
 300                     return undef;
 301                 }
 302
 303                 if (exists($r->{'args'}) and exists($r->{'args'}->{'url_encoded_fmt_stream_map'}) and ($r->{'args'}->{'url_encoded_fmt_stream_map'} ne '')) {
 304                     %urls = %{$self->_decode_url_encoded_fmt_stream_map($r->{'args'}->{'url_encoded_fmt_stream_map'}, 0)};
 305
 306                     $self->debug("Pagetype: 2012 (yt.playerConfig), url_encoded_fmt_stream_map");
 307                 } else {
 308                     $self->error('url_map not found in yt.playerConfig');
 309                     return undef;
 310                 }
 311             }
 312
 313
 314             if (%urls) {
 315                 $self->__pick_url(\%urls, $preflist, $metadata);
 316                 last SWF_ARGS;
 317             }
 318         } elsif ('div' eq $tag->[0]) {
 319             if (exists($tag->[1]->{'id'}) and ('watch-player-unavailable-message-container' eq $tag->[1]->{'id'})) {
 320                 # Search forward to the next <div>
 321                 $tag = $p->get_tag('div');
 322                 $self->error("Could not get video data for youtube %s: %s",
 323                         $metadata->{'ID'}, $p->get_trimmed_text());
 324                 return undef;
 325             }
 326         }
 327     }
 328
 329     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 330         $self->error('Could not determine download URL');
 331         return undef;
 332     }
 333
 334     return $metadata;
 335 }
 336
 337 sub __login {
 338     my $self = shift;
 339     my $videourl = shift;
 340     my $ua = shift;
 341     my $user = $self->_getval('USERNAME');
 342     my $pass = $self->_getval('PASSWORD');
 343     my $r;
 344     my $p;
 345     my $c;
 346     my $token;
 347
 348     sub check_cookie {
 349
 350         my $jar = shift;
 351         my $key = shift;
 352         my $found = undef;
 353
 354         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 355
 356         return $found;
 357     }
 358
 359     sub get_all_cookies {
 360
 361         my $jar = shift;
 362         my $key = shift;
 363         my $val = "";
 364         $jar->scan(sub { $val .= "; " if !( $val eq "" ); $val .= "$_[1]=$_[2]" });
 365
 366         return $val;
 367     }
 368
 369     if (($user eq '') or ($pass eq '')) {
 370         $self->error('No username or password defined for YouTube');
 371         return undef;
 372     }
 373
 374     $self->debug('Logging in');
 375     $r = $ua->get('https://www.google.com/accounts/ServiceLoginAuth?service=youtube');
 376     unless($r->is_success()) {
 377         $self->debug("Could not get login page (make sure your LWP supports HTTPS!)");
 378         return undef;
 379     }
 380     $c = $r->decoded_content();
 381     $p = HTML::TokeParser->new(\$c);
 382     while (my $tag = $p->get_tag('input')) {
 383         $self->debug("%s", Dumper($tag));
 384         if ($tag->[1]{name} eq 'GALX') {
 385             $token = $tag->[1]{value};
 386             last;
 387         }
 388     }
 389     $self->debug("GALX = %s", $token);
 390     $r = $ua->post('https://www.google.com/accounts/ServiceLoginAuth?service=youtube', { 'service' => 'youtube', 'Email' => $user, 'Passwd' => $pass, 'GALX' => $token });
 391     unless($r->is_success()) {
 392         $self->debug("Could not get login page (make sure your LWP supports HTTPS!)");
 393         return undef;
 394     }
 395     $c = $r -> decoded_content();
 396     $p = HTML::TokeParser->new(\$c);
 397     while (my $tag = $p->get_tag('script')) {
 398         if($p->get_text() =~ /location\.replace\("(.+)"\)/) {
 399             $token = $1;
 400             $token =~ s/\\x([A-Fa-f0-9]{2})/pack('C', hex($1))/seg;
 401             last;
 402         }
 403     }
 404     $r = $ua->get($token);
 405     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 406         $self->error('Could not log into YouTube');
 407         return undef;
 408     }
 409
 410     $self->debug("Got a cookie");
 411
 412     $r = $ua->get($videourl);
 413     if ($r->base->as_string() =~ m,/verify_age,) {
 414         $self->debug("Looking for session token...");
 415         $c = $r->decoded_content();
 416         $p = HTML::TokeParser->new(\$c);
 417         while (my $tag = $p->get_tag('script')) {
 418             if ($p->get_text() =~ /'XSRF_TOKEN': '(.+)'/) {
 419                 $token = $1;
 420                 last;
 421             }
 422         }
 423
 424         unless(defined($token)) {
 425             $self->error("Could not find session token");
 426             return undef;
 427         }
 428
 429         $self->debug('Authenticating session...');
 430         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 431     }
 432
 433 # Apparently there is no longer a specific "is_adult" cookie
 434 # or, by the looks of it, anything similar
 435 #
 436 #    unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 437 #        $self->error('Could not authenticate session');
 438 #        return undef;
 439 #    }
 440
 441     my $cookie = get_all_cookies($ua->cookie_jar);
 442     return ($ua->get($videourl), $cookie);
 443 }
 444
 445 # Take an encoded url_encoded_fmt_stream_map and return a hash
 446 # matching video IDs to download URLs
 447 sub _decode_url_encoded_fmt_stream_map {
 448     my $self = shift;
 449     my $data = shift;
 450     my $dataencoded = shift;
 451     my @data;
 452     my $h = {};
 453
 454     $data = $self->decode_hexurl($data) if $dataencoded;
 455     # This will
 456     # - Split the decoded string into segments (along ,)
 457     # - Interpret each segment as a concatenated key-value list (key and value separated by =, pairs separated by &
 458     # - URL-decode each key and value _again_
 459     #
 460     # @data will be an array of hash references
 461
 462     @data = map { { map { $self->decode_hexurl($_) } split /[&=]/  } } split /,/, $data;
 463     $self->debug("_decode_url_encoded_fmt_stream_map() decoded %s", Dumper(\@data));
 464
 465     # From each array entry, pick the itag and the url values and return that
 466     # as a hash reference
 467
 468
 469     foreach (@data) {
 470         if (exists($_->{'sig'})) {
 471             $h->{$_->{'itag'}} = sprintf('%s&signature=%s', $_->{'url'}, $_->{'sig'});
 472         } else {
 473             $h->{$_->{'itag'}} =  $_->{'url'};
 474         }
 475     }
 476
 477     return $h;
 478 }
 479
 480
 481
 482 sub __pick_url {
 483     my $self = shift;
 484     my $urls = shift;
 485     my $preflist = shift;
 486     my $metadata = shift;
 487
 488     foreach (keys(%{$urls})) {
 489         if (exists($videoformats{$_})) {
 490             $self->debug('Found URL for format %s (%s): %s', $_, $videoformats{$_}, $urls->{$_});
 491         } else {
 492             $self->error('Unknown format %s: %s', $_, $urls->{$_});
 493         }
 494     }
 495
 496     foreach (@{$preflist}) {
 497         if (exists($urls->{$_})) {
 498             $self->debug("Selected URL with quality level %s", $_);
 499             $metadata->{'DLURL'} = $urls->{$_};
 500             if (exists($videoformats{$_})) {
 501                 $metadata->{'FORMAT'} = $videoformats{$_};
 502             } else {
 503                 $metadata->{'FORMAT'} = 'unknown';
 504             }
 505             last;
 506         }
 507     }
 508
 509     $self->debug('URL found: %s', $metadata->{'DLURL'});
 510 }
 511
 512 1;
 513