videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package YouTubeGrabber;
  10
  11 use GrabberBase;
  12 @ISA = qw(GrabberBase);
  13
  14 use LWP::UserAgent;
  15 use HTTP::Cookies;
  16 use HTML::TokeParser;
  17 use Data::Dumper;
  18
  19 use strict;
  20
  21 sub new {
  22     my $class = shift;
  23     my $self = $class->SUPER::new();
  24
  25     $self->{'NAME'} = 'youtube';
  26     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  27                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];
  28     $self->{'_PARAMS'} = {'QUALITY' => ['normal', 'Quality of the video to download. normal = standard resolution flash video, high = higher resolution flash video, h264 = high resolution MPEG4 video, hd = HD720 rsolution'], 'USERNAME' => ['', 'Username to use for YouTube login'], 'PASSWORD' => ['', 'Password to use for YouTube login']};
  29
  30     bless($self, $class);
  31     $self->_prepare_parameters();
  32
  33     return $self;
  34 }
  35
  36 sub _parse {
  37     my $self = shift;
  38     my $url = shift;
  39     my $pattern = shift;
  40     my $content;
  41     my $metadata = {};
  42     my $p;
  43     my $e;
  44     my $tag;
  45     my $jar = HTTP::Cookies->new;
  46     my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
  47     my $r;
  48     my $videourl;
  49     my $quality = $self->_getval('QUALITY');
  50     my $append = '';
  51
  52     $url =~ m|$pattern|;
  53     $url = $1;
  54
  55     $metadata->{'URL'} = $url;
  56     $metadata->{'ID'} = $2;
  57     $metadata->{'TYPE'} = 'video';
  58     $metadata->{'SOURCE'} = $self->{'NAME'};
  59     $metadata->{'TITLE'} = undef;
  60     $metadata->{'DLURL'} = undef;
  61
  62     if ($quality eq 'high') {
  63         $append = '&fmt=6';
  64     } elsif ($quality eq 'h264') {
  65         $append = '&fmt=18';
  66     } elsif ($quality eq 'hd') {
  67         $append = '&fmt=22';
  68     }
  69
  70     $videourl = sprintf('http://www.youtube.com/watch?v=%s%s', $2, $append);
  71
  72     unless(defined($r = $ua->get($videourl))) {
  73         $self->error('Could not download %s', $url);
  74         return undef;
  75     }
  76
  77     if ($r->base->as_string() =~ m,/verify_age,) {
  78         $self->debug('Video requires age verification');
  79         $ua->cookie_jar($jar);
  80         $r = $self->__login($videourl, $ua);
  81         unless(defined($r)) {
  82             $self->error('Could not log into YouTube');
  83             return undef;
  84         }
  85     }
  86     $content = $r->content();
  87
  88     $p = HTML::TokeParser->new(\$content);
  89
  90     while ($tag = $p->get_tag('div', 'meta', 'script')) {
  91         if ('meta' eq $tag->[0]) {
  92             if ('title' eq $tag->[1]->{'name'}) {
  93                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
  94                 $self->debug('Title found: %s', $metadata->{'TITLE'});
  95             }
  96         } elsif ('script' eq $tag->[0]) {
  97             $e = $p->get_text();
  98             if ($e =~ m|/watch_fullscreen\?(.+)\x27|) {
  99                 my %args = map { split(/=/, $_, 2); } split(/&(?!amp;)/, $1);
 100                 $metadata->{'DLURL'} = sprintf('http://www.youtube.com/get_video.php?video_id=%s&t=%s%s',
 101                         $metadata->{'ID'}, $args{'t'}, $append);
 102                 $self->debug('URL found: %s', $metadata->{'DLURL'});
 103             }
 104         } elsif ('div' eq $tag->[0]) {
 105             if (exists($tag->[1]->{'class'}) and ('errorBox' eq $tag->[1]->{'class'})) {
 106                 $self->error("Could not get video data for youtube %s: %s",
 107                         $metadata->{'ID'}, $p->get_trimmed_text());
 108                 return undef;
 109             }
 110         }
 111     }
 112
 113     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 114         $self->error('Could not determine download URL');
 115         return undef;
 116     }
 117
 118     return $metadata;
 119 }
 120
 121 sub __login {
 122     my $self = shift;
 123     my $videourl = shift;
 124     my $ua = shift;
 125     my $user = $self->_getval('USERNAME');
 126     my $pass = $self->_getval('PASSWORD');
 127     my $r;
 128     my $p;
 129     my $c;
 130     my $token;
 131
 132     sub check_cookie {
 133
 134         my $jar = shift;
 135         my $key = shift;
 136         my $found = undef;
 137
 138         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 139
 140         return $found;
 141     }
 142
 143     if (($user eq '') or ($pass eq '')) {
 144         $self->error('No username or password defined for YouTube');
 145         return undef;
 146     }
 147
 148     $self->debug('Logging in');
 149     $r = $ua->post('http://www.youtube.com/signup', { 'next' => '/', 'current_form' => 'login', 'action_login' => '1', 'username' => $user, 'password' => $pass });
 150
 151     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 152         $self->error('Could not log into YouTube');
 153         return undef;
 154     }
 155
 156     $r = $ua->get($videourl);
 157     if ($r->base->as_string() =~ m,/verify_age,) {
 158         $self->debug("Looking for session token...");
 159         $c = $r->decoded_content();
 160         $p = HTML::TokeParser->new(\$c);
 161         while (my $tag = $p->get_tag('script')) {
 162             if ($p->get_text() =~ /gXSRF_token = '(.+)'/) {
 163                 $token = $1;
 164                 last;
 165             }
 166         }
 167
 168         unless(defined($token)) {
 169             $self->error("Could not find session token");
 170             return undef;
 171         }
 172
 173         $self->debug('Authenticating session...');
 174         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 175     }
 176
 177     unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 178         $self->error('Could not authenticate session');
 179         return undef;
 180     }
 181
 182     return $ua->get($videourl);
 183 }
 184
 185 1;