videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package YouTubeGrabber;
  10
  11 use GrabberBase;
  12 @ISA = qw(GrabberBase);
  13
  14 use LWP::UserAgent;
  15 use HTTP::Cookies;
  16 use HTML::TokeParser;
  17 use Data::Dumper;
  18
  19 use strict;
  20
  21 sub new {
  22     my $class = shift;
  23     my $self = $class->SUPER::new();
  24
  25     $self->{'NAME'} = 'youtube';
  26     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  27                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];
  28     $self->{'_PARAMS'} = {'USERNAME' => ['', 'Username to use for YouTube login'], 'PASSWORD' => ['', 'Password to use for YouTube login']};
  29
  30     bless($self, $class);
  31     $self->_prepare_parameters();
  32
  33     return $self;
  34 }
  35
  36 sub _parse {
  37     my $self = shift;
  38     my $url = shift;
  39     my $pattern = shift;
  40     my $content;
  41     my $metadata = {};
  42     my $p;
  43     my $e;
  44     my $tag;
  45     my $jar = HTTP::Cookies->new;
  46     my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
  47     my $r;
  48     my $videourl;
  49
  50     $url =~ m|$pattern|;
  51     $url = $1;
  52
  53     $metadata->{'URL'} = $url;
  54     $metadata->{'ID'} = $2;
  55     $metadata->{'TYPE'} = 'video';
  56     $metadata->{'SOURCE'} = $self->{'NAME'};
  57     $metadata->{'TITLE'} = undef;
  58     $metadata->{'DLURL'} = undef;
  59
  60     $videourl = sprintf('http://www.youtube.com/watch?v=%s', $2);
  61
  62     unless(defined($r = $ua->get($videourl))) {
  63         $self->error('Could not download %s', $url);
  64         return undef;
  65     }
  66
  67     if ($r->base->as_string() =~ m,/verify_age,) {
  68         $self->debug('Video requires age verification');
  69         $ua->cookie_jar($jar);
  70         $r = $self->__login($videourl, $ua);
  71         unless(defined($r)) {
  72             $self->error('Could not log into YouTube');
  73             return undef;
  74         }
  75     }
  76     $content = $r->decoded_content();
  77
  78     $p = HTML::TokeParser->new(\$content);
  79
  80     while ($tag = $p->get_tag('div', 'meta', 'script')) {
  81         if ('meta' eq $tag->[0]) {
  82             if ('title' eq $tag->[1]->{'name'}) {
  83                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
  84                 $self->debug('Title found: %s', $metadata->{'TITLE'});
  85             }
  86         } elsif ('script' eq $tag->[0]) {
  87             $e = $p->get_text();
  88             if ($e =~ m|/watch_fullscreen\?(.+)\x27|) {
  89                 my %args = map { split(/=/, $_, 2); } split(/&/, $1);
  90                 $metadata->{'DLURL'} = sprintf('http://www.youtube.com/get_video.php?video_id=%s&t=%s',
  91                         $metadata->{'ID'}, $args{'t'});
  92                 $self->debug('URL found: %s', $metadata->{'DLURL'});
  93             }
  94         } elsif ('div' eq $tag->[0]) {
  95             if ('errorBox' eq $tag->[1]->{'class'}) {
  96                 $self->error("Could not get video data for youtube %s: %s",
  97                         $metadata->{'ID'}, $p->get_trimmed_text());
  98                 return undef;
  99             }
 100         }
 101     }
 102
 103     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 104         $self->error('Could not determine download URL');
 105         return undef;
 106     }
 107
 108     return $metadata;
 109 }
 110
 111 sub __login {
 112     my $self = shift;
 113     my $videourl = shift;
 114     my $ua = shift;
 115     my $user = $self->_getval('USERNAME');
 116     my $pass = $self->_getval('PASSWORD');
 117     my $r;
 118     my $p;
 119     my $c;
 120     my $token;
 121
 122     sub check_cookie {
 123
 124         my $jar = shift;
 125         my $key = shift;
 126         my $found = undef;
 127
 128         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 129
 130         return $found;
 131     }
 132
 133     if (($user eq '') or ($pass eq '')) {
 134         $self->error('No username or password defined for YouTube');
 135         return undef;
 136     }
 137
 138     $self->debug('Logging in');
 139     $r = $ua->post('http://www.youtube.com/signup', { 'next' => '/', 'current_form' => 'login', 'action_login' => '1', 'username' => $user, 'password' => $pass });
 140
 141     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 142         $self->error('Could not log into YouTube');
 143         return undef;
 144     }
 145
 146     $r = $ua->get($videourl);
 147     if ($r->base->as_string() =~ m,/verify_age,) {
 148         $self->debug("Looking for session token...");
 149         $c = $r->decoded_content();
 150         $p = HTML::TokeParser->new(\$c);
 151         while (my $tag = $p->get_tag('script')) {
 152             if ($p->get_text() =~ /gXSRF_token = '(.+)'/) {
 153                 $token = $1;
 154                 last;
 155             }
 156         }
 157
 158         unless(defined($token)) {
 159             $self->error("Could not find session token");
 160             return undef;
 161         }
 162
 163         $self->debug('Authenticating session...');
 164         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 165     }
 166
 167     unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 168         $self->error('Could not authenticate session');
 169         return undef;
 170     }
 171
 172     return $ua->get($videourl);
 173 }
 174
 175 1;