videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package videosite::YouTubeGrabber;
  10
  11 use videosite::GrabberBase;
  12 @ISA = qw(videosite::GrabberBase);
  13
  14 use LWP::UserAgent;
  15 use HTTP::Cookies;
  16 use HTML::TokeParser;
  17 use Data::Dumper;
  18
  19 use strict;
  20
  21 sub new {
  22     my $class = shift;
  23     my $self = $class->SUPER::new();
  24
  25     $self->{'NAME'} = 'youtube';
  26     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  27                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];
  28     $self->{'_PARAMS'} = {
  29             'QUALITY' => ['normal', 'Quality of the video to download.', {
  30                     'normal' => 'standard resolution flash video',
  31                     'high' => 'higher resolution flash video',
  32                     'h264' => 'high resolution MPEG4 video',
  33                     'hd' => 'HD720 resolution'}],
  34             'USERNAME' => ['', 'Username to use for YouTube login'],
  35             'PASSWORD' => ['', 'Password to use for YouTube login']};
  36
  37     bless($self, $class);
  38     $self->_prepare_parameters();
  39
  40     return $self;
  41 }
  42
  43 sub _parse {
  44     my $self = shift;
  45     my $url = shift;
  46     my $pattern = shift;
  47     my $content;
  48     my $metadata = {};
  49     my $p;
  50     my $e;
  51     my $tag;
  52     my $jar = HTTP::Cookies->new;
  53     my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
  54     my $r;
  55     my $videourl;
  56     my $quality = $self->_getval('QUALITY');
  57     my $append = '';
  58
  59     $url =~ m|$pattern|;
  60     $url = $1;
  61
  62     $metadata->{'URL'} = $url;
  63     $metadata->{'ID'} = $2;
  64     $metadata->{'TYPE'} = 'video';
  65     $metadata->{'SOURCE'} = $self->{'NAME'};
  66     $metadata->{'TITLE'} = undef;
  67     $metadata->{'DLURL'} = undef;
  68
  69     if ($quality eq 'high') {
  70         $append = '&fmt=6';
  71     } elsif ($quality eq 'h264') {
  72         $append = '&fmt=18';
  73     } elsif ($quality eq 'hd') {
  74         $append = '&fmt=22';
  75     }
  76
  77     $videourl = sprintf('http://www.youtube.com/watch?v=%s%s', $2, $append);
  78
  79     unless(defined($r = $ua->get($videourl))) {
  80         $self->error('Could not download %s', $url);
  81         return undef;
  82     }
  83
  84     if ($r->base->as_string() =~ m,/verify_age,) {
  85         $self->debug('Video requires age verification');
  86         $ua->cookie_jar($jar);
  87         $r = $self->__login($videourl, $ua);
  88         unless(defined($r)) {
  89             $self->error('Could not log into YouTube');
  90             return undef;
  91         }
  92     }
  93     $content = $r->content();
  94
  95     $p = HTML::TokeParser->new(\$content);
  96
  97     while ($tag = $p->get_tag('div', 'meta', 'script')) {
  98         if ('meta' eq $tag->[0]) {
  99             if ('title' eq $tag->[1]->{'name'}) {
 100                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
 101                 $self->debug('Title found: %s', $metadata->{'TITLE'});
 102             }
 103         } elsif ('script' eq $tag->[0]) {
 104             $e = $p->get_text();
 105             $self->debug("Found script: %s", $e);
 106             if ($e =~ m|\x22fmt_url_map\x22\s*:\s*\x22([^\x22]+)\x22|) {
 107                 $self->debug("Found fmt_url_map: %s", $1);
 108                 my $urls = $1;
 109                 my @urls;
 110
 111                 $urls =~ s/%(..)/chr(hex($1))/ge;
 112                 @urls = split(/\|/, $urls);
 113
 114                 if ($urls[0] == 5) {
 115                     $metadata->{'DLURL'} = $urls[1];
 116                 } elsif ($urls[0] == 18) {
 117                     $metadata->{'DLURL'} = $urls[3];
 118                 } elsif ($urls[0] == 34) {
 119                     $metadata->{'DLURL'} = $urls[2];
 120                 } else {
 121                     $self->error("Unknown video type in fmt_url_map: %s", $urls[0]);
 122                     next;
 123                 }
 124                 $self->debug('URL found: %s', $metadata->{'DLURL'});
 125             }
 126         } elsif ('div' eq $tag->[0]) {
 127             if (exists($tag->[1]->{'class'}) and ('errorBox' eq $tag->[1]->{'class'})) {
 128                 $self->error("Could not get video data for youtube %s: %s",
 129                         $metadata->{'ID'}, $p->get_trimmed_text());
 130                 return undef;
 131             }
 132         }
 133     }
 134
 135     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 136         $self->error('Could not determine download URL');
 137         return undef;
 138     }
 139
 140     return $metadata;
 141 }
 142
 143 sub __login {
 144     my $self = shift;
 145     my $videourl = shift;
 146     my $ua = shift;
 147     my $user = $self->_getval('USERNAME');
 148     my $pass = $self->_getval('PASSWORD');
 149     my $r;
 150     my $p;
 151     my $c;
 152     my $token;
 153
 154     sub check_cookie {
 155
 156         my $jar = shift;
 157         my $key = shift;
 158         my $found = undef;
 159
 160         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 161
 162         return $found;
 163     }
 164
 165     if (($user eq '') or ($pass eq '')) {
 166         $self->error('No username or password defined for YouTube');
 167         return undef;
 168     }
 169
 170     $self->debug('Logging in');
 171     $r = $ua->post('http://www.youtube.com/signup', { 'next' => '/', 'current_form' => 'login', 'action_login' => '1', 'username' => $user, 'password' => $pass });
 172
 173     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 174         $self->error('Could not log into YouTube');
 175         return undef;
 176     }
 177
 178     $r = $ua->get($videourl);
 179     if ($r->base->as_string() =~ m,/verify_age,) {
 180         $self->debug("Looking for session token...");
 181         $c = $r->decoded_content();
 182         $p = HTML::TokeParser->new(\$c);
 183         while (my $tag = $p->get_tag('script')) {
 184             if ($p->get_text() =~ /gXSRF_token = '(.+)'/) {
 185                 $token = $1;
 186                 last;
 187             }
 188         }
 189
 190         unless(defined($token)) {
 191             $self->error("Could not find session token");
 192             return undef;
 193         }
 194
 195         $self->debug('Authenticating session...');
 196         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 197     }
 198
 199     unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 200         $self->error('Could not authenticate session');
 201         return undef;
 202     }
 203
 204     return $ua->get($videourl);
 205 }
 206
 207 1;