videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package videosite::YouTubeGrabber;
  10
  11 use videosite::GrabberBase;
  12 @ISA = qw(videosite::GrabberBase);
  13
  14 use LWP::UserAgent;
  15 use HTTP::Cookies;
  16 use HTML::TokeParser;
  17 use HTML::Entities qw(decode_entities);
  18 use Encode;
  19 use Data::Dumper;
  20 use videosite::JSArrayParser;
  21
  22 use strict;
  23
  24 sub new {
  25     my $class = shift;
  26     my $self = $class->SUPER::new();
  27
  28     $self->{'NAME'} = 'youtube';
  29     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  30                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];
  31     $self->{'_PARAMS'} = {
  32             'QUALITY' => ['normal', 'Quality of the video to download.', {
  33                     'normal' => 'standard resolution flash video',
  34                     'high' => 'higher resolution flash video',
  35                     'h264' => 'high resolution MPEG4 video',
  36                     'hd' => 'HD720 resolution'}],
  37             'USERNAME' => ['', 'Username to use for YouTube login'],
  38             'PASSWORD' => ['', 'Password to use for YouTube login']};
  39
  40     bless($self, $class);
  41     $self->_prepare_parameters();
  42
  43     return $self;
  44 }
  45
  46 sub _parse {
  47     my $self = shift;
  48     my $url = shift;
  49     my $pattern = shift;
  50     my $content;
  51     my $metadata = {};
  52     my $p;
  53     my $e;
  54     my $tag;
  55     my $jar = HTTP::Cookies->new;
  56     my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
  57     my $r;
  58     my $videourl;
  59     my $quality = $self->_getval('QUALITY');
  60     my %preflist = (
  61         'hd' => [37, 22, 35, 18, 34, 6, 5],
  62         'h264' => [18, 34, 37, 22, 35, 6, 5],
  63         'high' => [34, 35, 18, 37, 22, 6, 5],
  64         'normal' => [6, 5, 34, 35, 18, 22, 37]);
  65     my $preflist;
  66     my $jsp;
  67
  68     $url =~ m|$pattern|;
  69     $url = $1;
  70
  71     $metadata->{'URL'} = $url;
  72     $metadata->{'ID'} = $2;
  73     $metadata->{'TYPE'} = 'video';
  74     $metadata->{'SOURCE'} = $self->{'NAME'};
  75     $metadata->{'TITLE'} = undef;
  76     $metadata->{'DLURL'} = undef;
  77
  78     $self->debug("Matched id %s from pattern %s", $2, $pattern);
  79
  80     $preflist = $preflist{$quality};
  81     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
  82
  83     $videourl = sprintf('http://www.youtube.com/watch?v=%s', $2);
  84
  85     unless(defined($r = $ua->get($videourl))) {
  86         $self->error('Could not download %s', $url);
  87         return undef;
  88     }
  89
  90     if ($r->base->as_string() =~ m,/verify_age,) {
  91         $self->debug('Video requires age verification');
  92         $ua->cookie_jar($jar);
  93         $r = $self->__login($videourl, $ua);
  94         unless(defined($r)) {
  95             $self->error('Could not log into YouTube');
  96             return undef;
  97         }
  98     }
  99     $content = $r->content();
 100
 101     $p = HTML::TokeParser->new(\$content);
 102
 103     SWF_ARGS: while ($tag = $p->get_tag('div', 'meta', 'script')) {
 104         if ('meta' eq $tag->[0]) {
 105             if ('title' eq $tag->[1]->{'name'}) {
 106                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
 107                 # Convert HTML entities in the title. This is a bit convoluted.
 108                 $metadata->{'TITLE'} = encode("utf8",
 109                                          decode_entities(
 110                                            decode("utf8", $metadata->{'TITLE'})));
 111
 112                 $self->debug('Title found: %s', $metadata->{'TITLE'});
 113             }
 114         } elsif ('script' eq $tag->[0]) {
 115             $e = $p->get_text();
 116             $self->debug("Found script: %s", $e);
 117             if ($e =~ m|\x27SWF_ARGS\x27:\s+(.+),|) {
 118                 my %urls;
 119                 my $args = $1;
 120
 121                 $self->debug("Found SWF_ARGS: %s", $args);
 122                 $jsp = videosite::JSArrayParser->new();
 123                 $self->debug("Using %s to parse", ref($jsp));
 124                 $r = $jsp->parse($args);
 125
 126                 unless(defined($r)) {
 127                     $self->error("Found information hash, but could not parse");
 128                     return undef;
 129                 }
 130
 131                 if (exists($r->{'fmt_url_map'}) and ($r->{'fmt_url_map'} ne '')) {
 132                     my $urls =  $r->{'fmt_url_map'};
 133
 134                     $self->debug("Video has fmt_url_map: %s", $urls);
 135
 136                     $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 137                     %urls = split(/[\|,]/, $urls);
 138                 } elsif (exists($r->{'t'}) and ($r->{'t'} ne '')) {
 139                     my $thash = $r->{'t'};
 140
 141                     if (exists($r->{'fmt_map'}) && ($r->{'fmt_map'} ne '')) {
 142                         my $fmt = $r->{'fmt_map'};
 143                         my @fmt;
 144
 145                         $self->debug('Video has fmt_map');
 146                         $fmt =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 147                         @fmt = split(/,/, $fmt);
 148                         foreach (@fmt) {
 149                             split(/\//);
 150                             $urls{$_[0]} =  sprintf('http://www.youtube.com/get_video?video_id=%s&fmt=%d&t=%s',
 151                                 $metadata->{'ID'},
 152                                 $_[0],
 153                                 $thash);
 154                         }
 155                     } else {
 156                         $urls{5} = sprintf('http://www.youtube.com/get_video?video_id=%s&t=%s',
 157                             $metadata->{'ID'},
 158                             $thash);
 159                     }
 160                 } else {
 161                     $self->error('Neither fmt_url_map nor t found in video information hash');
 162                     return undef;
 163                 }
 164                 $self->debug("Found quality levels [%s]", join(", ", keys(%urls)));
 165
 166                 foreach (keys(%urls)) {
 167                     if ($_ == 35) {
 168                         $self->debug('Found flv,h264,large: %s', $urls{$_});
 169                     } elsif ($_ == 34) {
 170                         $self->debug('Found flv,h264: %s', $urls{$_});
 171                     } elsif ($_ == 22) {
 172                         $self->debug('Found mp4,h264,720p: %s', $urls{$_});
 173                     } elsif ($_ == 37) {
 174                         $self->debug('Found mp4,h264,1080p: %s', $urls{$_});
 175                     } elsif ($_ == 18) {
 176                         $self->debug('Found mp4,h264: %s', $urls{$_});
 177                     } elsif ($_ == 5) {
 178                         $self->debug('Found flv,flv: %s', $urls{$_});
 179                     } else {
 180                         $self->error('Unknown tag %s: %s', $_, $urls{$_});
 181                     }
 182                 }
 183
 184                 foreach (@{$preflist}) {
 185                     if (exists($urls{$_})) {
 186                         $self->debug("Selected URL with quality level %s", $_);
 187                         $metadata->{'DLURL'} = $urls{$_};
 188                         last;
 189                     }
 190                 }
 191
 192                 $self->debug('URL found: %s', $metadata->{'DLURL'});
 193                 last SWF_ARGS;
 194             }
 195         } elsif ('div' eq $tag->[0]) {
 196             if (exists($tag->[1]->{'class'}) and ('yt-alert-content' eq $tag->[1]->{'class'})) {
 197                 $self->error("Could not get video data for youtube %s: %s",
 198                         $metadata->{'ID'}, $p->get_trimmed_text());
 199                 return undef;
 200             }
 201         }
 202     }
 203
 204     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 205         $self->error('Could not determine download URL');
 206         return undef;
 207     }
 208
 209     return $metadata;
 210 }
 211
 212 sub __login {
 213     my $self = shift;
 214     my $videourl = shift;
 215     my $ua = shift;
 216     my $user = $self->_getval('USERNAME');
 217     my $pass = $self->_getval('PASSWORD');
 218     my $r;
 219     my $p;
 220     my $c;
 221     my $token;
 222
 223     sub check_cookie {
 224
 225         my $jar = shift;
 226         my $key = shift;
 227         my $found = undef;
 228
 229         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 230
 231         return $found;
 232     }
 233
 234     if (($user eq '') or ($pass eq '')) {
 235         $self->error('No username or password defined for YouTube');
 236         return undef;
 237     }
 238
 239     $self->debug('Logging in');
 240     $r = $ua->post('http://www.youtube.com/signup', { 'next' => '/', 'current_form' => 'login', 'action_login' => '1', 'username' => $user, 'password' => $pass });
 241
 242     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 243         $self->error('Could not log into YouTube');
 244         return undef;
 245     }
 246
 247     $r = $ua->get($videourl);
 248     if ($r->base->as_string() =~ m,/verify_age,) {
 249         $self->debug("Looking for session token...");
 250         $c = $r->decoded_content();
 251         $p = HTML::TokeParser->new(\$c);
 252         while (my $tag = $p->get_tag('script')) {
 253             if ($p->get_text() =~ /gXSRF_token = '(.+)'/) {
 254                 $token = $1;
 255                 last;
 256             }
 257         }
 258
 259         unless(defined($token)) {
 260             $self->error("Could not find session token");
 261             return undef;
 262         }
 263
 264         $self->debug('Authenticating session...');
 265         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 266     }
 267
 268     unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 269         $self->error('Could not authenticate session');
 270         return undef;
 271     }
 272
 273     return $ua->get($videourl);
 274 }
 275
 276 1;