videosite/WimpGrabber.pm

   1 # (c) 2009 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for wimp.com
   5
   6 package videosite::WimpGrabber;
   7
   8 use videosite::GrabberBase;
   9 @ISA = qw(videosite::GrabberBase);
  10
  11 use MIME::Base64;
  12 use HTML::Parser;
  13 use Data::Dumper;
  14
  15 use strict;
  16
  17 sub new {
  18     my $class = shift;
  19     my $self = $class->SUPER::new(
  20         NAME => 'wimp',
  21         _SELFTESTURL => 'http://www.wimp.com/insanebuilding/',
  22         _SELFTESTTITLE => 'Insane building.',
  23         PATTERNS => ['(http://(?:[-a-zA-Z0-9_.]+\.)*wimp.com/([^/]+)/?)'],
  24         @_,
  25     );
  26
  27     return bless($self, $class);
  28 }
  29
  30 sub _parse {
  31     my $self = shift;
  32     my $url = shift;
  33     my $pattern = shift;
  34     my $content;
  35     my $metadata = {};
  36     my $p = HTML::Parser->new(api_version => 3);
  37     my @accum;
  38     my @text;
  39     my $e;
  40
  41     $url =~ m|$pattern|;
  42     $url = $1;
  43
  44     $metadata->{'URL'} = $url;
  45     $metadata->{'ID'} = $2;
  46     $metadata->{'TYPE'} = 'video';
  47     $metadata->{'SOURCE'} = $self->{'NAME'};
  48     $metadata->{'TITLE'} = undef;
  49     $metadata->{'DLURL'} = undef;
  50
  51     unless(defined($content = $self->simple_get(sprintf('http://www.wimp.com/%s', $2)))) {
  52         $self->error('Could not download %s', $url);
  53         return undef;
  54     }
  55
  56     $p->handler(start => \@accum, "tagname, attr");
  57     $p->handler(text => \@text, "text");
  58     $p->report_tags(qw(meta script));
  59     $p->utf8_mode(1);
  60     $p->parse($content);
  61
  62     # Look for the title in the meta tags
  63     foreach $e (@accum) {
  64         if ('meta' eq $e->[0] and exists($e->[1]->{'name'})) {
  65             if ('description' eq $e->[1]->{'name'}) {
  66                 $metadata->{'TITLE'} = $e->[1]->{'content'};
  67                 last;
  68             }
  69         }
  70     }
  71
  72     # Look for the download URL
  73     # This is obfuscated a little bit.
  74     foreach $e (@text) {
  75         if ($e->[0] =~ m|var googleCode = '([^\x27]+)'|) {
  76             my $c = $1;
  77
  78             $self->debug("Found obfuscated code: %s", $c);
  79             my $d = decode_base64($c);
  80             $self->debug("Decoded to: %s", $d);
  81
  82             if ($d =~ m|\.addVariable\("file",\s*"([^\x22]+)"\)|) {
  83                 $metadata->{'DLURL'} = $1;
  84             }
  85         }
  86     }
  87
  88     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
  89         $self->error('Could not determine download URL');
  90         return undef;
  91     }
  92
  93     return $metadata;
  94 }
  95
  96 1;