videosite/YouTubeGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for youtube.com/de/...
   5 #
   6 # download strategy revised using
   7 # http://www.kde-apps.org/content/show.php?content=41456
   8
   9 package videosite::YouTubeGrabber;
  10
  11 use videosite::GrabberBase;
  12 @ISA = qw(videosite::GrabberBase);
  13
  14 use LWP::UserAgent;
  15 use HTTP::Cookies;
  16 use HTML::TokeParser;
  17 use Data::Dumper;
  18
  19 use strict;
  20
  21 sub new {
  22     my $class = shift;
  23     my $self = $class->SUPER::new();
  24
  25     $self->{'NAME'} = 'youtube';
  26     $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
  27                            '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];
  28     $self->{'_PARAMS'} = {
  29             'QUALITY' => ['normal', 'Quality of the video to download.', {
  30                     'normal' => 'standard resolution flash video',
  31                     'high' => 'higher resolution flash video',
  32                     'h264' => 'high resolution MPEG4 video',
  33                     'hd' => 'HD720 resolution'}],
  34             'USERNAME' => ['', 'Username to use for YouTube login'],
  35             'PASSWORD' => ['', 'Password to use for YouTube login']};
  36
  37     bless($self, $class);
  38     $self->_prepare_parameters();
  39
  40     return $self;
  41 }
  42
  43 sub _parse {
  44     my $self = shift;
  45     my $url = shift;
  46     my $pattern = shift;
  47     my $content;
  48     my $metadata = {};
  49     my $p;
  50     my $e;
  51     my $tag;
  52     my $jar = HTTP::Cookies->new;
  53     my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
  54     my $r;
  55     my $videourl;
  56     my $quality = $self->_getval('QUALITY');
  57     my %preflist = (
  58         'hd' => [22, 35, 18, 34, 6, 5],
  59         'h264' => [18, 34, 22, 35, 6, 5],
  60         'high' => [34, 35, 18, 22, 6, 5],
  61         'normal' => [6, 5, 34, 35, 18, 22]);
  62     my $preflist;
  63
  64     $url =~ m|$pattern|;
  65     $url = $1;
  66
  67     $metadata->{'URL'} = $url;
  68     $metadata->{'ID'} = $2;
  69     $metadata->{'TYPE'} = 'video';
  70     $metadata->{'SOURCE'} = $self->{'NAME'};
  71     $metadata->{'TITLE'} = undef;
  72     $metadata->{'DLURL'} = undef;
  73
  74     $preflist = $preflist{$quality};
  75     $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));
  76
  77     $videourl = sprintf('http://www.youtube.com/watch?v=%s', $2);
  78
  79     unless(defined($r = $ua->get($videourl))) {
  80         $self->error('Could not download %s', $url);
  81         return undef;
  82     }
  83
  84     if ($r->base->as_string() =~ m,/verify_age,) {
  85         $self->debug('Video requires age verification');
  86         $ua->cookie_jar($jar);
  87         $r = $self->__login($videourl, $ua);
  88         unless(defined($r)) {
  89             $self->error('Could not log into YouTube');
  90             return undef;
  91         }
  92     }
  93     $content = $r->content();
  94
  95     $p = HTML::TokeParser->new(\$content);
  96
  97     while ($tag = $p->get_tag('div', 'meta', 'script')) {
  98         if ('meta' eq $tag->[0]) {
  99             if ('title' eq $tag->[1]->{'name'}) {
 100                 $metadata->{'TITLE'} = $tag->[1]->{'content'};
 101                 $self->debug('Title found: %s', $metadata->{'TITLE'});
 102             }
 103         } elsif ('script' eq $tag->[0]) {
 104             $e = $p->get_text();
 105             $self->debug("Found script: %s", $e);
 106             if ($e =~ m|\x22fmt_url_map\x22\s*:\s*\x22([^\x22]+)\x22|) {
 107                 $self->debug("Found fmt_url_map: %s", $1);
 108                 my $urls = $1;
 109                 my %urls;
 110
 111                 $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
 112                 %urls = split(/[\|,]/, $urls);
 113                 $self->debug("Found quality levels [%s]", join(", ", keys(%urls)));
 114
 115                 foreach (keys(%urls)) {
 116                     if ($_ == 35) {
 117                         $self->debug('Found flv,h264,large: %s', $urls{$_});
 118                     } elsif ($_ == 34) {
 119                         $self->debug('Found flv,h264: %s', $urls{$_});
 120                     } elsif ($_ == 22) {
 121                         $self->debug('Found mp4,h264,large: %s', $urls{$_});
 122                     } elsif ($_ == 18) {
 123                         $self->debug('Found mp4,h264: %s', $urls{$_});
 124                     } elsif ($_ == 5) {
 125                         $self->debug('Found flv,flv: %s', $urls{$_});
 126                     } else {
 127                         $self->error('Unknown tag %s: %s', $_, $urls{$_});
 128                     }
 129                 }
 130
 131                 foreach (@{$preflist}) {
 132                     if (exists($urls{$_})) {
 133                         $self->debug("Selected URL with quality level %s", $_);
 134                         $metadata->{'DLURL'} = $urls{$_};
 135                         last;
 136                     }
 137                 }
 138
 139                 $self->debug('URL found: %s', $metadata->{'DLURL'});
 140             }
 141         } elsif ('div' eq $tag->[0]) {
 142             if (exists($tag->[1]->{'class'}) and ('errorBox' eq $tag->[1]->{'class'})) {
 143                 $self->error("Could not get video data for youtube %s: %s",
 144                         $metadata->{'ID'}, $p->get_trimmed_text());
 145                 return undef;
 146             }
 147         }
 148     }
 149
 150     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
 151         $self->error('Could not determine download URL');
 152         return undef;
 153     }
 154
 155     return $metadata;
 156 }
 157
 158 sub __login {
 159     my $self = shift;
 160     my $videourl = shift;
 161     my $ua = shift;
 162     my $user = $self->_getval('USERNAME');
 163     my $pass = $self->_getval('PASSWORD');
 164     my $r;
 165     my $p;
 166     my $c;
 167     my $token;
 168
 169     sub check_cookie {
 170
 171         my $jar = shift;
 172         my $key = shift;
 173         my $found = undef;
 174
 175         $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });
 176
 177         return $found;
 178     }
 179
 180     if (($user eq '') or ($pass eq '')) {
 181         $self->error('No username or password defined for YouTube');
 182         return undef;
 183     }
 184
 185     $self->debug('Logging in');
 186     $r = $ua->post('http://www.youtube.com/signup', { 'next' => '/', 'current_form' => 'login', 'action_login' => '1', 'username' => $user, 'password' => $pass });
 187
 188     unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
 189         $self->error('Could not log into YouTube');
 190         return undef;
 191     }
 192
 193     $r = $ua->get($videourl);
 194     if ($r->base->as_string() =~ m,/verify_age,) {
 195         $self->debug("Looking for session token...");
 196         $c = $r->decoded_content();
 197         $p = HTML::TokeParser->new(\$c);
 198         while (my $tag = $p->get_tag('script')) {
 199             if ($p->get_text() =~ /gXSRF_token = '(.+)'/) {
 200                 $token = $1;
 201                 last;
 202             }
 203         }
 204
 205         unless(defined($token)) {
 206             $self->error("Could not find session token");
 207             return undef;
 208         }
 209
 210         $self->debug('Authenticating session...');
 211         $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
 212     }
 213
 214     unless(check_cookie($ua->cookie_jar, 'is_adult')) {
 215         $self->error('Could not authenticate session');
 216         return undef;
 217     }
 218
 219     return $ua->get($videourl);
 220 }
 221
 222 1;