videosite/ZeroPunctuationGrabber.pm

   1 # (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
   2 # licensed under GNU GPL v2
   3 #
   4 # Grabber for www.escapistmagazine.com/articles/view/editorials/zeropunctuation
   5
   6 package videosite::ZeroPunctuationGrabber;
   7
   8 use videosite::GrabberBase;
   9 @ISA = qw(videosite::GrabberBase);
  10
  11 use HTML::TokeParser;
  12 use Data::Dumper;
  13 use videosite::JSArrayParser;
  14
  15 use strict;
  16
  17 sub new {
  18     my $class = shift;
  19     my $self = $class->SUPER::new(
  20         NAME => 'zeropunctuation',
  21         _SELFTESTURL => 'http://www.escapistmagazine.com/videos/view/zero-punctuation/5346-Amy',
  22         _SELFTESTTITLE =>'Amy',
  23         PATTERNS => ['(http://www.escapistmagazine.com/videos/view/zero-punctuation/([-A-Za-z0-9]+))'],
  24         @_,
  25     );
  26
  27     return bless($self, $class);
  28 }
  29
  30 sub _parse {
  31     my $self = shift;
  32     my $url = shift;
  33     my $pattern = shift;
  34     my $content;
  35     my $metadata = {};
  36     my $p;
  37     my $e;
  38     my $j;
  39     my $jsp;
  40     my $r;
  41
  42     $url =~ m|$pattern|;
  43     $url = $1;
  44
  45     $metadata->{'URL'} = $url;
  46     $metadata->{'ID'} = $2;
  47     $metadata->{'TYPE'} = 'video';
  48     $metadata->{'SOURCE'} = $self->{'NAME'};
  49     $metadata->{'TITLE'} = undef;
  50     $metadata->{'DLURL'} = undef;
  51
  52     unless(defined($content = $self->simple_get($url))) {
  53         $self->error('Could not download %s', $url);
  54         return undef;
  55     }
  56
  57     $p = HTML::TokeParser->new(\$content);
  58
  59     while ($e = $p->get_tag('div', 'param')) {
  60         if (($e->[0] eq 'param') and exists($e->[1]->{name}) and ($e->[1]->{name} eq 'flashvars')) {
  61             my %r = map { $self->decode_hexurl($_) } split(/[&=]/, $e->[1]->{value});
  62
  63             unless(exists($r{config})) {
  64                 $self->error("config URL not found in flashvars");
  65                 return undef;
  66             }
  67
  68             $j = $r{config};
  69         } elsif (($e->[0] eq 'div') and exists($e->[1]->{itemprop}) and ($e->[1]->{itemprop} eq 'name')) {
  70             $metadata->{'TITLE'} = $p->get_phrase();
  71         }
  72     }
  73
  74     unless(defined($content = $self->simple_get($j))) {
  75         $self->error("Could not download %s", $j);
  76         return undef;
  77     }
  78
  79     $jsp = videosite::JSArrayParser->new();
  80     $r = $jsp->parse($content);
  81
  82     foreach (@{$r->{playlist}}) {
  83         if ($_->{eventCategory} eq 'Video') {
  84             $metadata->{'DLURL'} = $_->{url};
  85             last;
  86         }
  87     }
  88
  89     unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
  90         $self->error('Could not determine download URL');
  91         return undef;
  92     }
  93
  94     return $metadata;
  95 }
  96
  97 1;