videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package videosite::YouTubeGrabber;
  10
  11 use videosite::GrabberBase;
  12 @ISA = qw(videosite::GrabberBase);
  13
  14 use LWP::UserAgent;
  15 use HTTP::Cookies;
  16 use HTML::TokeParser;
  17 use HTML::Entities qw(decode_entities);
  18 use Encode;
  19 use Data::Dumper;
  20 use videosite::JSArrayParser;
  21
  22 use strict;
  23
  24 sub new {
  25     my $class = shift;
  26     my $self = $class->SUPER::new();
  27
  28     $self->{'NAME'} = 'youtube';
  29     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  30                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\#\!v=([-a-zA-Z0-9_]+))',
  31                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))',
  32                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/([-a-zA-Z0-9_]+))',
  33                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/user/\w+\?.*/([-a-zA-Z0-9_]+))'];
  34     $self->{'_PARAMS'} = {
  35             'QUALITY' => ['normal', 'Quality of the video to download.', {
  36                     'normal' => 'standard resolution flash video',
  37                     'high' => 'higher resolution flash video',
  38                     'h264' => 'high resolution MPEG4 video',
  39                     'hd' => 'HD720 resolution'}],
  40             'USERNAME' => ['', 'Username to use for YouTube login'],
  41             'PASSWORD' => ['', 'Password to use for YouTube login']};
  42
  43     bless($self, $class);
  44     $self->_prepare_parameters();
  45
  46     return $self;
  47 }
  48
  49 sub _parse {
  50     my $self = shift;
  51     my $url = shift;
  52     my $pattern = shift;
  53     my $content;
  54     my $metadata = {};
  55     my $p;
  56     my $e;
  57     my $tag;
  58     my $jar = HTTP::Cookies->new;
  59     my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
  60     my $r;
  61     my $videourl;
  62     my $quality = $self->_getval('QUALITY');
  63     my %preflist = (
  64         'insane' => [38, 37, 22, 35, 18, 34, 6, 5],
  65         'hd' => [37, 22, 35, 18, 34, 6, 5, 38],
  66         'h264' => [18, 34, 37, 22, 35, 6, 5, 38],
  67         'high' => [34, 35, 18, 37, 22, 6, 5, 38],
  68         'normal' => [6, 5, 34, 35, 18, 22, 37, 38]);
  69     my $preflist;
  70     my $jsp;
  71
  72     $url =~ m|$pattern|;
  73     $url = $1;
  74
  75     $metadata->{'URL'} = $url;
  76     $metadata->{'ID'} = $2;
  77     $metadata->{'TYPE'} = 'video';
  78     $metadata->{'SOURCE'} = $self->{'NAME'};
  79     $metadata->{'TITLE'} = undef;
  80     $metadata->{'DLURL'} = undef;
  81     $metadata->{'COOKIE'} = undef;
  82
  83     $self->debug("Matched id %s from pattern %s", $2, $pattern);
  84
  85     $preflist = $preflist{$quality};
  86     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
  87
  88     $videourl = sprintf('http://www.youtube.com/watch?v=%s', $2);
  89
  90     unless(defined($r = $ua->get($videourl))) {
  91         $self->error('Could not download %s', $url);
  92         return undef;
  93     }
  94
  95     if ($r->base->as_string() =~ m,/verify_age,) {
  96         $self->debug('Video requires age verification');
  97         $ua->cookie_jar($jar);
  98         my @logindata = $self->__login($videourl, $ua);
  99         $r = $logindata[0];
 100         $metadata->{'COOKIE'} = $logindata[1];
 101         unless(defined($r)) {
 102             $self->error('Could not log into YouTube');
 103             return undef;
 104         }
 105     }
 106     $content = $r->content();
 107
 108     $p = HTML::TokeParser->new(\$content);
 109
 110     SWF_ARGS: while ($tag = $p->get_tag('div', 'meta', 'script')) {
 111         if ('meta' eq $tag->[0]) {
 112             if ('title' eq $tag->[1]->{'name'}) {
 113                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
 114                 # Convert HTML entities in the title. This is a bit convoluted.
 115                 $metadata->{'TITLE'} = encode("utf8",
 116                                          decode_entities(
 117                                            decode("utf8", $metadata->{'TITLE'})));
 118
 119                 $self->debug('Title found: %s', $metadata->{'TITLE'});
 120             }
 121         } elsif ('script' eq $tag->[0]) {
 122             my %urls;
 123
 124             $e = $p->get_text();
 125             $self->debug("Found script: %s", $e);
 126
 127             if ($e =~ m|\x27SWF_ARGS\x27:\s+(.+),|) {
 128                 my $args = $1;
 129
 130                 $self->debug("Found SWF_ARGS: %s", $args);
 131                 $jsp = videosite::JSArrayParser->new();
 132                 $self->debug("Using %s to parse", ref($jsp));
 133                 $r = $jsp->parse($args);
 134
 135                 unless(defined($r)) {
 136                     $self->error("Found information hash, but could not parse");
 137                     return undef;
 138                 }
 139
 140                 if (exists($r->{'fmt_url_map'}) and ($r->{'fmt_url_map'} ne '')) {
 141                     my $urls =  $r->{'fmt_url_map'};
 142
 143                     $self->debug("Video has fmt_url_map: %s", $urls);
 144
 145                     $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 146                     %urls = split(/[\|,]/, $urls);
 147                     $self->debug("Pagetype: old (SWF_ARGS), fmt_url_map");
 148
 149                 } elsif (exists($r->{'t'}) and ($r->{'t'} ne '')) {
 150                     my $thash = $r->{'t'};
 151
 152                     if (exists($r->{'fmt_map'}) && ($r->{'fmt_map'} ne '')) {
 153                         my $fmt = $r->{'fmt_map'};
 154                         my @fmt;
 155
 156                         $self->debug('Video has fmt_map');
 157                         $fmt =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 158                         @fmt = split(/,/, $fmt);
 159                         foreach (@fmt) {
 160                             @_=split(/\//);
 161                             $urls{$_[0]} =  sprintf('http://www.youtube.com/get_video?video_id=%s&fmt=%d&t=%s',
 162                                 $metadata->{'ID'},
 163                                 $_[0],
 164                                 $thash);
 165                         }
 166                         $self->debug("Pagetype: 2009 (SWF_ARGS), t with fmt_map");
 167
 168                     } else {
 169                         $urls{5} = sprintf('http://www.youtube.com/get_video?video_id=%s&t=%s',
 170                             $metadata->{'ID'},
 171                             $thash);
 172                         $self->debug("Pagetype: 2009 (SWF_ARGS), t without fmt_map");
 173                     }
 174                 } else {
 175                     $self->error('Neither fmt_url_map nor t found in video information hash');
 176                     return undef;
 177                 }
 178             } elsif ($e =~ m|var swfHTML = .*fmt_url_map=([^\&]+)\&|) {
 179                 my $urls = $1;
 180                 $self->debug("Video has fmt_url_map: %s", $urls);
 181
 182                 $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 183                 %urls = split(/[\|,]/, $urls);
 184                 $self->debug("Pagetype: 2010 (swfHTML), fmt_url_map");
 185             }
 186
 187             if (%urls) {
 188                 foreach (keys(%urls)) {
 189                     if ($_ == 35) {
 190                         $self->debug('Found flv,h264,large: %s', $urls{$_});
 191                     } elsif ($_ == 34) {
 192                         $self->debug('Found flv,h264: %s', $urls{$_});
 193                     } elsif ($_ == 22) {
 194                         $self->debug('Found mp4,h264,720p: %s', $urls{$_});
 195                     } elsif ($_ == 38) {
 196                         $self->debug('Found mp4,h264,4k: %s', $urls{$_});
 197                     } elsif ($_ == 37) {
 198                         $self->debug('Found mp4,h264,1080p: %s', $urls{$_});
 199                     } elsif ($_ == 18) {
 200                         $self->debug('Found mp4,h264: %s', $urls{$_});
 201                     } elsif ($_ == 5) {
 202                         $self->debug('Found flv,flv: %s', $urls{$_});
 203                     } else {
 204                         $self->error('Unknown tag %s: %s', $_, $urls{$_});
 205                     }
 206                 }
 207
 208                 foreach (@{$preflist}) {
 209                     if (exists($urls{$_})) {
 210                         $self->debug("Selected URL with quality level %s", $_);
 211                         $metadata->{'DLURL'} = $urls{$_};
 212                         last;
 213                     }
 214                 }
 215
 216                 $self->debug('URL found: %s', $metadata->{'DLURL'});
 217                 last SWF_ARGS;
 218             }
 219         } elsif ('div' eq $tag->[0]) {
 220             if (exists($tag->[1]->{'class'}) and ('yt-alert-content' eq $tag->[1]->{'class'})) {
 221                 $self->error("Could not get video data for youtube %s: %s",
 222                         $metadata->{'ID'}, $p->get_trimmed_text());
 223                 return undef;
 224             }
 225         }
 226     }
 227
 228     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 229         $self->error('Could not determine download URL');
 230         return undef;
 231     }
 232
 233     return $metadata;
 234 }
 235
 236 sub __login {
 237     my $self = shift;
 238     my $videourl = shift;
 239     my $ua = shift;
 240     my $user = $self->_getval('USERNAME');
 241     my $pass = $self->_getval('PASSWORD');
 242     my $r;
 243     my $p;
 244     my $c;
 245     my $token;
 246
 247     sub check_cookie {
 248
 249         my $jar = shift;
 250         my $key = shift;
 251         my $found = undef;
 252
 253         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 254
 255         return $found;
 256     }
 257
 258     sub get_all_cookies {
 259
 260         my $jar = shift;
 261         my $key = shift;
 262         my $val = "";
 263         $jar->scan(sub { $val .= "; " if !( $val eq "" ); $val .= "$_[1]=$_[2]" });
 264
 265         return $val;
 266     }
 267
 268     if (($user eq '') or ($pass eq '')) {
 269         $self->error('No username or password defined for YouTube');
 270         return undef;
 271     }
 272
 273     $self->debug('Logging in');
 274     $r = $ua->get('https://www.google.com/accounts/ServiceLoginAuth?service=youtube');
 275     $c = $r->decoded_content();
 276     $p = HTML::TokeParser->new(\$c);
 277     while (my $tag = $p->get_tag('input')) {
 278         if ($tag->[1]{name} eq 'GALX') {
 279             $token = $tag->[1]{value};
 280             last;
 281         }
 282     }
 283     $self->debug("GALX = .$token");
 284     $r = $ua->post('https://www.google.com/accounts/ServiceLoginAuth?service=youtube', { 'service' => 'youtube', 'Email' => $user, 'Passwd' => $pass, 'GALX' => $token });
 285     $c = $r -> decoded_content();
 286     $p = HTML::TokeParser->new(\$c);
 287     while (my $tag = $p->get_tag('script')) {
 288         if($p->get_text() =~ /location\.replace\("(.+)"\)/) {
 289             $token = $1;
 290             $token =~ s/\\x([A-Fa-f0-9]{2})/pack('C', hex($1))/seg;
 291             last;
 292         }
 293     }
 294     $r = $ua->get($token);
 295     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 296         $self->error('Could not log into YouTube');
 297         return undef;
 298     }
 299
 300     $self->debug("Got a cookie");
 301
 302     $r = $ua->get($videourl);
 303     if ($r->base->as_string() =~ m,/verify_age,) {
 304         $self->debug("Looking for session token...");
 305         $c = $r->decoded_content();
 306         $p = HTML::TokeParser->new(\$c);
 307         while (my $tag = $p->get_tag('script')) {
 308             if ($p->get_text() =~ /'XSRF_TOKEN': '(.+)'/) {
 309                 $token = $1;
 310                 last;
 311             }
 312         }
 313
 314         unless(defined($token)) {
 315             $self->error("Could not find session token");
 316             return undef;
 317         }
 318
 319         $self->debug('Authenticating session...');
 320         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 321     }
 322
 323 # Apparently there is no longer a specific "is_adult" cookie
 324 # or, by the looks of it, anything similar
 325 #
 326 #    unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 327 #        $self->error('Could not authenticate session');
 328 #        return undef;
 329 #    }
 330
 331     my $cookie = get_all_cookies($ua->cookie_jar);
 332     return ($ua->get($videourl), $cookie);
 333 }
 334
 335 1;