videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package videosite::YouTubeGrabber;
  10
  11 use videosite::GrabberBase;
  12 @ISA = qw(videosite::GrabberBase);
  13
  14 use LWP::UserAgent;
  15 use HTTP::Cookies;
  16 use HTML::TokeParser;
  17 use HTML::Entities qw(decode_entities);
  18 use Encode;
  19 use Data::Dumper;
  20 use videosite::JSArrayParser;
  21
  22 use strict;
  23
  24 sub new {
  25     my $class = shift;
  26     my $self = $class->SUPER::new();
  27
  28     $self->{'NAME'} = 'youtube';
  29     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  30                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\#\!v=([-a-zA-Z0-9_]+))',
  31                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))',
  32                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/watch\?v=([-a-zA-Z0-9_]+))',
  33                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/([-a-zA-Z0-9_]+))',
  34                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/user/\w+\?.*/([-a-zA-Z0-9_]+))'];
  35     $self->{'_PARAMS'} = {
  36             'QUALITY' => ['normal', 'Quality of the video to download.', {
  37                     'normal' => 'standard resolution flash video',
  38                     'high' => 'higher resolution flash video',
  39                     'h264' => 'high resolution MPEG4 video',
  40                     'hd' => 'HD720 resolution'}],
  41             'USERNAME' => ['', 'Username to use for YouTube login'],
  42             'PASSWORD' => ['', 'Password to use for YouTube login']};
  43
  44     bless($self, $class);
  45     $self->_prepare_parameters();
  46
  47     return $self;
  48 }
  49
  50 sub _parse {
  51     my $self = shift;
  52     my $url = shift;
  53     my $pattern = shift;
  54     my $content;
  55     my $metadata = {};
  56     my $p;
  57     my $e;
  58     my $tag;
  59     my $jar = HTTP::Cookies->new;
  60     my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
  61     my $r;
  62     my $videourl;
  63     my $quality = $self->_getval('QUALITY');
  64     my %preflist = (
  65         'insane' => [38, 37, 22, 35, 18, 34, 6, 5],
  66         'hd' => [37, 22, 35, 18, 34, 6, 5, 38],
  67         'h264' => [18, 34, 37, 22, 35, 6, 5, 38],
  68         'high' => [34, 35, 18, 37, 22, 6, 5, 38],
  69         'normal' => [6, 5, 34, 35, 18, 22, 37, 38]);
  70     my %videoformats = (
  71         38 => 'mp4,h264,4k',
  72         37 => 'mp4,h264,1080p',
  73         35 => 'flv,h264,large',
  74         34 => 'flv,h264',
  75         22 => 'mp4,h264,720p',
  76         18 => 'mp4,h264',
  77         5 => 'flv,flv',
  78         );
  79     my $preflist;
  80     my $jsp;
  81
  82     $url =~ m|$pattern|;
  83     $url = $1;
  84
  85     $metadata->{'URL'} = $url;
  86     $metadata->{'ID'} = $2;
  87     $metadata->{'TYPE'} = 'video';
  88     $metadata->{'SOURCE'} = $self->{'NAME'};
  89     $metadata->{'TITLE'} = undef;
  90     $metadata->{'DLURL'} = undef;
  91     $metadata->{'COOKIE'} = undef;
  92
  93     $self->debug("Matched id %s from pattern %s", $2, $pattern);
  94
  95     $preflist = $preflist{$quality};
  96     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
  97
  98     $videourl = sprintf('http://www.youtube.com/watch?v=%s', $2);
  99
 100     unless(defined($r = $ua->get($videourl))) {
 101         $self->error('Could not download %s', $url);
 102         return undef;
 103     }
 104
 105     if ($r->base->as_string() =~ m,/verify_age,) {
 106         $self->debug('Video requires age verification');
 107         $ua->cookie_jar($jar);
 108         my @logindata = $self->__login($videourl, $ua);
 109         $r = $logindata[0];
 110         $metadata->{'COOKIE'} = $logindata[1];
 111         unless(defined($r)) {
 112             $self->error('Could not log into YouTube');
 113             return undef;
 114         }
 115     }
 116     $content = $r->content();
 117
 118     $p = HTML::TokeParser->new(\$content);
 119
 120     SWF_ARGS: while ($tag = $p->get_tag('div', 'meta', 'script')) {
 121         if ('meta' eq $tag->[0]) {
 122             if ('title' eq $tag->[1]->{'name'}) {
 123                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
 124                 # Convert HTML entities in the title. This is a bit convoluted.
 125                 $metadata->{'TITLE'} = encode("utf8",
 126                                          decode_entities(
 127                                            decode("utf8", $metadata->{'TITLE'})));
 128
 129                 $self->debug('Title found: %s', $metadata->{'TITLE'});
 130             }
 131         } elsif ('script' eq $tag->[0]) {
 132             my %urls;
 133
 134             $e = $p->get_text();
 135             $self->debug("Found script: %s", $e);
 136
 137             if ($e =~ m|\x27SWF_ARGS\x27:\s+(.+),|) {
 138                 my $args = $1;
 139
 140                 $self->debug("Found SWF_ARGS: %s", $args);
 141                 $jsp = videosite::JSArrayParser->new();
 142                 $self->debug("Using %s to parse", ref($jsp));
 143                 $r = $jsp->parse($args);
 144
 145                 unless(defined($r)) {
 146                     $self->error("Found information hash, but could not parse");
 147                     return undef;
 148                 }
 149
 150                 if (exists($r->{'fmt_url_map'}) and ($r->{'fmt_url_map'} ne '')) {
 151                     my $urls =  $r->{'fmt_url_map'};
 152
 153                     $self->debug("Video has fmt_url_map: %s", $urls);
 154
 155                     $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 156                     %urls = split(/[\|,]/, $urls);
 157                     $self->debug("Pagetype: old (SWF_ARGS), fmt_url_map");
 158
 159                 } elsif (exists($r->{'t'}) and ($r->{'t'} ne '')) {
 160                     my $thash = $r->{'t'};
 161
 162                     if (exists($r->{'fmt_map'}) && ($r->{'fmt_map'} ne '')) {
 163                         my $fmt = $r->{'fmt_map'};
 164                         my @fmt;
 165
 166                         $self->debug('Video has fmt_map');
 167                         $fmt =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 168                         @fmt = split(/,/, $fmt);
 169                         foreach (@fmt) {
 170                             @_=split(/\//);
 171                             $urls{$_[0]} =  sprintf('http://www.youtube.com/get_video?video_id=%s&fmt=%d&t=%s',
 172                                 $metadata->{'ID'},
 173                                 $_[0],
 174                                 $thash);
 175                         }
 176                         $self->debug("Pagetype: 2009 (SWF_ARGS), t with fmt_map");
 177
 178                     } else {
 179                         $urls{5} = sprintf('http://www.youtube.com/get_video?video_id=%s&t=%s',
 180                             $metadata->{'ID'},
 181                             $thash);
 182                         $self->debug("Pagetype: 2009 (SWF_ARGS), t without fmt_map");
 183                     }
 184                 } else {
 185                     $self->error('Neither fmt_url_map nor t found in video information hash');
 186                     return undef;
 187                 }
 188             } elsif ($e =~ m|var swfHTML = .*fmt_url_map=([^\&]+)\&|) {
 189                 my $urls = $1;
 190                 $self->debug("Video has fmt_url_map: %s", $urls);
 191
 192                 $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 193                 %urls = split(/[\|,]/, $urls);
 194                 $self->debug("Pagetype: 2010 (swfHTML), fmt_url_map");
 195             }
 196
 197             if (%urls) {
 198                 foreach (keys(%urls)) {
 199                     if (exists($videoformats{$_})) {
 200                         $self->debug('Found URL for format %s (%s): %s', $_, $videoformats{$_}, $urls{$_});
 201                     } else {
 202                         $self->error('Unknown format %s: %s', $_, $urls{$_});
 203                     }
 204                 }
 205
 206                 foreach (@{$preflist}) {
 207                     if (exists($urls{$_})) {
 208                         $self->debug("Selected URL with quality level %s", $_);
 209                         $metadata->{'DLURL'} = $urls{$_};
 210                         last;
 211                     }
 212                 }
 213
 214                 $self->debug('URL found: %s', $metadata->{'DLURL'});
 215                 last SWF_ARGS;
 216             }
 217         } elsif ('div' eq $tag->[0]) {
 218             if (exists($tag->[1]->{'class'}) and ('yt-alert-content' eq $tag->[1]->{'class'})) {
 219                 $self->error("Could not get video data for youtube %s: %s",
 220                         $metadata->{'ID'}, $p->get_trimmed_text());
 221                 return undef;
 222             }
 223         }
 224     }
 225
 226     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 227         $self->error('Could not determine download URL');
 228         return undef;
 229     }
 230
 231     return $metadata;
 232 }
 233
 234 sub __login {
 235     my $self = shift;
 236     my $videourl = shift;
 237     my $ua = shift;
 238     my $user = $self->_getval('USERNAME');
 239     my $pass = $self->_getval('PASSWORD');
 240     my $r;
 241     my $p;
 242     my $c;
 243     my $token;
 244
 245     sub check_cookie {
 246
 247         my $jar = shift;
 248         my $key = shift;
 249         my $found = undef;
 250
 251         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 252
 253         return $found;
 254     }
 255
 256     sub get_all_cookies {
 257
 258         my $jar = shift;
 259         my $key = shift;
 260         my $val = "";
 261         $jar->scan(sub { $val .= "; " if !( $val eq "" ); $val .= "$_[1]=$_[2]" });
 262
 263         return $val;
 264     }
 265
 266     if (($user eq '') or ($pass eq '')) {
 267         $self->error('No username or password defined for YouTube');
 268         return undef;
 269     }
 270
 271     $self->debug('Logging in');
 272     $r = $ua->get('https://www.google.com/accounts/ServiceLoginAuth?service=youtube');
 273     unless($r->is_success()) {
 274         $self->debug("Could not get login page (make sure your LWP supports HTTPS!)");
 275         return undef;
 276     }
 277     $c = $r->decoded_content();
 278     $p = HTML::TokeParser->new(\$c);
 279     while (my $tag = $p->get_tag('input')) {
 280         $self->debug("%s", Dumper($tag));
 281         if ($tag->[1]{name} eq 'GALX') {
 282             $token = $tag->[1]{value};
 283             last;
 284         }
 285     }
 286     $self->debug("GALX = %s", $token);
 287     $r = $ua->post('https://www.google.com/accounts/ServiceLoginAuth?service=youtube', { 'service' => 'youtube', 'Email' => $user, 'Passwd' => $pass, 'GALX' => $token });
 288     unless($r->is_success()) {
 289         $self->debug("Could not get login page (make sure your LWP supports HTTPS!)");
 290         return undef;
 291     }
 292     $c = $r -> decoded_content();
 293     $p = HTML::TokeParser->new(\$c);
 294     while (my $tag = $p->get_tag('script')) {
 295         if($p->get_text() =~ /location\.replace\("(.+)"\)/) {
 296             $token = $1;
 297             $token =~ s/\\x([A-Fa-f0-9]{2})/pack('C', hex($1))/seg;
 298             last;
 299         }
 300     }
 301     $r = $ua->get($token);
 302     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 303         $self->error('Could not log into YouTube');
 304         return undef;
 305     }
 306
 307     $self->debug("Got a cookie");
 308
 309     $r = $ua->get($videourl);
 310     if ($r->base->as_string() =~ m,/verify_age,) {
 311         $self->debug("Looking for session token...");
 312         $c = $r->decoded_content();
 313         $p = HTML::TokeParser->new(\$c);
 314         while (my $tag = $p->get_tag('script')) {
 315             if ($p->get_text() =~ /'XSRF_TOKEN': '(.+)'/) {
 316                 $token = $1;
 317                 last;
 318             }
 319         }
 320
 321         unless(defined($token)) {
 322             $self->error("Could not find session token");
 323             return undef;
 324         }
 325
 326         $self->debug('Authenticating session...');
 327         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 328     }
 329
 330 # Apparently there is no longer a specific "is_adult" cookie
 331 # or, by the looks of it, anything similar
 332 #
 333 #    unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 334 #        $self->error('Could not authenticate session');
 335 #        return undef;
 336 #    }
 337
 338     my $cookie = get_all_cookies($ua->cookie_jar);
 339     return ($ua->get($videourl), $cookie);
 340 }
 341
 342 1;